コマンド行ルーチンのデバッグ

ブレークポイントとウォッチポイントの使用法

Caché デバッガ には、プログラムの実行を中断する 2 つの方法があります。

• ブレークポイント

• ウォッチポイント

ブレークポイントは、ZBREAK コマンドで指定する Caché ルーチン内の位置です。実行中のルーチンが指定された行に達すると、Caché はルーチンを中断します。オプションとして、定義したデバッグを実行する場合もあります。最大 20 個のルーチンまでブレークポイントを設定できます。また、1 つのルーチン内に最大 20 個までのブレークポイントを設定できます。

ウォッチポイントは、ZBREAK コマンドで識別する変数です。SET コマンドあるいは KILL コマンドで値を変更すると、ルーチンの実行またはZBREAK コマンド内で定義したデバッグの実行、あるいはその両方を中断できます。最大 20 個のウォッチポイントを設定できます。

定義したブレークポイントとウォッチポイントは、1 つのセッション内でのみ維持されます。したがって、ブレークポイントとウォッチポイントの定義を 1 つのルーチンあるいは XECUTE コマンド文字列に格納すると、セッション間でそれらを簡単に元に戻せるため便利です。

ブレークポイントとウォッチポイントの設定

ZBREAK コマンドを使用して、ブレークポイントとウォッチポイントを設定します。

構文

ZBREAK location[:action:condition:execute_code]

以下を示します。

location	必須項目。(ブレークポイントを設定する) コード位置、(ウォッチポイントを設定する) ローカル変数あるいはシステム変数を指定します。指定した位置にブレークポイント/ウォッチポイントが既に定義されている場合、新規の設定により古い設定が置き換えられます。
action	オプション　—　ブレークポイント/ウォッチポイントがトリガされた (引き起こされた) ときの動作を指定します。ブレークポイントの場合、動作はコード行が実行される前に発生します。またウォッチポイントの場合、動作はローカル変数を変更するコマンドの実行後に発生します。動作は、大文字あるいは小文字で指定できますが、引用符で囲む必要があります。
condition	オプション　—　ブレークポイント/ウォッチポイントがトリガされたときに評価される式を指定します。その式は、引用符で囲む必要があります。condition が False の場合、action は実行されず、execute_code も実行されません。condition が未指定の場合、既定では True です。
execute_code	オプション — condition が True の場合に実行される ObjectScript コードを指定します。コードがリテラルの場合、引用符で囲む必要があります。このコードは、動作が実行される前に実行されます。特殊なシステム変数 $TEST の値は、コードを実行する前に保存されます。コードの実行後、デバッグされたプログラムに存在する $TEST の値は復元されます。

Note:

疑問符 (?) を付けて ZBREAK を使用すると、ヘルプが表示されます。

ZBREAK の例

以下の例では、ローカル変数 a が削除されると常に実行を中断するウォッチポイントを設定します。動作は何も指定されていないため、"B" が指定されているものとします。

ZBREAK *a::"'$DATA(a)"

以下の例は、(ルーチン内から発行されるコマンドではなく) ダイレクト・モードの Caché コマンドに対して動作する、上記のウォッチポイントを示しています。キャレット (^) は、実行を中断させるコマンドを示します。

%SYS>KILL a
KILL a
^
<BREAK>
%SYS 1s0>

以下の例は、実行を中断し、label2^rou 行の先頭にシングル・ステップ・モードを設定するブレークポイントです。

ZBREAK label2^rou:"L"

以下の例は、ルーチン実行時にどのようにブレークが実行されるかを示しています。キャレット (^) は、実行が中断した位置を示します。

%SYS>DO ^rou
label2 SET x=1
 ^ 
<BREAK>label2^rou
%SYS 2d0>

以下の例では、"N" 動作のため、行 label3^rou のブレークポイントは実行を中断しません。しかし、行 label3^rou に達した際に x<1 の場合、flag を x に設定します。

ZBREAK label3^rou:"N":"x<1":"SET flag=x" 

以下の例は、a の値が変更されるたびに、^GLO のコードを実行するウォッチポイントを設定します。二重コロンは、condition 引数がないことを示しています。

ZBREAK *a:"N"::"XECUTE ^GLO"

以下の例は、b の値が変更されるたびに、トレース・メッセージを表示するウォッチポイントを設定します。トレース・メッセージは、トレース・モードが ZBREAK /TRACE:ON コマンドで ON になっている場合にのみ表示されます。

ZBREAK *b:"T"

以下の例は、変数 a が 5 に設定されると、シングル・ステップ・モードで実行を中断するウォッチポイントを設定します。

ZBREAK *a:"S":"a=5"

以下の例は、ブレークの発生時、キャレット記号 (^) は、変数 a を 5 に設定するコマンドを指定します。

%SYS>DO ^test
FOR i=1:1:6 SET a=a+1
 ^ 
<BREAK>
test+3^test 
%SYS 3f0>WRITE a 
5

ブレークポイントとウォッチポイントを無効にする

以下のいずれかを無効にできます。

• 特定のブレークポイントとウォッチポイント

• すべてのブレークポイントあるいはウォッチポイント

特定のブレークポイントとウォッチポイントを無効にする

マイナス記号をブレークポイントあるいはウォッチポイントの位置指定の前に置くと、ブレークポイントあるいはウォッチポイントを無効にできます。以下のコマンドは、位置 label2^rou で事前に指定されたブレークポイントを無効にします。

ZBREAK -label2^rou

無効になったブレークポイントは “消失” しますが、その定義は維持されます。したがって、プラス記号をその前に置くと、無効にされたブレークポイントを有効にできます。以下のコマンドは、以前無効にされたブレークポイントを有効にします。

ZBREAK +label2^rou

ブレークポイントとウォッチポイントの実行を遅らせる

指定した数の反復の間、ブレークポイント/ウォッチポイントの実行を遅らせることもできます。実行する度ではなく定期的にブレークさせるように、ループ内にコード行を記述している場合もあります。このためには、通常どおりにブレークポイントを設定した後、位置の引数に続くカウントを無効にします。

以下の ZBREAK コマンドは、100 回反復される間、label2^rou のブレークポイントを無効にします。101 回目にこの行が実行されると、指定したブレークポイントの動作が発生します。

 ZBREAK label2^rou       ; establish the breakpoint 
 ZBREAK -label2^rou#100  ; disable it for 100 iterations 

ブレークポイントとウォッチポイントの削除

次のように、ブレークポイント/ウォッチポイントの位置の前にマイナス記号を 2 つ付けて、ブレークポイントまたはウォッチポイントを個別に削除できます。

ZBREAK --label2^rou

ブレークポイント/ウォッチポイントを削除した後は、それを再度定義することにより削除したポイントをリセットできます。

すべてのブレークポイントを削除するには、以下のコマンドを発行します。

ZBREAK /CLEAR

このコマンドは、Caché プロセスが停止すると、自動的に実行されます。

シングル・ステップ・ブレークポイントの動作

シングル・ステップ実行を使用して、コードの各行あるいは各コマンドの最初で実行を停止できます。シングル・ステップ・ブレークポイントを設定し、各ステップで実行される動作と実行コードを指定できます。以下の構文を使用して、シングル・ステップ・ブレークポイントを定義します。

ZBREAK $:action[:condition:execute_code]

他のブレークポイントと異なり、ZBREAK $ はブレークを引き起こしません。ブレークは、シングル・ステップとして自動的に発生するからです。ZBREAK $ を使用すると、ルーチンのステップ実行時にデバッガがブレークする各ポイントで、動作を指定しコードを実行できます。これは、行あるいはコマンドの実行をトレースするのに特に役立ちます。例えば以下のコードは、アプリケーション ^TEST で実行された行をトレースします。

%SYS>ZBREAK /TRACE:ON
%SYS>BREAK "L+"
%SYS>ZBREAK $:"T"

"T" 単体で (つまり、その他のアクション・コードなしで) 指定すると、通常自動的に発生するシングル・ステップ・ブレークが抑制されます (また、他のアクション・コードを使用するかどうかにかかわらず、"N" アクション・コードを指定すれば、シングル・ステップ・ブレークが抑制されます)。

トレースとブレークの両方を発生させるには、以下の方法でシングル・ステップ・ブレークポイントの定義を設定します。

%SYS>ZBREAK $:"TB"

実行のトレース

以下の ZBREAK 形式を使用して、ZBREAK コマンドの "T" 動作を有効にするかどうかを制御できます。

ZBREAK /TRACE:state[:device]

state には、以下を指定できます。

device で ALL あるいは ON 状態キーワードを使用する場合、トレース・メッセージは、主デバイスではなく、指定されたデバイスに転送されます。デバイスを開いていない場合、Caché は、WRITE オプションと APPEND オプションが付いたシーケンシャル・ファイルとしてそのデバイスを開こうとします。

OFF 状態キーワードを使用してデバイスを指定すると、現在ファイルが開いていると、Caché はそのファイルを閉じます。

トレース・メッセージは、“T” 動作に対応するブレークポイントで生成されます。例外として、トレース・メッセージの形式は、すべてのブレークポイントで以下のようになります。

Trace: line_reference での ZBREAK

line_reference は、参照するブレークポイントの行です。

コマンドでステップを実行する場合、トレース・メッセージの形式は、シングル・ステップのブレークポイントと若干異なります。

Trace: line_reference source_offset での ZBREAK

line_reference は参照するブレークポイントの行で、source_offset は、ブレークが発生したソース行位置への 0 ベースのオフセットです。

オペレーティング・システムの注釈

• Windows —　別のデバイスへのトレース・メッセージは、COM1: など COM ポートに接続されているターミナル・デバイスに対して、Windows プラットフォームでサポートされています。コンソールあるいはターミナル・ウィンドウは使用できません。トレース・デバイスへのシーケンシャル・ファイルを指定できます。

• UNIX® —　以下の方法で、UNIX® プラットフォームで別のデバイスにトレース・メッセージを送信します。

  1. /dev/tty01 にログインします。

  2. 次の tty コマンドを入力し、デバイス名を検証します。

     $ tty
     /dev/tty01
     

     

  3. 以下のコマンドを発行し、デバイス競合を避けます。

     $ exec sleep 50000
     

     

  4. 作業ウィンドウに戻ります。

  5. Caché を開始します。

  6. 以下のトレース・コマンドを発行します。

     ZBREAK /T:ON:"/dev/tty01"
     

     

  7. プログラムを実行します。

     “T” 動作を実行するブレークポイントあるいはウォッチポイントを設定すると、 /dev/tty01 に接続されたウィンドウに、トレース・メッセージが表示されます。

トレース・メッセージ形式

ブレークポイントをコードに設定すると、以下のメッセージが表示されます。

Trace: ZBREAK at label2^rou2

ウォッチポイント変数を設定すると、以下のメッセージが表示されます。

Trace: ZBREAK SET var=val at label2^rou2 
Trace: ZBREAK SET var=Array Val at label2^rou2
Trace: ZBREAK KILL var at label2^rou2

• var は、監視される変数です。

• val は、その変数に設定された新しい値です。

NEW コマンドを発行すると、トレース・メッセージは受け取りません。しかし、NEW レベルの変数で次に SET あるいは KILL を発行すると、変数のトレースが実行されます。変数がルーチンに参照渡しされると、その名前が変更された場合も、変数は引き続き追跡されます。

割り込みキーと Break コマンド

通常、割り込みキー (一般的に CTRL-C) を続けて押すと、トラップ可能な (<INTERRUPT>) エラーが生成されます。<INTERRUPT> エラーではなく、ブレークを発生させる割り込み処理を設定するには、ZBREAK コマンド ZBREAK /INTERRUPT:Break を使用します。

これにより、デバイスのアプリケーション・レベルで割り込みが無効の場合も、割り込みキーを押したときにブレークが発生します。

ターミナルから読み取り中に割り込みキーを押すと、ブレーク・モード・プロンプトを表示するため、Enter キーを押す必要があります。ブレークではなくエラーを生成するよう割り込み処理をリセットするには、コマンド ZBREAK /INTERRUPT:NORMAL を発行します。

現在のデバッグ環境情報の表示

定義されたすべてのブレークポイントあるいはウォッチポイントを含め、現在のデバッグ環境の情報を表示するには、引数なしの ZBREAK コマンドを発行します。

引数なしの ZBREAK コマンドは、以下のデバッグ環境の状態を示します。

• CTRL-C がブレークを生じさせるかどうか

• "T" 動作で指定されたトレースの出力が、ZBREAK コマンドで表示されるかどうか

• 有効/無効状態、動作、条件、実行可能コードを指定するフラグを持つ、すべての定義済みブレークポイントの位置

• 有効/無効状態、動作、条件、実行可能コードを指定するフラグを持つウォッチポイントのすべての変数

このコマンドからの出力は、デバッグ・デバイスとして定義されたデバイスに表示されます。ZBREAK /DEBUG コマンドで異なるデバッグ・デバイスを定義しない限り、ユーザの主デバイスに出力されます。デバイスの定義は、"デバッグ・デバイスの使用法" のセクションで説明しています。

以下のテーブルは、各ブレークポイントとウォッチポイントに提供されるフラグの説明です。

以下のテーブルは、ブレークポイント/ウォッチポイントの表示で F: 値をどのように解釈するかを示しています。F: 値は、最初の列にある適切な値のリストです。

既定表示

最初に Caché を開いて ZB コマンドを使用するとき、出力は以下のようになります。

%SYS>ZBREAK
BREAK: 
No breakpoints
No watchpoints

これは、以下を示します。

• トレースの実行は OFF です。

• CTRL-C が押されると、ブレークは無効になります。

• ブレークポイント/ウォッチポイントは未定義です。

既存のブレークポイントとウォッチポイントの表示

この例では、2 つのブレークポイントと 1 つのウォッチポイントの定義を示しています。

%SYS>ZBREAK +3^test:::"WRITE ""IN test"""
%SYS>ZBREAK -+3^test#5
%SYS>ZBREAK +5^test:"L"
%SYS>ZBREAK -+5^test
%SYS>ZBREAK *a:"T":"a=5"
%SYS>ZBREAK /TRACE:ON
%SYS>ZBREAK
BREAK: TRACE ON
+3^test F:EB S:5 C: E:"WRITE ""IN test"""
+5^test F:DL S:0 C: E:
a F:ET S:0 C:"a=5" E:

最初の 2 つの ZBREAK コマンドは、ブレークポイントの遅延を定義しています。その次の 2 つの ZBREAK は無効なブレークポイントを、5 番目の ZBREAK はウォッチポイントを定義しています。6 番目の ZBREAK コマンドはトレースの実行を有効にし、引数のない最後の ZBREAK コマンドは、現在のデバッグ設定情報を表示します。

例えば、ZBREAK は以下を表示します。

• トレースは ON です。

• CTRL-C が押されると、ブレークは無効になります。

その後出力は、2 つのブレークポイントと 1 つのウォッチポイントを示します。

• 最初のブレークポイントの F フラグは “EB”、S フラグは 5 です。つまり、ブレークポイントは、行の 5 回目の実行で発生します。E フラグは、ブレーク用の Caché プログラマ・プロンプトが表示される前に実行される、実行可能コードを表示します。

• 2 番目のブレークポイントの F フラグは “DL” です。これは、ブレークポイントの無効を意味しますが、有効の場合ブレークが発生し、ブレークポイント位置の後ろの各コード行をシングル・ステップで実行します。

• ウォッチポイントの F フラグは “ET” です。これは、ウォッチポイントが有効であることを意味します。トレース実行が ON の場合、トレース・メッセージがトレース・デバイスに表示されます。トレース・デバイスを定義していない場合、トレース・デバイスは主デバイスになります。

• C フラグは、condition が True の場合にのみトレースが表示されることを意味します。

デバッグ・デバイスの使用法

デバッグ・デバイスは、以下のようなデバイスです。

• ZBREAK コマンドは、デバッグ環境情報を表示します。

• Caché プログラマ・プロンプトは、ブレーク発生時に表示されます。

Caché を実行すると、バッグ・デバイスが主デバイスとして自動的に設定されます。いつでも、デバッグ入出力は、コマンド ZBREAK /DEBUG:"device" で代わりのデバイスに送信できます。

Note:

また、オペレーティング・システム固有の動作も実行可能です。

UNIX® システムで tty01 デバイスをブレーク状態にするには、以下のコマンドを発行します。

ZBREAK /D:"/dev/tty01/"

CTRL-C あるいはブレークポイント、ウォッチポイントがトリガされてブレークが発生すると、デバイスに接続されたウィンドウに表示されます。そのウィンドウが、アクティブ・ウィンドウになります。

デバイスが開いていない場合、自動的に OPEN コマンドが実行されます。デバイスが指定した位置で既に開いている場合、あらゆる既存の OPEN パラメータが優先されます。

Caché デバッガの例

最初に、以下に示す test という簡単なプログラムをデバッグします。目標は、変数 a に 1 を、変数 b に 2 を、変数 c に 3 を格納することです。

test; Assign the values 1, 2, and 3 to the variables a, b, and c
 SET a=1
 SET b=2
 SET c=3 KILL a WRITE "in test, at end"
 QUIT

しかし、test を実行すると、b と c のみが正しい値を取得します。

%SYS>DO ^test
in test, at end
%SYS>WRITE
b=2
c=3
%SYS>

明らかにこのプログラムの問題は、変数 a が行 4 で KILL コマンドによって削除されることですが、この問題を特定するためにデバッガを使用する必要があると想定します。

ZBREAK コマンドを使用して、ルーチン test の各コード行 ("L" 動作) をシングル・ステップに設定できます。ステップを実行して a の値を書き込むことにより、4 行目に問題があることを判定します。

%SYS>NEW 
%SYS 1S1>ZBREAK 
BREAK
No breakpoints
No watchpoints
%SYS 1S1>ZBREAK ^test:"L"
%SYS 1S1>DO ^test 
SET a=1
^
<BREAK>test+1^test
%SYS 3d3>WRITE a 
<UNDEFINED>^test
%SYS 3d3>GOTO
SET b=2
^
<BREAK>test+2^test
%SYS 3d3>WRITE a 
1
%SYS 3d3>GOTO
SET c=3 KILL a WRITE "in test, at end"
^
<BREAK>test+3^test
%SYS 3d3>WRITE a
1
%SYS 3d3>GOTO
in test, at end
QUIT
^
<BREAK>test+4^test
%SYS 3d3>WRITE a 
WRITE a
^
<UNDEFINED>^test
%SYS 3d3>GOTO
%SYS 1S1>

これでこの行を検証し、KILL a コマンドを発見できます。さらに複雑なコードでは、その行から ("S" 動作) コマンドでシングル・ステップを実行したい場合もあります。

問題が、DO、FOR、XECUTE コマンド、ユーザ定義関数で発生した場合、"L+" あるいは "S+" 動作を使用して、コードの下位レベルにある行あるいはコマンドからシングル・ステップを実行します。

Caché デバッガ・エラーの理解

Caché デバッガ は、適切な Caché エラー・メッセージを持つ条件引数あるいは実行引数でエラーが発生すると、フラグを立てます。

エラーが execute_code 引数内に存在する場合、実行コードがエラー・メッセージの前に表示されると、実行コードは条件コードに囲まれます。条件特殊変数 ($TEST) は、常に実行コードの最後で 1 に設定されるため、残りのデバッガ処理コードは適切に動作します。制御がルーチンに戻ると、ルーチン内の $TEST 値はリストアされます。

サンプル・プログラム test に対し、以下の ZBREAK コマンドを発行するとします。

%SYS>ZBREAK test+1^test:"B":"a=5":"WRITE b"

このプログラム test で変数 b は、行 test+1 で定義されていないため、エラーが発生します。以下のようなエラーが表示されます。

IF a=5 XECUTE "WRITE b" IF 1
^
<UNDEFINED>test+1^test

condition を定義しなかった場合、人工的に True の条件を実行コードの前後に定義できます。以下はその例です。

%SYS>IF 1 WRITE b IF 1

ルーチンの実行を中断する引数なし BREAK の使用法

実行中のルーチンを中断し、プロセスをプログラマ・モードに戻すには、ルーチンで実行を一時的に中断させたい位置に、引数なしの BREAK を入力します。

Caché が BREAK に遭遇すると、以下のステップが実行されます。

1. 実行中のルーチンを中断します。

2. プログラマ・モードへプロセスを戻します。

   これにより、ObjectScript コマンドを発行し、データを修正できます。また、エラーまたは追加の BREAK があっても、他のルーチンやサブルーチンを実行できます。

ルーチンが中断された位置で実行を再開するには、引数なしの GOTO コマンドを発行します。

コード内の引数なしの BREAK コマンドに後置条件を指定すると、ルーチンを変更しなくても、単に後置条件変数を設定するだけで同じコードを再実行できるので便利です。例えば、ルーチンに以下の行があるとします。

CHECK BREAK:$DATA(debug)

変数 debug を設定すると、ルーチンを中断し、ジョブをプログラマ・モードに戻すことができます。また、変数 debug をクリアすると、ルーチンの実行を継続できます。

詳細は、このドキュメントの "コマンド後置条件式" を参照してください。

ルーチンの実行を中断する引数付き BREAK の使用法

中断したいルーチンのすべての位置に、引数なし BREAK コマンドを置く必要はありません。Caché では、コードのステップ実行を可能にする引数オプションがいくつか用意されています。コードのステップ実行は、シングル・ステップ (BREAK “S”) またはコマンド行 (BREAK “L”) を使用して行えます。これらの文字コード引数のすべてのリストについては、BREAK コマンドを参照してください。

BREAK “S” と BREAK “L” の一つの違いは、多数のコマンド行が複数ステップで構成されることにあります。このことは必ずしも明白になっているわけではありません。例えば、以下はすべて単一行 (および単一 ObjectScript コマンド) ですが、それぞれが 2 ステップで解析されます ：SET x=1,y=2、KILL x,y、WRITE “hello”,!、IF x=1,y=2。

BREAK “S” と BREAK “L” は、ラベル行、コメント、および TRY 文を無視します (ただし、両方ともに TRY ブロックの閉じ中括弧でブレークします)。BREAK “S” は CATCH 文でブレークしますが (CATCH ブロックが入力された場合)、BREAK “L” はブレークしません。

プログラマ・モードに設定すると、ブレークの状態はスタックされません。したがって、ブレークの状態を変更した場合、引数なしの GOTO を発行して実行中のルーチンに戻ったときに、その新規の状態が有効なままになります。

DO、XECUTE、FOR、ユーザ定義関数が実行されるたびに、Caché はブレークの状態をスタックします。BREAK "C" を選択してブレークを OFF にすると、システムは DO、XECUTE、FOR、またはユーザ定義関数の最後にブレークの状態をリストアします。そうしない場合、Caché はスタックされた状態を無視します。

このように、下位のサブルーチン・レベルでブレークを有効にすると、ルーチンが上位のサブルーチン・レベルに戻った後、ブレークが継続されます。一方、上位レベルで有効だったブレークを下位サブルーチン・レベルで無効にした場合、上位レベルに戻ると、ブレークが再開されます。BREAK "C-" を使用して、すべてのレベルでブレークを無効にすることができます。

BREAK “L+” または BREAK “S+” を使用して、DO、XECUTE、FOR、またはユーザ定義関数内でブレークを有効にすることができます。

BREAK “L-” を使用すると、現在のレベルでのブレークが無効になりますが、前のレベルでの改行が有効になります。BREAK “S-” を使用すると、現在のレベルでのブレークが無効になりますが、前のレベルでのシングル・ステップ・ブレークが有効になります。

デバッグの停止

プロセスで作成されたすべてのデバッグを削除するには、BREAK "OFF" コマンドを使用します。このコマンドは、すべてのブレークポイントとウォッチポイントを削除し、すべてのプログラム・スタック・レベルでステップ実行を無効にします。また、デバッグとトレース・デバイスに関連するものも削除しますが、それらを閉じません。

BREAK "OFF" コマンドを実行することは、以下の一連のコマンドを発行することと同じです。

 ZBREAK /CLEAR 
 ZBREAK /TRACE:OFF 
 ZBREAK /DEBUG:"" 
 ZBREAK /ERRORTRAP:ON 
 BREAK "C-"

プログラマ・プロンプトのプログラム・スタック情報表示

BREAK コマンドがルーチンの実行を中断したとき、あるいはエラーが発生したとき、プログラム・スタックは、スタックされた情報の一部を維持します。プログラマ・モードでこの状態になった場合、情報の概要がプログラマ・モード・プロンプト ( > ) の前に表示されます。例えば、5d3> のような形式で表示されます。以下はその説明です。

プロンプトには、以下に一覧表示されているようなメッセージが表示されます。

以下の例では、スタック・フレーム追加時において、コマンド行の文が結果のプログラマ・モード・プロンプトを伴って表示されます。

USER>NEW
USER 1S1>NEW
USER 2N1>XECUTE "NEW  WRITE 123 BREAK"
<BREAK>
USER 4x1>NEW
USER 5B1>BREAK
<BREAK>
USER 6N2>

QUIT 1 を使用して、プログラム・スタックを戻すことができます。以下は、スタックの巻き戻し時におけるプログラマ・モード・プロンプトの例です。

USER 6f0>QUIT 1  /* an error occurred in a FOR loop. */
USER 5x0>QUIT 1  /* the FOR loop was in code invoked by XECUTE. */
USER 4f0>QUIT 1  /* the XECUTE was in a FOR loop. */
USER 3f0>QUIT 1  /* that FOR loop was nested inside another FOR loop. */
USER 2d0>QUIT 1  /* the DO command was used to execute the program. */
USER 1S0>QUIT 1  /* sign on state. */
USER>

BREAK あるいはエラー後の実行の再開

BREAK あるいはエラーの後にプログラマ・モードに戻ると、Caché は、BREAK あるいはエラーの原因となったコマンドの位置を記録します。その後、プログラマ・モードで引数なしの GOTO を入力するだけで、次のコマンドで実行を再開できます。

4f0>GOTO

引数付きの GOTO を入力すると、以下のように、ブレークあるいはエラーが発生する同じルーチン内の別の行頭から実行を再開できます。

4f0>GOTO label3

また、異なるルーチンの行頭から実行を再開できます。

4f0>GOTO label3^rou

または、引数なしの QUIT コマンドで、プログラム・スタックをクリアすることもできます。

4f0>QUIT
%SYS>

サンプル・ダイアログ

以下はサンプルで使用されるルーチンです。

MAIN ; 03 Jan 99 11:40 AM
 SET x=1,y=6,z=8
 DO ^SUB1 WRITE !,"sum=",sum
 QUIT
 
SUB1 ; 03 Jan 99 11:42 AM
 SET sum=x+y+z
 QUIT

BREAK "L" により、ルーチン SUB1 でブレークは発生しません。

%SYS>BREAK "L"
%SYS>DO ^MAIN
SET x=1,y=6,z=8
^
<BREAK>MAIN+1^MAIN
2d0>GOTO
DO ^SUB1 WRITE !,"sum=",sum
^
<BREAK>MAIN+2^MAIN
2d0>GOTO
sum=15
QUIT
^
<BREAK>MAIN+3^MAIN
2d0>GOTO
%SYS>

BREAK"L+" により、ルーチン SUB1 でブレークも発生します。

%SYS>BREAK "L+"
%SYS>DO ^MAIN
SET x=1,y=6,z=8
^
<BREAK>MAIN+1^MAIN
2d0>GOTO
DO ^SUB1 Write !,"sum=",sum
^
<BREAK>MAIN+2^MAIN
2d0>GOTO
SET sum=x+y+z
^
<BREAK>SUB1+1^SUB1
3d0>GOTO
QUIT
^
<BREAK>SUB1+2^SUB1
3d0>GOTO
sum=15
QUIT
^
<BREAK>MAIN+3^MAIN
2d0>GOTO
%SYS>

プログラマ・モードでの NEW コマンド

引数なしの NEW コマンドは、事実上すべての記号をシンボル・テーブルに格納します。したがって、空のシンボル・テーブルを実行できます。エラーあるいは BREAK の発生後にプログラマ・モードに戻ったとき、このコマンドが特に役立ちます。

シンボル・テーブルの妨げにならずに他のルーチンを実行するには、プログラマ・モードで引数なしの NEW コマンドを発行します。その後、システムは以下を実行します。

• プログラム・スタックにプログラマ・モード・フレームをスタックします。

• プログラマ・モードに戻ります。

例えば以下のようになります。

4d0>NEW
5B1>DO ^%T
3:49 PM
5B1>QUIT 1
4d0>GOTO

5B1> プロンプトは、システムが BREAK から入ったプログラマ・モードをスタックしたことを示します。1 は、NEW コマンドが変数情報をスタックしたことを示し、この変数情報は、QUIT 1 を発行することで削除できます。実行を再開する場合は、QUIT 1 を発行して古いシンボル・テーブルをリストアし、GOTO を発行して実行を再開します。

NEW コマンド、パラメータ渡し、ユーザ定義関数を使用するたびに、システムは情報をスタックに格納し、後で現在のサブルーチンまたは XECUTE レベルの明示的または暗黙的 QUIT により特定の編集を削除して他の値をリストアする必要があることを示します。

プログラマ・モードでは、NEW コマンド、パラメータ渡し、ユーザ定義関数が実行されたかどうか (その結果一部の変数がスタックされます)、また実行された場合、既存情報をどのスタックまで戻すかどうかがわかると役立ちます。

プログラマ・モードでの QUIT コマンド

プログラマ・モードで引数なしの QUIT コマンドを入力すると、すべての項目をプログラム・スタックから削除できます。

4f0>QUIT
%SYS>

プログラム・スタックからいくつかの項目のみを除外するには (例えば、現在実行中のサブルーチンから出て、前の DO レベルに戻る場合)、整数の引数で QUIT を使用します。例えば、QUIT 1 はプログラム・スタックの最後の項目を削除し、QUIT 3 は最後の 3 つの項目を削除します。以下はそのコード例です。

9f0>QUIT 3
6d0>

Caché エラー・メッセージ

Caché は、<ERROR> のように、<> 山括弧内にエラー・メッセージを表示します。その後には、エラー発生時にルーチンが実行していた行の参照が続きます。キャレット記号 (^) は、行参照とルーチンを区切ります。また、エラー発生時に実行するコマンドの最初の文字の下に、キャレット記号と共に中間コード行が表示されます。例えば以下のようになります。

SET x=y+3 DO ^ABC
^
<UNDEFINED>label+3^rou

このエラー・メッセージは、rou ルーチンの label+3 行で、<UNDEFINED> エラー (変数 y への参照) が発生したことを示しています。この時点で、このメッセージも特殊変数 $ZERROR の値となります。

%STACK の実行

以下のコマンドを入力して、%STACK を実行します。

%SYS>DO ^%STACK

この例で示されているように、%STACK ユーティリティは、変数を持たない現在のプロセス・スタックを表示します。

Level  Type     Line                   Source 
  1   SIGN ON 
  2   DO                                 ~DO ^StackTest 
  3   NEW ALL/EXCL                       NEW (E) 
  4   DO                 TEST+1^StackTest          SET A=1 ~DO TEST1 QUIT  ;level=2 
  5   NEW                                NEW A 
  6   DO                TEST1+1^StackTest          ~DO TEST2 ;level = 3 
  7   ERROR TRAP                         SET $ZTRAP="TrapLabel^StackTest" 
  8   XECUTE            TEST2+2^StackTest  ~XECUTE "SET A=$$TEST3()" 
  9   $$EXTFUNC                ^StackTest ~SET A=$$TEST3() 
 10   PARAMETER                          AA 
 11   DIRECT BREAK      TEST3+1^StackTest          ~BREAK 
 12   DO                       ^StackTest ~DO ^%STACK 

現在の実行スタック表示の下で、%STACK により、スタックの表示動作を求めるプロンプトが表示されます。“Stack Display Action” プロンプトで疑問符 (?) を入力すると、ヘルプを表示できます。

プロセス実行スタックの表示

“Stack Display Action” で入力した内容によって、以下の 4 種類の形式で現在のプロセス実行スタックを表示できます。

• *F を入力にすると、変数なしのスタックを表示

• *V を入力すると、特定の変数付きスタックを表示

• *P を入力すると、すべての変数付きスタックを表示

• *A を入力すると、プロセス状態変数リストに先行するすべての変数付きスタックを表示

特定の変数付きスタックの表示

“Stack Display Action” プロンプトで、*V を入力し、その後にスタックから記録したい変数名を入力します。以下の例では、変数 e は記録され、“Device:” プロンプトで RETURN キーを押すと画面に表示されます。

Stack Display Action: *V 
Variable(s):e
Display on Device: <RETURN>

スタックの表示の理解

スタックの各項目は、フレーム と呼ばれます。以下のテーブルは、各フレームに提供される情報を示します。

以下のテーブルは、各フレーム・タイプごとにレベル、行、ソース値が使用できるかどうかを示します。レベルの下の "No" は、レベル番号がインクリメントされず、表示されないことを示します。

%STACK 表示からの移動

%STACK 表示が複数画面にわたる場合、画面の左下にプロンプト “-- more --” が表示されます。最後のページには、プロンプト “-- fini --” が表示されます。? を入力すると、%STACK 表示内での移動に使用するキー操作が表示されます。

- - - Filter Help - - -
<space> Display next page. 
<return> Display one more line. 
T Return to the beginning of the output. 
B Back up one page (or many if arg>1). 
R Redraw the current page. 
/text Search for \qtext\q after the current page. 
A View all the remaining text. 
Q Quit. 
? Display this screen 
# specify an argument for B, L, or W actions. 
L set the page length to the current argument. 
W set the page width to the current argument.

“-- more --” あるいは “-- fini --” プロンプトが表示される場合は常に、上記に表示されたいずれかのコマンドを入力します。

B、L、W コマンドを入力する場合、コマンド文字の前に数値引数を入力します。例えば、2B と入力すると 2 ページ前に戻ります。また、20L を入力すると、20 行の長さにページが設定されます。

ページは、実際に表示される行数に合わせて設定してください。そうしない場合、ページを上下すると一部の行が表示されない可能性があります。既定のページの長さは 23 です。

特定のスタック・レベルでの変数の表示

指定されたスタック・フレーム・レベルに存在する変数を表示するには、“Stack Display Action” プロンプトで ?# と入力します。# には、スタック・フレーム・レベルを入力します。以下の例は、レベル 1 の変数を要求した場合の表示を示します。

Stack Display Action: ?1 
The following Variables are defined for Stack Level: 1
E 
Stack Display Action:

変数付きのスタック・レベルの表示

“Stack Display Action” プロンプトに ?? と入力すると、すべてのスタック・レベルで定義された変数を表示できます。?? と入力した場合に表示される例は、以下のとおりです。

Stack Display Action: ?? 
Now loading variable information ... 19 
Base Stack Level: 5
A
Base Stack Level: 3
A B C D
Base Stack Level: 1
E
Stack Display Action:

$SYSTEM.OBJ.ShowReferences によるオブジェクトへの参照の表示

指定されたオブジェクトへの参照を格納したすべての変数をプロセスのシンボル・テーブルに表示するには、%SYSTEM.OBJOpens in a new tab クラスの ShowReferences(oref)Opens in a new tab メソッドを使用します。oref は指定されたオブジェクトの OREF (オブジェクト参照) です。OREF の詳細は、"Caché オブジェクトの使用法" の “登録オブジェクトを使用した作業” の章にある “OREF の基本” を参照してください。

エラー・トラップ・ユーティリティ

エラー・トラップ・ユーティリティ、%ETN と %ERN は、変数を格納し、エラーに関する他の適切な情報を記録することで、エラーの解析に役立ちます。

%ETN アプリケーション・エラー・トラップ

エラー・トラップを設定すると、アプリケーション・エラーの発生時、%ETN ユーティリティを実行できるため便利です。ユーティリティは、エラー時のジョブに関する重要な情報 (実行スタックや各変数の値など) を保存します。この情報はアプリケーションのエラー・ログに保存されており、%ERN ユーティリティを使用して表示するか、または管理ポータルの [アプリケーションエラーログの表示] ページ ([システム処理]→[システムログ]→[アプリケーションエラーログの表示]) を使用して確認できます。

以下のコードを使用して、このユーティリティにエラー・トラップを設定します。

SET $ZTRAP="^%ETN"

Note:

プロシージャでは、外部ルーチンに $ZTRAP を設定できません。この制限のため、プロシージャでは ^%ETN を使用できません (プロシージャであるクラス・メソッドを含む)。ただし、%ETN を呼び出すローカル・ラベルには $ZTRAP を設定できます。

エラーが発生し、%ETN ユーティリティを呼び出すと、以下のようなメッセージが表示されます。

Error has occurred: <SYNTAX> at 10:30 AM

%ETN は HALT コマンド (プロセスを終了) で終了するため、アプリケーション・モードでルーチンを使用している場合にのみ、%ETN エラー・トラップを設定できます。プログラマ・モードでは、エラーが発生したときに、ターミナルにエラーが表示され、デバッガ・プロンプトで直ちにエラーの分析を行えるので、便利です。以下のコードは、Caché がアプリケーション・モードの場合にのみ、エラー・トラップを設定します。

SET $ZTRAP=$SELECT($ZJ#2:"",1:"^%ETN")

%ERN アプリケーション・エラー・レポート

%ERN ユーティリティは、%ETN エラー・トラップ・ユーティリティによって記録されたアプリケーション・エラーを検証します。%ERN の使用の詳細は、このドキュメントの “エラー処理” の章の "%ERN を使用したアプリケーション・エラー・ログの表示" を参照してください。

以下のコードでは、すべての変数を “*LOAD” でロードしてからルーチンをロードすることを示すために、ルーチン REPORT の ZLOAD が発行されています。エラー発生時、DO に関する情報などを記録するプログラム・スタックが空でない場合、ジョブの状態を再現できます。

%SYS>DO ^%ERN

For Date: 4/30/2018   3 Errors

Error: ?L

1) "<DIVIDE>zMyTest+2^Sample.MyStuff.1"  at 10:27 am.   $I=|TRM|:|10044   ($X=0  $Y=17)
     $J=10044  $ZA=0   $ZB=$c(13)   $ZS=262144 ($S=268242904)
               WRITE 5/0

2) <SUBSCRIPT>REPORT+4^REPORT at 03:16 pm. $I=|TRM|:|10044   ($X=0  $Y=57)
     $J=10044  $ZA=0   $ZB=$c(13)   $ZS=2147483647 ($S=2199023047592)
 SET ^REPORT(%DAT,TYPE)=I

3) <UNDEFINED>zMyTest+2^Sample.MyStuff.1 *undef"  at 10:13 pm.   $I=|TRM|:|12416   ($X=0  $Y=7)
     $J=12416  $ZA=0   $ZB=$c(13)   $ZS=262144 ($S=268279776)
               WRITE undef

Error: 2

2) <SUBSCRIPT>REPORT+4^REPORT at 03:16 pm. $I=|TRM|:|10044   ($X=0  $Y=57)
     $J=10044  $ZA=0   $ZB=$c(13)   $ZS=2147483647 ($S=2199023047592)
 SET ^REPORT(%DAT,TYPE)=I

Variable: %DAT
  %DAT="Apr 30 2018" 

Variable: TYPE
  TYPE="" 

Variable: *LOAD
%SYS>ZLOAD REPORT

%SYS>WRITE

%DAT="Apr 30 2018"
%DS=""
%TG="REPORT+1"
I=88
TYPE=""
XY="SET $X=250 WRITE *27,*91,DY+1,*59,DX+1,*72 SET $X=DX,$Y=DY"
%SYS>