データ型クラスの定義

データ型クラスの概要

データ型クラスの目的は、オブジェクト・クラスのリテラル・プロパティのタイプとして使用されることです。データ型クラスには、以下の機能があります。

• SQL 論理操作、クライアント・データ型、および変換情報の提供による、SQL、ODBC、ActiveX および Java の相互運用性

• データ型クラス・パラメータを使用して拡張、またはカスタマイズできるリテラル・データ値の妥当性検証

• これらは、(ディスク上に) 格納された、論理 (メモリ内) 形式、および表示形式に対するリテラル・データの変換を管理します。

データ型クラスを使用した、コンパイラによるプロパティのコード生成の詳細は、“プロパティ・メソッド” の章を参照してください。

データ型は他のクラスとは異なる点がいくつかあります。

• 独立してインスタンス化されたり、格納することはできません。

• プロパティを持つことはできません。

• 以下に示すような特定のメソッド (データ型インタフェース) に対応します。

内部の詳細をいくらかでも知っていると役に立つので、このセクションでは、データ型クラスがどのように機能するかについて、手短に説明します。

前述のように、データ型クラスの目的はプロパティのタイプとして (特に重要なオブジェクト・クラスの 1 つを拡張するクラス内で) 使用されることです。3 つのプロパティを持っているオブジェクト・クラスの例を以下に示します。各プロパティは、プロパティのタイプとしてデータ型クラスを使用します。

Class Datatypes.Container Extends %RegisteredObject
{

Property P1 As %String;

Property P2 As %Integer;

Property P3 As %Boolean;

}

データ型クラスのパラメータ

クラス・パラメータは、データ型クラスで使用されるときに、特別な振る舞いをします。データ型クラスでは、クラス・パラメータはデータ型に基づいてプロパティの動作をカスタマイズする方法を提供するために使用されます。

例えば、%IntegerOpens in a new tab データ型クラスは、クラス・パラメータ MAXVAL を持ち、%IntegerOpens in a new tab 型のプロパティに対して最大有効値を指定します。プロパティ NumKids を持つクラスを、以下のように定義した場合、

Property NumKids As %Integer(MAXVAL=10);

これは、%IntegerOpens in a new tab クラスの MAXVAL パラメータを、NumKids プロパティに対して 10 に設定することを指定します。

内部的には、標準データ型クラスに対するすべての検証メソッドは、メソッド・ジェネレータとして実装され、さまざまなクラス・パラメータを使用して、これらの検証メソッドの生成を制御します。この例では、このプロパティ定義は、NumKids の値が 10 を超えるか否かをテストする NumKidsIsValid() メソッドに対してコンテンツを作成します。クラス・パラメータを使用せずにこの機能を作成するには、IntegerLessThanTen クラスの定義が必要です。

データ型クラスの定義

データ型クラスを簡単に定義するには、まず自分の要求に近い既存のデータ型クラスを特定します。このクラスのサブクラスを作成します。サブクラスで以下を実行します。

• キーワード SqlCategory、ClientDataType、および OdbcType に適切な値を指定します。

• 必要に応じて、クラス・パラメータをオーバーライドします。例えば、MAXLEN パラメータをオーバーライドして、プロパティの長さを無制限にすることもできます。

  必要に応じて、ユーザ独自のクラス・パラメータを追加します。

• 必要に応じて、データ型クラスのメソッドをオーバーライドします。必要に応じて、実装時にこのクラスのパラメータを参照します。

データ型クラスが既存のデータ型クラスに基づいていない場合は、必ずクラス定義に [ ClassType=datatype ] を追加してください。クラスが別のデータ型クラスに基づく場合、この宣言は必要ありません。

データ型クラスのクラス・メソッドの定義

要求の内容に応じて、以下に示すデータ型クラスのクラス・メソッドの一部または全部を定義します。

• IsValid() — 必要に応じてプロパティ・パラメータを使用して、プロパティのデータの検証を行います。前述したように、オブジェクト・クラスの %ValidateObject() インスタンス・メソッドは、各プロパティの IsValid() メソッドを呼び出します。このメソッドには、以下のシグニチャがあります。

  ClassMethod IsValid(%val) As %Status 
  

  

  %val は検証される値です。このメソッドは、値が無効の場合にはエラー・ステータスを返し、それ以外の場合には $$$OK を返します。

  Note:

  NULL 値に対しては検証ロジックを呼び出さないのが Caché での標準的なやり方です。

• Normalize() — プロパティのデータを標準フォームまたは標準形式に変換します。オブジェクト・クラスの %NormalizeObject() インスタンス・メソッドは、各プロパティの Normalize() メソッドを呼び出します。このメソッドには、以下のシグニチャがあります。

  ClassMethod Normalize(%val) As Type 
  

  

  %val は検証される値、Type は適切なタイプのクラスです。

• DisplayToLogical() — 表示値を論理値に変換します。(形式の詳細は、“データ形式” を参照してください。)このメソッドには、以下のシグニチャがあります。

  ClassMethod DisplayToLogical(%val) As Type 
  

  

  %val は変換される値、Type は適切なタイプのクラスです。

  その他の形式変換メソッドには、同様の一般的な形式があります。

• LogicalToDisplay() — 論理値を表示値に変換します。

• LogicalToOdbc() — 論理値を ODBC 値に変換します。

  ODBC の値は、データ型クラスの OdbcType クラス・キーワードで指定された ODBC のタイプと一致している必要があります。

• LogicalToStorage() — 論理値をストレージ値に変換します。

• LogicalToXSD() — 論理値を SOAP でエンコードされた適切な値に変換します。

• OdbcToLogical() — ODBC 値を論理値に変換します。

• StorageToLogical() — データベースのストレージ値を論理値に変換します。

• XSDToLogical() — SOAP でエンコードされた値を論理値に変換します。

データ型クラスに DISPLAYLIST パラメータと VALUELIST パラメータが含まれる場合、これらのメソッドは、最初にこれらのクラスのパラメータが存在するかを確認し、存在する場合は、これらのリストを処理するコードを含める必要があります。このロジックは、その他のメソッドと類似しています。

ほとんどの場合、これらのメソッドの多くはメソッド・ジェネレータです。このドキュメントで後述の “メソッド・ジェネレータとトリガ・ジェネレータの定義” を参照してください。

以下に例を示します。

ClassMethod LogicalToDate(%val As %MV.Date) As %Library.Date [ CodeMode = expression, ServerOnly = 1 ]
{
$s(%val="":"",1:%val+46385)
}

データ型クラスのインスタンス・メソッドの定義

データ型クラスには、インスタンス・メソッドを追加することもできます。これらのメソッドは、プロパティの現在の値を含む変数 %val を使用できます。コンパイラはこれらを使用して、データ型クラスを使用するクラスの関連プロパティ・メソッドを生成します。例えば、以下のデータ型クラスの例を考えてみます。

Class Datatypes.MyDate Extends %Date
{

Method ToMyDate() As %String [ CodeMode = expression ]
{
$ZDate(%val,4)
}
}

以下に示す、別のクラスがあるとします。

Class Datatypes.Container Extends %Persistent
{

Property DOB As Datatypes.MyDate;

/// additional class members
}

これらのクラスをコンパイルすると、Caché によって DOBToMyDate() インスタンス・メソッドがコンテナ・クラスに追加されます。このメソッドは、後でコンテナ・クラスのインスタンスを作成するときに呼び出すことができます。以下に例を示します。

SAMPLES>set instance=##class(Datatypes.Container).%New()
 
SAMPLES>set instance.DOB=+$H
 
SAMPLES>write instance.DOBToMyDate()
30/10/2014