LOCK

引数なしの LOCK

引数なしの LOCK は、プロセスによって現在保持されているロックをすべて解除 (アンロック) します。これにはローカルとグローバルの両方の、排他ロックと共有ロックが含まれます。また、累積した増分ロックもすべて含まれます。例えば、任意のロック名に 3 つの増分ロックが設定されている場合、Caché は 3 つのロックすべてを解除し、ロック・テーブルからそのロック名のエントリを削除します。

トランザクション中に引数なし LOCK を発行すると、Caché は現在プロセスにより保持されているすべてのロックを、トランザクションの終わりまでロック解除状態にします。トランザクションが終了すると、Caché はロックを解除し、対応するロック名のエントリをロック・テーブルから削除します。

以下の例は、トランザクション中のさまざまなロックに適用され、それらすべてのロックを解除するために引数なし LOCK を発行します。ロックは、トランザクションの終了までロック解除状態になります。HANG コマンドを実行すると、ロック・テーブルにあるロックの ModeCount を確認する時間を取ることができます。

  TSTART
  LOCK +^a(1)      // ModeCount: Exclusive
  HANG 2
  LOCK +^a(1)#"E"  // ModeCount: Exclusive/1+1e
  HANG 2
  LOCK +^a(1)#"S"  // ModeCount: Exclusive/1+1e,Shared
  HANG 2
  LOCK             // ModeCount: Exclusive/1+1e->Delock,Shared->Delock
  HANG 10
  TCOMMIT          // ModeCount: locks removed from table

引数なし LOCK は、プロセスにより保持されているすべてのロックを、ロックを適用せずに解除します。プロセスを完了することでも、そのプロセスに保持されているすべてのロックを解除することができます。

引数付きの LOCK

引数付きの LOCK は、ロックとアンロックのオペレーションを行う、1 つまたは複数のロック名を指定します。Caché が行うロック・オペレーションは、使用するロック・オペレーション・インジケータ引数により異なります。

• LOCK lockname は、プロセスにより事前に保持されていたすべてのロックをアンロックし、指定されたロック名にロックを適用します。

• LOCK +lockname は、前のすべてのロックをアンロックすることなく、指定されたロック名にロックを適用します。これにより、さまざまなロックを累積させて、増分ロックを同じロックに適用できます。

• LOCK -lockname は、アンロック・オペレーションを、指定されたロック名に対して実行します。アンロックは、指定されたロック名に対するロック・カウントをデクリメントします。このロック・カウントが 0 までデクリメントされると、ロックは解除されます。

ロック・オペレーションは、即時にロックを適用する場合もあれば、別のプロセスによる競合ロックが解除されるまでロック要求を待機キューで保留にする場合もあります。待機中のロック要求は (タイムアウトが指定されていれば) タイムアウトする場合もあり、無制限に (プロセスの終了まで) 待機する場合もあります。

pc

コマンドを条件付きにする、オプションの後置条件式です。Caché は、後置条件式が True (0 以外の数値) の場合に LOCK コマンドを実行します。Caché は、後置条件式が False (0 に評価される) の場合はコマンドを実行しません。引数なしの LOCK コマンドまたは引数付きの LOCK コマンドには、後置条件式を指定できます。詳細は、"Caché ObjectScript の使用法" の "コマンド後置条件式" を参照してください。

lock operation indicator

ロック・オペレーション・インジケータは、ロックの適用 (ロック) または削除 (アンロック) に使用されます。これは以下のいずれかの値を指定できます。

LOCK コマンドに、複数のコンマ区切りのロック引数が含まれる場合、各ロック引数は、独自のロック・オペレーション・インジケータを持つことができます。Caché はこれを、複数の非依存 LOCK コマンドとして解析します。

lockname

lockname はデータ・リソースのロックの名前であり、データ・リソースそのものではありません。つまり、プログラムは ^a(1) という名前のロックと、^a(1) という変数を競合なく使用できます。ロックとデータ・リソースの間の関係は、プログラミングの規約です。規約により、プロセスは対応するデータ・リソースを変更する前にロックを獲得する必要があります。

ロック名は、大文字と小文字を区別します。ロック名は、対応するローカル変数およびグローバル変数と同じ命名規則に従います。ロック名は、添え字付きでも添え字なしでもかまいません。ロックの添え字は、変数の添え字と同じ命名規則、最大長、およびレベル数を持ちます。Caché では、a、a(1)、A(1)、^a、^a(1,2)、^A(1,1,1) はすべて、有効で一意なロック名です。詳細は、"Caché ObjectScript の使用法" の "変数" の章を参照してください。

ロック名は、ローカル、グローバルのどちらにもできます。A(1) などのロック名は、ローカル・ロック名です。これは、使用しているプロセスだけに適用されますが、ネームスペース全体に適用されます。キャレット記号 (^) で開始するロック名は、グローバル・ロック名です。このロックに対するマッピングは、対応するグローバルと同じマッピングに従います。つまり、プロセス全体に適用でき、同じリソースへのプロセスのアクセスを制御するということです ("Caché グローバルの使用法" の "グローバル構造" 参照)。

ロック名はローカル、またはグローバル変数で、添え字付き、または添え字なしで表されます。また、暗黙のグローバル参照、または他のコンピュータのグローバルへの拡張参照も可能です ("Caché グローバルの使用法" の "グローバル構造" 参照)。

ロック名に対応するデータ・リソースが存在する必要はありません。例えば、同じ名前を持つグローバル変数の有無に関係なく、ロック名 ^a(1,2,3) をロックできます。ロックとデータ・リソースの間の関係は、合意された規約であるため、ロックはまったく異なる名前を持つデータ・リソースを保護するために使用できます。

locktype

適用または削除するロックのタイプを指定する文字コードです。locktype はオプションの引数です。locktype を省略する場合、ロック・タイプは既定では排他の非エスカレート・ロックになります。locktype を省略する場合、ポンド記号 (#) 接頭語を省略する必要があります。locktype を指定する場合、ロック・タイプの構文は、必須のポンド記号 (#)　に、1 つ以上のロック・タイプ文字コードを囲む引用符が続きます。ロック・タイプ文字コードは順不同で指定でき、大文字と小文字の区別をしません。以下は、ロック・タイプ文字コードです。

• S ： 共有ロック

  同じリソース上で、競合しないロックを同時に保持するための複数のプロセスを許可します。例えば、2 つ (またはそれ以上) のプロセスは、同じリソース上で共有ロックを同時に保持しますが、排他ロックはリソースを 1 つのプロセスに制限します。既存の共有ロックがあると、他のすべてのプロセスの排他ロックは適用できなくなります。また既存の排他ロックがあると、他のプロセスの共有ロックは適用できなくなります。しかし、プロセスでまずリソースに共有ロックを適用し、その同じプロセスでリソースに排他ロックを適用することで、ロックを共有から排他にアップグレードできます。共有と排他ロックのカウントは、独立しています。したがって、そのようなリソースを解除するためには、排他ロックと共有ロックの両方を解除する必要があります。共有 (“S”) として指定されていないすべてのロックとアンロックのオペレーションは、排他が既定です。

  共有ロックはインクリメントである場合があります。つまり、同じリソースにおいて複数の共有ロックがプロセスによって発行される場合があります。ロックおよびアンロック時に、共有ロックをエスカレート (“SE”) として指定できます。共有ロックのアンロック時に、アンロックを即時 (“SI”) または遅延 (“SD”) として指定できます。エスカレート・ロックおよび非エスカレート・ロックのタイプにおけるインクリメント数と共に現在の共有ロックを表示するには、"Caché ObjectScript の使用法" の “Lock Management” の章で説明されているシステム全体のロック・テーブルを参照してください。

• E ： エスカレート・ロック

  ロック・テーブルをオーバーフローさせることなく、同時ロックの最大数を適用できます。既定では、ロックは非エスカレートです。ロックの適用時に、locktype “E” を使用して、そのロックをエスカレートとして指定できます。エスカレート・ロックのリリース時には、アンロック文で locktype “E” を指定する必要があります。排他ロックと共有 (“S”) ロックの両方をエスカレートと指定できます。

  一般に、同じ添え字レベルで多数の同時ロックを適用する場合に、エスカレート・ロックを使用することになります。例えば、LOCK +^mylock(1,1)#"E",+^mylock(1,2)#"E",+^mylock(1,3)#"E"... のようになります。

  同じロックを、非エスカレート・ロックおよびエスカレート・ロックとして同時に適用することができます。例えば、^mylock(1,1) や ^mylock(1,1)#"E" のようにすることができます。Caché は、ロック・テーブルで locktype “E” を指定して発行されたロックを個別にカウントします。ロック・テーブルでエスカレート・ロックおよび非エスカレートロックがどのように表示されるかについての詳細は、"Caché ObjectScript の使用法" の “ロック管理” の章を参照してください。

  添え字レベルの “E” ロックの数がしきい値に達すると、その添え字レベルで要求される次の “E” ロックは親ノード (次に高位の添え字レベル) を自動的にロックしようとします。不可能な場合は、エスカレーションは発生しません。親ノードのロックに成功すると、1 つの親ノードのロックが下位の添え字レベルのロックの数 + 1 に対応するロック・カウントで設定されます。下位の添え字レベルのロックは解除されます。その後の下位の添え字レベルへの “E” ロックの要求は、この親ノードのロックのロック・カウントをさらにインクリメントします。親ノードのロック・カウントを 0 にデクリメントし、下位の添え字レベルにエスカレーション解除するには、適用済みのすべての “E” ロックを解除する必要があります。ロックの既定のしきい値は 1000 ロックです。1001 番目のロックが要求されると、ロックのエスカレーションが発生します。

  ロックがエスカレートすると、ロック・オペレーションは、ロックされた特定のリソースではなく、適用されたロックの数のみを保持することに注意してください。そのため、ロックした同じリソースのロック解除に失敗すると、“E” ロックのカウントが同期されなくなります。

  以下の例では、プログラムがロックしきい値 + 1 の “E” ロックを適用すると、ロックのエスカレーションが発生します。この例では、ロックのエスカレーションにより、次に高い添え字レベルにおいてロックが適用されると同時に、下位の添え字レベルにおいてロックが解除されることを示しています。

  Main
    TSTART
    SET thold=$SYSTEM.SQL.GetLockThreshold()
    WRITE "lock escalation threshold is ",thold,!
    SET almost=thold-5
    FOR i=1:1:thold+5 { LOCK +dummy(1,i)#"E"
       IF i>almost {
         IF ^$LOCK("dummy(1,"_i_")","OWNER") '= "" {WRITE "lower level lock applied at ",i,"th lock ",! }
         ELSEIF ^$LOCK("dummy(1)","OWNER") '= ""   {WRITE "lock escalation",!
                                                    WRITE "higher level lock applied at ",i,"th lock ",!
                                                    QUIT }
         ELSE {WRITE "No locks applied",! }
       }
    }
    TCOMMIT

  

  ロック・エスカレーションに対してカウントされるのは “E” ロックだけであることに注意してください。以下の例では、既定 (非 “E”) のロックと “E” ロックの両方を同じ変数に設定します。ロックのエスカレーションは、変数における “E” ロックの合計数がロックしきい値に達した場合にのみ発生します。

  Main
    TSTART
    SET thold=$SYSTEM.SQL.GetLockThreshold()
    WRITE "lock escalation threshold is ",thold,!
    SET noE=17
    WRITE "setting ",noE," non-escalating locks",!
    FOR i=1:1:thold+noE { IF i < noE {LOCK +a(6,i)}
                    ELSE {LOCK +a(6,i)#"E"}
      IF ^$LOCK("a(6)","OWNER") '= "" {
         WRITE "lock escalation on lock a(6,",i,")",!
         QUIT }
    }
    TCOMMIT

  

  “E” ロックのロック解除は、上記の逆です。ロックがエスカレーションされている場合、子のレベルでのロック解除は、ゼロに達してロック解除されるまで親ノードのロックのロック・カウントをデクリメントします。これらのロック解除はカウントをデクリメントし、特定のロックとは一致しません。親ノードのロック・カウントが 0 に達すると、親ノードのロックが削除され、“E” ロックが下位の添え字レベルへとエスカレーション解除されます。それ以降の下位の添え字レベルのロックは、そのレベルで固有のロックを作成します。

  “E” locktype は、他の任意の locktype と組み合わせることができます。例えば、“SE”、“ED”、“EI”、“SED”、“SEI” などです。“I” locktype と組み合わせると、現在のトランザクションの最後ではなく、呼び出された直後に “E” ロックを解除できます。この “EI” locktype は、ロックがエスカレートされる状況を最低限に抑えることができます。

  通常、“E” ロックは、トランザクション内の SQL INSERT、UPDATE、および DELETE 処理において自動的に適用されます。ただし、“E” ロックをサポートする SQL データ定義構造について固有の制限事項が存在します。詳細は、固有の SQL コマンドを参照してください。

• I ： 即時アンロック

  トランザクションの終了まで待つのではなく、ロックを即時に解除します。

  • 非増分 (ロック・カウント 1) ロックのアンロック時に “I” を指定すると、ロックは即時に解除されます。既定では、アンロックは非増分ロックを即時に解除しません。代わりに、非増分ロックをアンロックすると、Caché はそのロックを、トランザクションの終了までロック解除状態に維持します。“I” を指定すると、この既定の動作はオーバーライドされます。

  • 増分ロック (ロック・カウント > 1) のアンロック時に “I” を指定すると、増分ロックは即時に解除され、ロックカウントは 1 だけデクリメントされます。これは増分ロックの既定のアンロックと同じ動作です。

  “I” locktype は、トランザクション中にアンロックを実行する場合に使用します。これには、ロックがトランザクションの内部または外部のどちらで適用されたかに関係なく、Caché のアンロック動作に対して同じ効果があります。“I” locktype は、アンロックがトランザクションの外部で行われる場合は、オペレーションを実行しません。トランザクションの外部では、アンロックは必ず指定されたロックを即時に解除します。

  “I” は、アンロック・オペレーションにのみ指定できます。ロック・オペレーションには指定できません。“I” は、共有ロック (#"SI") または排他ロック (#"I") のアンロックに指定できます。Locktypes “I” および “D” は、相互排他的です。“IE” は、エスカレート・ロックの即時アンロックに使用できます。

  この即時アンロックを以下の例で示します。

    TSTART
    LOCK +^a(1)      // apply lock ^a(1)
    LOCK -^a(1)      // remove (unlock) ^a(1)
                     // An unlock without a locktype defers the unlock
                     // of a non-incremented lock to the end of the transaction.
    WRITE "Default unlock within a transaction.",!,"Go look at the Lock Table",!
    HANG 10          // This HANG allows you to view the current Lock Table
    LOCK +^a(1)      // reapply lock ^a(1)
    LOCK -^a(1)#"I"  // remove (unlock) lock ^a(1) immediately
                     // this removes ^a(1) from the lock table immediately
                     // without waiting for the end of the transaction
    WRITE "Immediate unlock within a transaction.",!,"Go look at the Lock Table",!
    HANG 10          // This HANG allows you to view the current Lock Table
                     // while still in the transaction
    TCOMMIT

  

• D ： 遅延アンロック

  アンロックされたロックをトランザクション中に解除するタイミングを制御します。アンロック状態は、そのロックの直前のアンロックの状態まで遅延されます。そのため、ロックをアンロックするときに locktype “D” を指定すると、そのトランザクション中のロックの履歴に応じて、即時アンロックになるか、またはトランザクションの終わりまでロック解除状態になるかのいずれかの結果になります。複数回ロック/アンロックされたロックの動作は、現在のトランザクション中に 1 回のみロックされたロックの動作とは異なります。

  “D” アンロックは、ロックを解除するアンロック (ロック・カウント 1) のみに有効であり、ロックをデクリメントするアンロック (ロック・カウント > 1) には無効です。ロックをデクリメントするアンロックは、常に即時に解除されます。

  “D” は、アンロック・オペレーションにのみ指定できます。“D” は、共有ロック (#"SD") または排他ロック (#"D") に指定できます。“D” は、エスカレート (“E”) ロックに指定できますが、当然ながらアンロックもエスカレート (“ED”) として指定する必要があります。ロック・タイプ “D” と “I” は、相互排他的です。

  トランザクション内でのこの “D” アンロックの使用を以下の例に示します。HANG コマンドを実行すると、ロック・テーブルにあるロックの ModeCount を確認する時間を取ることができます。

  ロックが現在のトランザクション中に 1 回のみ適用された場合、“D” はロックを即時に解除します。これは “I” の振る舞いと同じです。詳細は、以下の例を参照してください。

    TSTART
    LOCK +^a(1)      // Lock Table ModeCount: Exclusive
    LOCK -^a(1)#"D"  // Lock Table ModeCount: null (immediate unlock)
    HANG 10
    TCOMMIT

  

  現在のトランザクション中にロックが複数回適用された場合、“D” アンロックは直前のアンロック状態に戻します。

  • 最後のアンロックが標準アンロックであった場合、“D” アンロックは、その直前のアンロックの動作に戻します。つまり、トランザクションの終了までアンロックを遅延します。詳細は、以下の例を参照してください。

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)      // Lock Table ModeCount: Exclusive
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive->Delock
         WRITE "2nd unlock",! HANG 5
      TCOMMIT

    

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)      // Lock Table ModeCount: Exclusive->Delock
         WRITE "1st unlock",! HANG 5
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive->Delock
         WRITE "2nd unlock",! HANG 5
      TCOMMIT

    

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"I"  // Lock Table ModeCount: Exclusive/2
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)      // Lock Table ModeCount: Exclusive
         WRITE "2nd unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive->Delock
         WRITE "3rd unlock",! HANG 5
      TCOMMIT

    

  • 最後のアンロックが “I” アンロックであった場合、“D” アンロックは、その直前のアンロックの動作に戻します。つまり、ロックを即時にアンロックします。詳細は、以下の例を参照してください。

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"I"  // Lock Table ModeCount: null (immediate unlock)
         WRITE "1st unlock",! HANG 5
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"D"  // Lock Table ModeCount: null (immediate unlock)
         WRITE "2nd unlock",! HANG 5
      TCOMMIT

    

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"I"  // Lock Table ModeCount: Exclusive
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: null (immediate unlock)
         WRITE "2nd unlock",! HANG 5
      TCOMMIT

    

  • 最後のアンロックが “D” アンロックだった場合、“D” アンロックは直前の非 “D” ロックの動作に従います。

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: null (immediate unlock)
         WRITE "2nd unlock",! HANG 5
      TCOMMIT

    

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)      // Lock Table ModeCount: Exclusive/2
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive
         WRITE "2nd unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive->Delock
         WRITE "3rd unlock",! HANG 5
      TCOMMIT

    

      TSTART
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK +^a(1)      // Lock Table ModeCount: Exclusive
      LOCK -^a(1)#"I"  // Lock Table ModeCount: Exclusive/2
         WRITE "1st unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: Exclusive
         WRITE "2nd unlock",! HANG 5
      LOCK -^a(1)#"D"  // Lock Table ModeCount: null (immediate unlock)
         WRITE "3rd unlock",! HANG 5
      TCOMMIT

    

timeout

タイムアウト前に、ロックを待機する時間 (秒数) です。timeout はオプションの引数です。省略された場合、LOCK コマンドはリソースがロック可能になるまで無制限に待機します。ロックが適用できない場合、プロセスは停止します。timeout の構文には、必須のコロン (:) が最初にあり、その後に整数値や、整数値に評価される式が続きます。ゼロの値は、タイムアウトの前に 1 つのロックの試みを許可します。負の数は、ゼロと同様です。

通常、ロック要求が指定ロックを取得する (保持する) のを妨げる競合ロックが別プロセスに存在する場合、ロックは待機します。ロック要求は、ロックが解除されて競合が解決されるか、またはロック要求がタイムアウトになるまで待機します。プロセスを終了しても保留中のロック要求が終了します (削除されます)。ロックの競合は、別プロセスが保持するのと同じロックをあるプロセスが要求する場合だけでなく、さまざまな状況によって発生する場合があります。ロックの競合およびロック要求の待機状態の詳細は、"Caché ObjectScript の使用法" の “ロック管理” の章を参照してください。

timeout を使用し、ロックに成功した場合、Caché は特殊変数 $TEST を 1 (TRUE) に設定します。タイムアウト時間内にロックを適用できなかった場合、Caché は $TEST を 0 (FALSE) に設定します。timeout を指定せずにロック要求を出した場合、$TEST の現在値には何の影響を及ぼしません。$TEST は、ユーザが設定することもできます。また、JOB、OPEN、または READ のタイムアウトで設定されることもあります。

以下の例では、ロックをロック名 ^abc(1,1) に適用し、プロセスにより保持されている既存のすべてのロックをアンロックします。

  LOCK ^abc(1,1)

このコマンドは、排他ロックを要求します。他のプロセスは、このリソース上のロックを同時に保持することができません。他のプロセスが既にこのリソース上のロックを保持している場合 (排他、または共有)、この例では、ロックが解除されるまで待機する必要があります。プロセスを停止しながら、無制限に待機できます。この状態を避けるため、タイムアウト値を指定することを強くお勧めします。

  LOCK ^abc(1,1):10

LOCK により、コンマ区切りリストの lockname 引数を複数指定する場合、各 lockname リソースは専用の timeout (括弧なしの構文) を備えるか、または、指定した lockname リソースすべてが単一の timeout (括弧付きの構文) を共有することもできます。

• 括弧なし：各 lockname 引数には固有の timeout を指定できます。Caché はこれを複数の独立した LOCK コマンドとして解析するので、ロック引数の timeout は他のロック引数に影響を与えません。ロック引数は厳密に左から右の順で解析され、各ロック要求は、次のロック要求が試される前に、完了するかまたはタイムアウトします。

• 括弧付き：すべての lockname 引数で timeout を共有します。LOCK は、タイムアウト時間内にすべてのロック (またはアンロック) を正常に適用する必要があります。すべてのロックが成功する前にタイムアウト時間が経過した場合、LOCK コマンドで指定されたどのロック・オペレーションも実行されず、制御はプロセスに戻ります。

Caché は、厳密に左から右の順に複数のオペレーションを実行します。したがって、括弧なしの LOCK 構文では、$TEST の値は複数の lockname ロック要求の最後 (右端) の結果を示しています。

以下の例では、現在のプロセスは ^a(1) を、別のプロセスにより排他的にロックされているためロックできません。これらの例では、指定されたロックへの適用を 1 回試みることになる、タイムアウト 0 を使用しています。

最初の例は、^x(1) および ^z(1) をロックします。^z(1) がタイムアウト前に成功したので、これは $TEST=1 を設定します。

  LOCK +^x(1):0,+^a(1):0,+^z(1):0

2 番目の例は、^x(1) および ^z(1) をロックします。^z(0) がタイムアウトしたので、これは $TEST=1 を設定します。^z(1) はタイムアウトを指定していなかったため、$TEST に効果はありません。

  LOCK +^x(1):0,+^a(1):0,+^z(1):0

3 番目の例は、括弧で囲まれたロックのリストがアトミック (全か無か) オペレーションであるため、ロックを適用しません。^a(1) がタイムアウトしたので、これは $TEST=0 を設定します。

  LOCK +(^x(1),^a(1),^z(1)):0

自動アンロック

プロセスが終了すると、Caché は引数なしの暗黙の LOCK を実行して、そのプロセスが適用していたロックをすべて消去します。これにより保持されていたロックとロック待機要求の両方が削除されます。

ネットワークにおけるロック

ネットワーク・システムでは、1 つ、または複数のサーバがグローバル変数のロックを解決する役割を果たすことができます。

LOCK コマンドは、最大 255 までの、任意の数のサーバで使用できます。リモート・サーバ・システム上のクライアント・ジョブにより保持されるリモート・ロックは、クライアント・ジョブを削除するために ^RESJOB ユーティリティを呼び出すときに解除されます。