$EXTRACT

部分文字列を返す方法

$EXTRACT は string から文字位置により部分文字列を返します。部分文字列の抽出の特性は、使用するパラメータによって決まります。

• $EXTRACT(string) は、文字列の先頭文字を抽出します。

     SET mystr="ABCD"
     WRITE $EXTRACT(mystr)

  

• $EXTRACT(string,from) は、from で指定した位置の 1 文字を抽出します。from の値は、文字列の最初からカウントした整数、文字列の最後の文字を指定するアスタリスク、または、文字列の最後から逆方向にカウントして指定する負の整数を持つアスタリスクになります。

  以下の例では、文字列 “ABCD” から 1 つの文字を抽出します。

     SET mystr="ABCD"
     WRITE !,$EXTRACT(mystr,2)    // "B" the 2nd character
     WRITE !,$EXTRACT(mystr,*)    // "D" the last character
     WRITE !,$EXTRACT(mystr,*-2)  // "B" the offset 2 characters from end
     WRITE !,$EXTRACT(mystr,*-0)  // "D" the last character by 0 offset

  

• $EXTRACT(string,from,to) は、from の位置から始まり to の位置で終了する文字列の範囲 (その位置の文字を含む) を抽出します。例えば、変数 var2 が文字列 “1234Alabama567” を含むときは、以下の $EXTRACT 関数は両方とも文字列 “Alabama” を返します。

     SET var2="1234Alabama567"
     WRITE !,$EXTRACT(var2,5,11)
     WRITE !,$EXTRACT(var2,*-9,*-3)

  

string

部分文字列が識別されるターゲット文字列。

部分文字列を返すために $EXTRACT を使用する場合、string は、引用符で囲まれた文字列リテラル、キャノニック形式の数値、変数、オブジェクト・プロパティ、または評価結果が文字列または数値になる有効な ObjectScrip 式にできます。ターゲット文字列として NULL 文字列 ("") を指定すると、$EXTRACT はその他のパラメータ値に関係なく、常に NULL 文字列を返します。

1 つの部分文字列を置換するために、等号の左側で SET と共に $EXTRACT を使用する場合、string は変数名または 多次元プロパティ参照にすることができますが、非多次元オブジェクト・プロパティにすることはできません。

from

from パラメータは、単独の文字または文字の範囲の先頭を指定できます。

• from が n (正の整数) の場合、$EXTRACT は string の先頭から文字をカウントします。

• from が * (アスタリスク) の場合、$EXTRACT は string 内の末尾の文字を返します。

• from が *-n (アスタリスクとそれに続く負の整数) の場合、$EXTRACT は string の末尾からオフセット分だけ文字をカウントします。つまり、*-0 は string 内の末尾の文字になり、*-1 は string 内の最後から 2 番目の文字 (末尾からのオフセットが 1) になります。

• SET $EXTRACT 構文のみ — from が *+n (アスタリスクとそれに続く正の整数) の場合、SET $EXTRACT は string の末尾の先にオフセット分の文字を追加します。つまり、*+1 の場合は string の末尾の先に 1 つの文字が追加され、*+2 の場合は string の末尾の 2 つ先の位置に 1 つの文字が追加されます (末尾と追加位置の間には空白スペースが埋め込まれます)。*+0 は string 内の最後の文字です。

from の整数値が文字列内の文字数よりも大きいときは、$EXTRACT は NULL 文字列を返します。from に *-n 値を指定したときに、n が文字列の文字数以上になる場合、$EXTRACT は NULL 文字列を返します。from の値が 0 または負の数の場合、$EXTRACT は NULL 文字列を返します。ただし、from が to と共に使用されていると、0 または負の数になる from の値は、値 1 と見なされます。

from を to パラメータと共に使用するときは、from は抽出する範囲の先頭を識別します。また、to の値よりも小さくなくてはなりません。from が to と等しい場合、$EXTRACT は指定した位置にある 1 文字を返します。from が to よりも大きいときは、$EXTRACT は NULL 文字列を返します。to パラメータと共に使用するときは、1 未満の from の値 (ゼロか負の数) は 1 として扱われます。

to

to パラメータは from パラメータと共に使用する必要があります。正の整数、* (アスタリスク)、または *-n (アスタリスクとそれに続く負の整数) でなければなりません。to の値が from 以上の整数である場合、$EXTRACT は指定した部分文字列を返します。to の値がアスタリスクのときは、$EXTRACT は、from 文字から文字列の最後までを含む部分文字列を返します。to が文字列の長さより大きい整数の場合も、$EXTRACT は、from 文字から文字列の最後までの部分文字列を返します。

from と to の位置が同じ場合、$EXTRACT は単一の文字を返します。to の位置が from の位置よりも文字列の先頭に近い場合、$EXTRACT は NULL 文字列を返します。

to パラメータを省略すると、1 文字のみが返されます。from を指定すると、$EXTRACT は from により識別される文字を返します。to と from の両方を省略すると、$EXTRACT は string の最初の文字を返します。

SET $EXTRACT 構文のみ — to が *+n の場合、SET $EXTRACT は string の末尾の先にオフセット分の文字の範囲を追加します (必要に応じて、空白スペースが埋め込まれます)。from が string の末尾の後の文字位置を示している場合、SET $EXTRACT は文字を追加します。from が string の末尾の前の文字位置を示している場合、SET $EXTRACT は文字の置換と追加の両方を実行します。

*-n および *+n パラメータ値の指定

変数を使用して *-n または *+n を指定する場合は、常に、パラメータ自体でアスタリスクと符号文字を指定する必要があります。

*-n の有効な指定内容は以下のとおりです。

  SET count=2
  SET alph="abcd"
  WRITE $EXTRACT(alph,*-count)

  SET count=-2
  SET alph="abcd"
  WRITE $EXTRACT(alph,*+count)

*+n の有効な指定内容は以下のとおりです。

  SET count=2
  SET alph="abcd"
  SET $EXTRACT(alph,*+count)="F"
  WRITE alph

これらのパラメータ値内では、空白を使用できます。

例 ： 部分文字列を返す方法

以下の例は文字列の 4 番目の文字 “D” を返します。

   SET x="ABCDEFGHIJK"
   WRITE $EXTRACT(x,4)

以下の例は文字列の最後の文字 “K” を返します。

   SET x="ABCDEFGHIJK"
   WRITE $EXTRACT(x,*)

以下の例では、$EXTRACT 関数は、すべて文字列の最後から 2 番目の文字 “J” を返します。

   SET n=-1
   SET m=1
   SET x="ABCDEFGHIJK"
   WRITE !,$EXTRACT(x,*-1)
   WRITE !,$EXTRACT(x,*-m)
   WRITE !,$EXTRACT(x,*+n)
   WRITE !,$EXTRACT(x,*-1,*-1)

アスタリスクと整数変数の間には、マイナス記号かプラス記号が必要です。

以下の例は、from 値が “1” のとき、1-引数形式は 2-引数形式と等しいことを示しています。両方の $EXTRACT 関数は、“H” を返します。

   SET x="HELLO"
   WRITE !,$EXTRACT(x)
   WRITE !,$EXTRACT(x,1)

以下の例は、先頭から 7 番目の文字までの部分文字列 “THIS IS” を返します。

   SET x="THIS IS A TEST"
   WRITE $EXTRACT(x,1,7)

以下の例も、部分文字列 "THIS IS" を返します。from 変数が 1 未満の値を含むとき、$EXTRACT はその値を 1 として処理します。以下の例は、先頭から 7 番目の文字までの部分文字列を返します。

   SET X="THIS IS A TEST"
   WRITE $EXTRACT(X,-1,7)

以下の例は文字列の最後の 4 文字を返します。

   SET X="THIS IS A TEST"
   WRITE $EXTRACT(X,*-3,*)

また、以下の例は文字列の最後の 4 文字も返します。

   SET X="THIS IS A TEST"
   WRITE $EXTRACT(X,*-3,14)

以下の例では、オブジェクト・プロパティから部分文字列を抽出します。

  SET tStatement = ##class(%SQL.Statement).%New()
  SET tStatement.%SchemaPath="MyTests,Sample,Cinema"
  WRITE "whole schema path: ",tStatement.%SchemaPath,!
  WRITE "start of schema path: ",$EXTRACT(tStatement.%SchemaPath,1,10),!

$EXTRACT と Unicode

$EXTRACT 関数は、バイトではなく、文字を処理します。したがって、以下の例で示すように、Unicode の文字列は ASCII 文字列と同様に処理されます。以下の例では、"pi" ($CHAR(960)) に対して Unicode 文字を使っています。

   IF $SYSTEM.Version.IsUnicode()  {
     SET a="QT PIE"
     SET b="QT "_$CHAR(960)
     SET a1=$EXTRACT(a,-33,4)
     SET a2=$EXTRACT(a,4,4)
     SET a3=$EXTRACT(a,4,99)
     SET b1=$EXTRACT(b,-33,4)
     SET b2=$EXTRACT(b,4,4)
     SET b3=$EXTRACT(b,4,99)
     WRITE !,"ASCII form returns ",!,a1,!,a2,!,a3
     WRITE !,"Unicode form returns ",!,b1,!,b2,!,b3
   }
   ELSE {WRITE "This example requires a Unicode installation of Caché"}

Caché Unicode サポートの詳細は、"Caché ObjectScript の使用法" の "Unicode" を参照してください。

DTM モードでの $EXTRACT

DTM および DTM-J モードでは、$EXTRACT は、以下のようにさらに 2 つの引数をサポートします。

$EXTRACT(string,from,to,replace,pad)

オプションの replace 引数は、from および to によって指定される部分文字列を replace 部分文字列で置換し、その結果を返します。元の string は変更されません。

オプションの pad 引数は、埋め込み文字を指定します。これは、from 引数が string の最後を越える位置を指定するときに使用します。返される文字列は、from で指定された位置まで replace 部分文字列を後に続けて埋め込まれます。pad 値は任意の 1 文字となります。数値でない文字は引用符で囲む必要があります。引用符を埋め込み文字リテラルとして指定するには、これを二重にします。

%SYSTEM.ProcessOpens in a new tab クラスの LanguageMode()Opens in a new tab メソッドを使用すると、DTM モード (2) または DTM-J モード (7) を設定できます。

以下の例は、4 つの引数の置換構文を示します。

   SET x="ABCDEFGH"
   DO ##class(%SYSTEM.Process).LanguageMode(2)
   WRITE $EXTRACT(x,3,6,"##")
     /* returns "AB##GH"  */

以下の例は、置換文字列を追加する 4 つの引数の構文を示します。

   SET x="ABCDEFGH"
   DO ##class(%SYSTEM.Process).LanguageMode(2)
   WRITE $EXTRACT(x,1,0,"##")
     /* returns "##ABCDEFGH"  */

以下の例は、5 つの引数の埋め込みおよび置換構文を示します。

   SET x="ABCDEFGH"
   DO ##class(%SYSTEM.Process).LanguageMode(2)
   WRITE $EXTRACT(x,12,16,"##","*")
     /* returns "ABCDEFGH***##"  */

Note:

4 つの引数または 5 つの引数の構文を使用する場合、$EXTRACT の from 引数および to 引数は、アスタリスク構文をサポートしません。

SET $EXTRACT は、4 つの引数または 5 つの引数の構文では使用できません。

$PIECE と $LIST と比較した $EXTRACT コマンド

$EXTRACT は、文字列の最初の部分から文字をカウントすることにより、部分文字列を決定します。$EXTRACT は、入力として通常の任意の文字列を取ります。$PIECE と $LIST は両方とも、特別に用意された文字列を処理します。

$PIECE は、文字列内のユーザ定義の区切り文字をカウントすることにより、部分文字列を決定します。

$LIST は、リストの最初から要素 (文字ではない) をカウントすることにより、エンコードされたリストから要素を決定します。$LIST は、通常の文字列に対して使用できません。また、$EXTRACT は、エンコードされたリストに対して使用できません。