ターミナル入出力

主デバイスとなるログイン・ターミナルとコンソール

Caché へのログインに使用したターミナルやコンソールは、主デバイスです。ユーザ側で主デバイスを開く必要はありません。OPEN と USE が発行されていない場合、プロセスは最初にREAD または WRITE を発行します。OPEN 0 USE 0 が明示的に発行されたかのように、システムは自動的に主デバイスを開き、現在のデバイスとして確立します。

$X と $Y とカーソル位置

カーソルや印字ヘッドについて、$X は水平方向の位置情報、$Y は垂直方法の位置情報を持ちます。$X=0,$Y=0 は、CRT 画面あるいは印刷ページの上部左端を意味します。$X と $Y の両方について、Caché ではそのモジュロ 256 が計算されます。つまり、範囲は 0 から 255 で、その後は再度 0 から始まります。

以下のテーブルは、入力した文字とその入力に対する画面上の応答 (エコー) を示しています。

OPEN と USE の S プロトコルはエコーを無効にします。また、入力中の $X と $Y の変更も無効にします。したがって、これらの変数はカーソルの真の位置を示します。

$X と $Y の例

以下の例では、制御シーケンスは、VT100 ターミナルのカーソルを 10 行、20 列目に移動し、それに応じて $X と $Y を設定します。

 ; set DY and DX to desired 
 ; values for $Y and $X 
 SET DY=10
 SET DX=20
 ; ...
 ; escape sequence moves
 ; cursor to desired position
 WRITE *27, *91, DY+1, *59, DX+1, *72
 ; ...
 ; updates $X and $Y
 SET $Y=DY
 SET $X=DX

$X と $Y に対するエスケープ・シーケンスのさまざまな影響

エスケープ・シーケンスは、$X と $Y の値に対する効果を変更できます。この効果を制御する要因には、以下の 3 つがあります。

• 既定の動作を設定するオペレーティング・システム

• /NOXY ($X および $Y の処理を無効化) が、OPEN コマンドまたは USE コマンドに指定されたかどうか

• %SYSTEM.ProcessOpens in a new tab クラスの DX()Opens in a new tab メソッドを使用すると、$X による現在のプロセスのエスケープ・シーケンスの処理方法を設定できます。システム全体の既定の動作は、Config.MiscellaneousOpens in a new tab クラスの DXOpens in a new tab プロパティで設定できます。

$X と $Y に対するエスケープ・シーケンスの影響 (Windows システムおよび UNIX® システム)

既定の UNIX® と Windows では、ASCII のエスケープ文字 (10 進数値 27) を含む文字列を入力したときやそれに対するエコーが表示されるとき、他の文字シーケンスと同様に、Caché によって $X と $Y が更新されます。したがって、ターミナルで動作し、画面には表示されない ANSI 標準の制御シーケンスでは、$X と $Y の値とカーソル位置との関係に矛盾が生じます。

この問題を防ぐ一番簡単な方法は、その動作を変更する DX() メソッドを使用することです (次セクション参照)。あるいは Write * 文の文字列で、各文字の ASCII 値を使用できます。

制御シーケンスの例

以下のコードを考えます。

%SYS>WRITE $CHAR(27)_"[lm"

このコードを使用するかわりに、$X と $Y を更新しない以下の文を使用できます。

%SYS>WRITE *27,*91,*49,*109

エスケープ・シーケンスに対する $X の更新制御の変更

実際のプロセスで、既定ではない方法で $X を更新するには、%SYSTEM.ProcessOpens in a new tab クラスの DX(n)Opens in a new tab メソッドを発行します。

システム管理者は、Config.MiscellaneousOpens in a new tab クラスの DXOpens in a new tab プロパティを設定することによりシステム全体の既定の動作を変更できます。

いずれの場合も、n には以下のような 0 から 4 までの値を指定します。

値	$X を更新するための既定の動作
0	UNIX® と Windows での Caché の動作 (UNIX® と Windows での既定の動作)
1	DSM による動作
2	DTM/MSM による動作

詳細は、"ObjectScript ランゲージ・リファレンス" の "$X" を参照してください。

タイムアウト付き処理結果を示す $TEST

$TEST 特殊変数は、タイムアウト値を持つコマンドで設定されます。これらのコマンドには OPEN およびREAD があります。$TEST の値は、1 あるいは 0 に設定されます。

• タイムアウトになる前に時間制限コマンドが成功した場合、$TEST には 1 が設定されます。

• 時間制限コマンドがタイムアウトになった場合、$TEST には 0 が設定されます。

詳細は、"ObjectScript ランゲージ・リファレンス" の "$TEST" を参照してください。

READ のステータスを示す $ZA

$ZA 特殊変数にはビット・フラグがあり、現在のデバイスで最後に実行された READ のステータスを示します。ユーザは $ZA を設定できず、Caché がその値を制御します。$ZA の値は、次の READ が実行されるまで有効な状態で保持されます。以下のテーブルのように、$ZA 値には、この変数をプログラムがどのようにテストするのかを示す合計値が含まれます。($ZA 値には、モデム接続ステータス用のビット・フラグが含まれますが、ここに記載されていません。$ZA ビット・フラグの値の全リストについては、"ObjectScript ランゲージ・リファレンス" の "$ZA" を参照してください。)

$ZA がエラーを示す状況は数多くありますが、$ZTRAP 特殊変数にトラップすることによるプログラム・フローへの割り込みは発生しません。エラーに関連するプログラムは、READ を実行するたびに $ZA を検証する必要があります。当然、ブレークを有効にする Ctrl-C は、$ZTRAP にトラップします。エラー・トラップと $ZTRAP の詳細は、"Caché ObjectScript の使用法" の "エラー処理" の章と "ObjectScript ランゲージ・リファレンス" の "$ZTRAP" を参照してください。

READ の終了原因を示す $ZB

$ZB は、現在のデバイスで最後の READ 処理を終了させた文字シーケンスあるいはイベントを示します。ユーザ側で $ZB を設定することはできません。READ を実行するたびに、Caché によって $ZB の値が設定されます。この値を使用して、上向き矢印やファンクション・キーなど、出力されない文字を操作できます。

$ZB には、以下のいずれかが含まれます。

• キャリッジ・リターンなどの終端文字

• エスケープ・シーケンス

• 固定長 READ x#y の y 番目の文字

• READ *x の 1 文字

• 時間制限つきの READ がタイムアウトになったときの空文字列

$ZB に含まれる文字は、64 文字以下です。それを超える長さのエスケープ・シーケンスは無効です。

$ZB の例

以下の例は、ユーザ定義の入力文字を READ コマンド変数 x に割り当て、入力ターミネータ (通常は Enter) を $ZB 特殊変数に割り当てます。ターミナル・プロンプトからこのコマンドを発行する場合、READ コマンドと同じコマンド行で、$ZB 値をトラップする変数を設定する必要があります。コマンド行の作成に使用する改行は、終端文字として $ZB に記述されるからです。この例では、ZZDUMP を使用して $ZB でトラップされる文字の値を表示します。

USER>READ x SET y=$ZB
USER>ZZDUMP y

0000: 0D 
USER>

OPEN コマンド

ターミナルの所有権を構築します。オプションのパラメータ・リストでは、右マージンの設定、デバイス・プロトコルの指定、および 1 つ以上の終端文字の指定が可能です。以下のパラメータ・リストに従って、timeout 引数または mnespace 引数 (またはその両方) を必要に応じて指定できます。mnespace 引数は、WRITE /mnemonic で使用する制御ニーモニックを定義している Caché ルーチンを指定します。

OPEN は、デバイスが完全に開くまで、プロセスを休止します。Ctrl-C を押して OPEN コマンドに割り込むと、<NOTOPEN> エラーを生じます。

OPEN は、タイムアウトを指定しない限り、デバイスが開くまで制御を保持します。タイムアウトを設定している場合、指定した時間内にデバイスが開かないと $TEST が 0 に設定され、制御はプロセスに戻ります。オペレーティング・システム・レベルで無効なデバイスであっても、OPEN は、そのデバイスが正常に開くまで、またはタイムアウトになるまでデバイスの取得を続けます。

OPEN 構文

OPEN コマンドは、以下の引数をとります。

OPEN terminal:(margin:protocols:terminator:portstate:baud):timeout:"mnespace"

terminal 引数のみが必須です。terminal 引数には、値がターミナル・デバイス名となる式を指定することもできます。ゼロ (0) はプロセスの主デバイスを示します。$IO は現在のデバイスです。terminal の最大長は 256 文字です。

複数の引数はコロン (:) で区切ります。リスト内の引数を省略するには、プレースホルダとしてコロンを指定する必要があります。ただし、末尾にはコロンを使用できません。コマンドまたはパラメータ・リストの末尾にコロンを記述しないでください。

オプションのパラメータ・リストは括弧で囲み、次のオプション・パラメータを記述できます。

• margin は、右マージンを指定することにより行ごとの文字数を指定する整数です。

• protocols は、ターミナルのオプションを指定する 1 文字以上のコードです。

• terminator は、READ 処理を終了する 1 文字以上の文字列です。これらの文字は、特定の protocols に対して定義する終端文字を補足します。

• portstateは、COM ポート状態を指定する文字列です。

• baud は、COM ポートのボー・レートを指定する整数です。

これらのオプションのパラメータは、記述した順序による位置パラメータまたは /KEYWORD=value 構文によるキーワード・パラメータとして指定できます。キーワード・パラメータは、任意の順序で指定できます。Caché では、パラメータが左から右の順に実行されるので、パラメータ間の相互関係により優先の順序が決まる場合もあります。位置パラメータとキーワード・パラメータを同じパラメータ・リスト内で混在して使用することもできます。複数のパラメータを含む場合、それらを囲む括弧は必須です。

以下のパラメータ・リストは同じものです。

   OPEN $IO:(80:"BFU":$CHAR(13)) 
    ; all positional
   OPEN $IO:(80::$CHAR(13):/PARAMS="BFU") 
    ; mixed positional and keyword, using the /PARAMS keyword
    ; to specify a protocol letter code string.
   OPEN $IO:(/MARGIN=80:/TERMINATOR=$CHAR(13):/BREAK:/FLUSH:/UPCASE)
    ; all keyword, using separate keywords 
    ; for each protocol letter code.

パラメータ・リスト (パラメータ・リストを指定していない場合は代替のコロン) の後に、timeout の秒数をオプションで指定できます。また、このデバイスの制御ニーモニックを保持するルーチンを指定する mnespace 引数を指定できます。

詳細は、"ObjectScript ランゲージ・リファレンス" の "OPEN" を参照してください。

USE コマンド

指定されたターミナルを現在のデバイスにします。プログラマ・モードでは、同じコード行にある連続したすべての入出力コマンドが、そのデバイスを対象とします。アプリケーション・モードでは、USE コマンドで指定したデバイスが、次の USE コマンドまで現在のデバイスとなります。

USE terminal:(margin:protocols:terminator):"mnespace"

OPEN コマンドと USE コマンドの位置パラメータ

以下の位置パラメータは、OPEN コマンドと USE コマンドで使用できます。デバイスに対するこれらのパラメータは OPEN コマンドと USE コマンドのいずれでも設定できます。あるいは、管理ポータルで構成した既定の設定を使用することもできます。これらのパラメータは位置を示します。パラメータを省略すると、その代わりとして、前にコロンを置く必要があります。

portstate

第 4 位置パラメータ ： COM ポート状態を制御する最大 8 バイトの文字列で、それぞれのバイト位置に制御内容が割り当てられています。portstate バイトは、以下のとおりです (バイトは左から右の順に 1 から番号が付けられます)。

バイト	意味	値
1	切断	D = ポートを切断 (停止) する。空白 = ポートを切断しない。
2	モデム制御	1 = モデム制御を使用する。0 = モデム制御を使用しない。空白 = モデム制御を変更しない。
3	データ・ビット	5 = 5 データ・ビット。6 = 6 データ・ビット。7 = 7 データ・ビット。8 = 8 データ・ビット。空白 = データ・ビット設定を変更しない。
4	パリティ	0 = パリティなし。0 = 奇数パリティ。2 = 偶数パリティ。3 = マーク・パリティ。4 = スペース・パリティ。空白 = パリティ設定を変更しない。
5	ストップ・ビット	1 = 1 ストップ・ビット。5 = 1.5 ストップ・ビット。2 = 2 ストップ・ビット。空白 = ストップ・ビット設定を変更しない。
6	フロー制御	X = Xon/Xoff フロー制御を使用する。C = CTS/RTS フロー制御を使用する。D = DSR/DTR フロー制御を使用する。N = フロー制御を無効にする。空白 = フロー制御を変更しない。
7	DTR 設定	0 = DTR を無効にする (オフに設定、オフを保持)。1 = DTR を有効にする (オンに設定、オンを保持)。空白 = DTR 状態を変更しない。
8	$ZA エラー報告	0 = $ZA エラー報告を無効にする (既定)。1 = $ZA エラー報告を有効にする。空白 = $ZA エラー報告を変更しない。

以下の例は、COM ポート状態の文字列です。

  OPEN "COM2":(:::" 0801x0")

この文字列の値は、次のとおりです。空白 (ポートを切断しない)、0 (モデム制御を使用しない)、8 (8 データ・ビット)、0 (パリティなし)、1 (1 ストップ・ビット)、X (Xon/Xoff フロー制御)、0 (DTR を無効にする)、既定 ($ZA エラー報告を無効にする)。

Disconnect パラメータは、DTR シグナルのレベルを 2 秒間下げた後、元に戻すことで、モデム制御ポートを停止します。この切断によってポートは閉じません。切断後に、COM デバイスを開き直さなくても、再度ダイヤルできます。

Modem Control パラメータは、Caché が RLSD (Received Line Signal Detector) ピンの状態にどのように応答するかを決定します。このピンは、DCD (Data Carrier Detect) ピンとも呼ばれます。回線がモデム制御されている場合 (modem control=1)、Caché は RLSD の状態を監視しています。キャリアが存在しない状態で READ コマンドを発行すると、<ENDOFFILE> エラーが生成されます。キャリアが存在しない状態で WRITE コマンドを発行した場合は、エラーは生成されません。これは、接続が確立する前にモデムにダイヤル・コマンドを送信できる必要があるからです。Caché モデム制御は、いつでも有効 (1) あるいは無効 (0) にできます。モデムにコマンドを送信する際にはモデム制御を無効にし、キャリアが検出されて接続が確立された後はモデム制御を有効にすることをお勧めします。

DTR Setting パラメータは、接続されたモデムからのログインを制御するために使用されます。DTR 設定が 0 (ゼロ) の場合、DTR 制御シグナルはオフになり、モデムはコンピュータと通信できません。この場合は、ダイヤルイン接続できません。DTR 設定が 1 の場合、DTR 制御シグナルはオンになり、モデムはコンピュータと通信できます。これでダイヤルイン接続が可能になります。DTR をオフ (0) に設定している場合、接続されたモデムを使用してダイヤルアウトするためには、OPEN コマンドまたは USE コマンドで DTR をオン (1) に設定する必要があります。多くの場合、NULL モデム・ケーブルを使用して直接ターミナル・デバイスまたはシリアル・プリンタに接続すれば、DTR 設定は重要ではなくなります。これは、NULL モデム・ケーブルによって DTR 制御ピンが強制的にオンになるためです。

$ZA Error Reporting パラメータは、$ZA 特殊変数へのモデム制御ピンの状態の報告を有効にします。このチェックは、COM ポートのモデム制御バイト設定に関係なく実行できます。$ZA エラー報告が有効になっている場合、COM ポート・エラーは、Windows ClearCommError() 関数の呼び出しでクリアされます。ポート・エラー状態は、$ZA ビット 16 から 22 で報告されます。$ZA ビット値のテーブルについては、"Caché ObjectScript リファレンス" の "$ZA" を参照してください。

OPEN コマンドと USE コマンドのキーワード・パラメータ

以下のテーブルは、OPEN コマンドと USE コマンドの両方を使用して、ターミナル・デバイスを制御するキーワード・パラメータの説明です。それぞれのキーワードについて、OPEN および USE の対応する文字コード・プロトコルがテーブルに一覧表示されています。これらのプロトコルの使用に関する詳細は、文字コード・プロトコルのテーブルにあります。

OPEN コマンド実行の検証

OPEN コマンドが成功したかどうかを判断するために、コードでは $TEST または $ZE (またはその両方) の使用をお勧めします。$TEST は、OPEN コマンドが timeout 引数で指定された場合にのみ設定されます。Ctrl-C が OPEN コマンドに割り込んだ場合にのみ、<NOTOPEN> エラーが発生します。したがって、コードは <NOTOPEN> エラーに依存していないことが必要です。

OPEN と USE の文字コード・プロトコル

特別な状況やターミナルでは、異なるプロトコルが必要になる場合があります。protocols 文字コード・パラメータ (あるいは対応するキーワード・パラメータ) を使用し、Caché がターミナルでやり取りするための規則を変更できます。プロトコルは、通常の読み取りや単一文字の読み取りに影響します。

すべての特殊プロトコルが無効になっている通常モードで、大半のターミナル入出力には十分です。通常モードでは、Caché は、受信する各 ASCII 文字をエコーし、ターミナルで表示するよう返送します。Enter キーあるいは有効なエスケープ・シーケンスは、READ コマンドを終了します。

ターミナルに OPEN を発行すると、+ オプションまたは - オプションで指定されたプロトコル以外の既存のプロトコルはすべて無効になります。

以下のテーブルは、有効な protocols 文字とその効果の説明です。

プロトコル文字列の例

以下の一連の例は、プロトコル文字列の使用方法を示しています。以下の各 USE コマンドは、その前に実行した USE コマンドで構築したプロトコル上で実行します。

   USE 0:(80:"BP" )

文字コード BP は、B と P プロトコルを有効にします。この例はブレーク (B) を有効にし、ターミナルを出力デバイス (P) として処理するよう Caché に命令します。

   USE 0:(80:"P")

上述の例にある USE コマンドに続いてこのコマンドを実行すると、P プロトコルは有効のままで、B プロトコルが無効になります。

   USE 0:(80:"+R" )

+R は、他のプロトコル設定に影響せずに、行呼び出しモードを有効にします。

   USE 0:(80:"")

空の文字列は、すべてのプロトコルを無効にします。しかし、P あるいは C は有効のままです。

   USE 0:(80)

プロトコル・パラメータを省略すると、プロトコルと明示的なターミネータは、変更されない状態のままとなります。

プロトコル・ターミネータ文字

OPEN プロトコルと USE プロトコル は、READ 入力文字、制御シーケンス、およびキーストロークのうち、暗黙のターミネータ文字として処理される文字を定義します。これには、I (イメージ・モード)、N (通常モード (既定))、R (行呼び出しモード)、および T (ターミネータ・モード) の 4 種類のプロトコルがあります。

• I (イメージ・モード) では、256 個すべての 8 ビット文字をデータとして使用できます。READ 入力ターミネータやコマンド行編集文字として扱われる文字はありません。このため、イメージ・モードでは、単一の文字または固定長の READ 処理のみを使用する必要があります。ターミネータを定義せずに通常どおりに READ を実行すると、<TERMINATOR> エラーが発生します。

• N (通常モード) および C (CRT モード) では、ASCII の 3、8、10、13、21、および 127 の 6 つを除くすべての文字をデータとして使用できます。ASCII の 10 (改行) と 13 (キャリッジ・リターン) の2 つは、READ を終了し、入力を送信します。ASCII 3 (Ctrl-C) は、入力を破棄し、BREAK が有効になっている場合は <INTERRUPT> エラーを発行します。ASCII の 8 (バックスペース) および 127 (削除) は、画面上で後退して 1 文字を消去してから READ を続行します。ASCII の 21 は、後退して前にあるすべての文字を消去してから READ を続行します。

• R (行呼び出しモード) では、ASCII の 1 から 8、10 から 14、16、18、21、23、24、27 および 127 の 20 個を除くすべての文字をデータとして使用できます。ASCII の 10 (改行) と 13 (キャリッジ・リターン) は、READ を終了し、入力を送信します。ASCII 3 (Ctrl-C) は、入力を破棄し、BREAK が有効になっている場合は <INTERRUPT> を発行します。他の文字は、以下のコマンド行編集機能を実行します。

  1   ^A = beginning of line
  2   ^B = back word
  3   ^C = interrupt
  4   ^D = delete current character
  5   ^E = end of line
  6   ^F = forward word
  7   ^G = delete to beginning of word ("wipe word backward")
  8   ^H = BS = destructive backspace
  9   ^I = HT = horizontal tab (echoed as a SPACE)
  10  ^J = LF = end of input
  11  ^K = VT = forward character
  12  ^L = FF = erase to end of line
  13  ^M = CR = end of input (same as LF)
  14  ^N = recall next input line
  16  ^P = recall previous input line
  18  ^R = back char (reverse)
  21  ^U = erase to start of line
  23  ^W = delete to end of word "gobble word forward")
  24  ^X = erase entire line
  27  ESC lead character for arrow and function keys
  127 DEL = destructive backspace (same as BS)
  

• T (ターミネータ・モード) では、ASCII の 0 から 31 および 127 から 159 の 65 個の制御文字を除くすべての文字をデータとして使用できます。これらの文字のほとんどは、READ 終端文字として扱われます。これには、他のすべてのプロトコルではデータとして扱われるタブ文字 (ASCII 9) も含まれます。コマンド行制御文字として扱われる文字もいくつかあります。ASCII の 3 (Ctrl-C) は、入力を破棄し、BREAK が有効になっている場合は <INTERRUPT> を発行します。ASCII の 8 (バックスペース) および 127 (削除) は、画面上で後退して 1 文字を消去してから READ を続行します。ASCII 21 (Ctrl-U) および ASCII 24 (Ctrl-X) は、後退して前にあるすべての文字を消去してから READ を続行します。ASCII 27 は、エスケープ文字です。

• IT (イメージ・モード + ターミネータ・モード) では、ASCII の 0 から 31 および 127 から 159 の 65 個の制御文字を除くすべての文字をデータとして使用できます。このモードでは、すべての制御文字が READ ターミネータ文字として扱われます。

これらのモードのいずれでも、terminator パラメータを使用して、追加のターミネータ文字を明示的に指定できます。イメージ・モードは、ビット・ストリーム・データに使用することが多いので、通常は、任意の文字をターミネータとして指定することは避けます。

明示的ターミネータ文字

OPEN コマンドまたは USE コマンドの terminator パラメータを使用して、特定の文字を READ コマンドまたは WRITE コマンドのターミネータとして定義できます。これらの明示的ターミネータは、指定した protocol で決まるターミネータ文字を補足するために使用できます。この terminator パラメータは、protocol による文字の指定を無視し、指定した文字を代わりのターミネータ文字として指定するためにも使用できます。文字をターミネータとして再定義する機能に対する例外は、ASCII 0 (NULL)、ASCII 3 (Ctrl-C)、および 2 つの出力制御文字 Ctrl-Q (XON) および Ctrl-S (XOFF) です。これらの文字は、元の機能が保持され、ターミネータ文字として再定義できません。

例

以下の例は、Z、Backspace、Tab を主デバイスのターミネータとして定義します。アンダースコアは、連結演算子です。

  USE 0:("":"":"Z"_$CHAR(8,9))

所有していないターミナルに対して OPEN コマンドを発行すると、明示的なターミネータの Caché 内部リストが暗黙的にクリアされます。プロトコル文字列を検出すると、Caché は以下を実行します。

1. 明示的なターミネータ・リストをクリアします。

2. プロトコル文字列に従い、プロトコルを設定します。

3. ターミネータ文字列が存在する場合、それを内部的な明示的ターミネータ・リストにコピーします。

   以下のテーブルは、明示的なターミネータ文字列の例です。

ターミネータ文字列 ： 例

ターミネータ文字列	定義
USE 0:(80:"C":$CHAR(27))	このエスケープ文字は、エスケープ・シーケンスを開始せず、READ を終了します。
USE 0:(80:"C":"")	空の文字列は、すべてのターミネータをクリアします。
USE 0:(80:"C")	protocol の指定時に terminator パラメータを省略すると、すべてのターミネータをクリアします。
USE 0:(80) または U 0:80	protocol と terminator の両方を省略すると、ターミネータは変更されません。

Read 操作でのプロトコルとターミネータの概要

以下の文字は、通常モード (非イメージ) の READ を終了します。

• Enter

• ASCII NUL 以外のターミネータ文字列の文字と Ctrl-C、Ctrl-O、Ctrl-Q、Ctrl-S

• T プロトコルが有効な場合の、出力制御文字以外の制御文字。制御文字は、10 進数コード 0 から 31、および 127 から 159 の出力されない文字です。

• あらゆるエスケープ・シーケンス

• 固定長 READ x#y の y 番目の文字。

以下の文字は、イメージ・モードの READ を終了します。

• ASCII NUL 以外のターミネータ文字列で指定された文字

• T プロトコルが有効な場合の制御文字

• 固定長 READ x#y の y 番目の文字。

構文

READ variable:timeout         ; Variable-length read
READ variable#length:timeout  ; Fixed-length read
READ *variable:timeout        ; Single-character read

詳細は、"ObjectScript ランゲージ・リファレンス" の "READ" を参照してください。

例

以下のテーブルは、Read コマンド引数の使用方法です。

行呼び出し

行呼び出しモードでは、ターミナルからの READ 操作に対する入力として、編集可能な行の行呼出しが提供されます。これらの呼び出し可能な行には、以前の READ 入力行と以前のコマンド行の両方が含まれます。行呼出しの前提条件として、入力行のエコーが必要です。

Caché は、可変長ターミナル読み取り (READ variable) と固定長ターミナル読み取り (READ variable#length) の両方で、行呼び出しをサポートしています。Caché は、単一文字ターミナル読み取り (READ *varaiable) では行呼び出しをサポートしていません。行呼び出しでは、オプションの timeout 引数をサポートしています。

固定長ターミナル読み取りの場合、呼び出された行は、READ で指定した文字数よりも 1 文字少ない文字数まで切り捨てられます。READ で指定した最終文字の位置は、行終了文字の入力、編集文字の指定、またはデータ文字 1 文字の追加のために予約されています。

行呼び出しがアクティブである場合、上矢印キーと下矢印キーを使用して以前のターミナル入力行を呼び出すことにより、READ に入力を提供できます。その後、左矢印キー、右矢印キー、Home キーおよび End キーを使用して、呼び出された行を編集するためにカーソルの位置を変更できます。文字を削除するには Backspace キー、行全体を削除するには Ctrl-X キー、行の中でカーソルの左側にある部分をすべて削除するには Ctrl-U キーをそれぞれ使用します。

行呼び出しがアクティブでない場合、4 つの 矢印 キー、Home キー、および End キーはすべて、行終了文字を発行します。1 つの入力文字を削除するには Backspace キー、入力行全体を削除するには Ctrl-X キー (または Ctrl-U キー) を使用します。

OPEN コマンドまたは USE コマンドを使用すると、R プロトコルを指定することで行呼び出しをアクティブにでき、N、I、S、または T のいずれかのプロトコルを指定することで行呼び出しを非アクティブにできます。

ターミナル入出力に影響する特殊なプロトコル文字

各オペレーティング・システムは、特定のプロトコル文字 (UNIX® の場合) やキーの組み合わせ (例えば、Windows プラットフォームでの CTR-ALT-DEL) を無効にし、これらの文字が Caché に影響を与えないようにします。Windows のコンソールは、これらのオペレーティング・システム機能を阻害しません。

他の特殊文字は、ルーチンの実行方法を変更できますが、READ コマンドの変数には使用されません。イメージ・モードでターミナルを操作すると、これらの機能は無効となり、Caché はこれらの文字を他の文字と同様に扱います。

READ は、入出力制御文字に影響されます。READ は、終端文字以外の制御文字すべてを読み取りますが、エコーしません。

出力制御文字は、ルーチン・フローとルーチン出力の両方に影響します。以下はその説明です。

入力制御文字は、入力に影響を与えます。これらの文字は、イメージ・モード (I プロトコル) ではデータとして扱われますが、通常モードでは現在の READ コマンドへの入力に影響します。以下は、これらの文字についての説明です。

READ コマンドによる入力の処理

READ コマンドは、入力バッファから文字を受け取るたびにそれを処理します。以下のテーブルは、このプロセスが通常モードでどのように発生するかを示しています。以下の図は、READ コマンドがイメージ・モード・データを処理する方法を示しています。

構文

WRITE *variable
WRITE *-n
WRITE #
WRITE /mnemonic

例

以下の例にある WRITE * では、ユーザ・ターミナルで警告音を発してプロンプトを表示し、受信済みで使用されていない文字を入力バッファからクリアします。

   SET eek="No. I can't accept that reply" 
   WRITE *7,eek,*-10

以下の 2 つの例は、WRITE *-1 と WRITE *-10 との違いを示します。どちらの場合も、ユーザは、最初の READ に応答して ENTER キーを押し、その後、HANG コマンドに起因する 2 つの一時停止の間に先に入力します。

  READ "type:",x HANG 4 WRITE *-1 HANG 4 READ "type:",y

上記の例で、Caché は、2 番目の READ が発行されると、入力バッファをクリアします。したがって、いずれかの HANG 中に入力したテキストはすべてバッファからクリアされます。

  READ "type:",x HANG 4 WRITE *-10 HANG 4 READ "type:",y

上記の例で、Caché は、WRITE *-10 が発行されると直ちに入力バッファをクリアします。したがって、最初の HANG の間に入力したテキストはすべてクリアされますが、2 番目の HANG 中に入力したテキストはすべて 2 番目の READ コマンドに提供されます。

以下の例は、WRITE /mnemonic で制御ニーモニック CUP (CUrsor Position) を使用し、ターミナルの 4 行 3 列目にカーソルを移動します。この例では、事前定義のニーモニック空間 ^%X364 は USE コマンドで指定し、開いているターミナル・デバイスの名前は terminal 変数を使用して指定します。^%X364 の詳細は、"ターミナルの事前定義ニーモニック空間" を参照してください。

   USE terminal:(80:"BP"):"%X364"
   SET %1=3,%2=4
   WRITE /CUP(%1,%2)

構文

CLOSE device

詳細は、"ObjectScript ランゲージ・リファレンス" の "CLOSE" を参照してください。

X3.64 のニーモニック空間

Caché は、ANSI X3.64 を定義するために、組み込みのニーモニック空間を提供します。このニーモニック空間は、管理者のネームスペース内にある Caché ルーチン %X364 です。以下のいずれかの方法で、ルーチン %X364 を使用します。

• Caché システム管理者が [IO 設定] 構成設定で、既定のニーモニック空間として %X364 を入力します。管理ポータルから、システム, 構成, デバイス設定, IO設定 を選択します。

• このニーモニック空間を指定する OPEN コマンドを発行します。

   OPEN "terminal"::"^%X364"

  

以下のテーブルは、ニーモニックのリストです。

DTM PC コンソール用ニーモニック空間

Caché は、DTM アプリケーション開発用に使用するニーモニックに適合した Caché ルーチン %XDTM を提供します。このニーモニック空間は有効ですが、ターミナルの既定のニーモニック空間としては設定されません。DTM 用に生成したアプリケーションを Caché に移植する場合、以下のいずれかを実行します。

• 管理ポータルで、^%XDTM をターミナルの既定のニーモニック空間 ([MnemonicTerminal]) として構成します。

• OPEN コマンドまたは USE コマンドを使用して、^%XDTM ニーモニック空間を参照します。

DTM の例

UNIX®

  OPEN "/dev/tty04/"::"^%XDTM"

Windows

  OPEN "c:\sys\user"::"^%XDTM"

その後、Caché は、以下のテーブルのように、DTM 制御ニーモニックを WRITE /mnemonic コマンドに適切に変換します。

DTM PC コンソール用制御ニーモニック

ニーモニック	説明
AA	通常モード
AB	太字モード
AC	下線モード
AD	太字、下線モード
AE	反転映像
AF	反転映像/太字モード
AG	反転映像/下線モード
AH	反転映像/太字、下線モード
AI	点滅モード
AJ	太字、点滅モード
AK	下線、点滅モード
AL	太字、下線、点滅モード
AM	反転映像/太字、点滅モード
AN	反転映像/太字、点滅モード
AO	反転映像/下線、点滅モード
AP	反転映像/太字、下線、点滅モード
AZ	モード Z
B(%1,%2)	映像属性の設定：%1 は文字属性、%2 はフレーム・クリア属性
BOX	ウィンドウ相対ユーティリティ・ボックスの描画
C(%1,%2)	カーソルを列 %1、行 %2 に配置
CLR	現在のフレームをクリア
COLOR(%1,%2)	IBM PC 標準色に設定 ： 前景 %1、背景 %2
DC(%1)	%1 文字の削除
EC(%1)	%1 文字の消去
EF	フレームの最後まで消去
EL	行の最後まで消去
F(%1,%2,%3, %4,%5)	左上隅の行幅 %4、行高 %5 の四角い領域を $CHAR(%1) で埋める
GETCUR	ターミナル・カーソル位置に戻る
HF	画面の半輝度化の解除
HIDECURSOR	マウス・カーソルを隠す
HN	画面を半輝度化
IC(%1)	%1 文字の挿入
LF	リテラル・モードを無効
LN	リテラル・モードを有効にし、PC の画面に制御文字を画像で表示
MARK(%1)	画面に印付け
NORM	標準表示属性を有効
PAD(%1)	パディング用として %1 NULLS を書き込み
PF	一時停止の解除
PN	一時停止
RF	反転映像画面オフ
RN	反転映像画面
SD(%1,%2,%3)	現在のフレームを %3 行ずつスクロール・ダウン
SHOWCURSOR	マウス・カーソルの表示
SU(%1,%2,%3)	現在のフレームを %1 から %2 に %3 行ずつスクロール・アップ (ただし、行 %2 は含まない)
VF	カーソル表示オフ
VN	カーソル表示オン
WBOX	画像相対ユーティリティ・ボックスの描画
WCLOSE	ユーティリティ・ウィンドウを閉じる
WINDOW	スクロール・ウィンドウの設定
WOPEN	ユーティリティ・ウィンドウを開く
Y(%1)	バイナリ・フレーム属性の設定

構文

PRINT
ZPRINT
PRINT x
ZPRINT x
PRINT x:y
ZPRINT x:y

各項目の内容は次のとおりです。

引数	定義
(なし)	引数なしの PRINT あるいは ZPRINT コマンドは、すべてのルーチンを出力します。
x,y	変数 x と y は、出力する行範囲を示します。TAG+OFFSET 形式の行参照、あるいは +7 の形式の行数のいずれかになります。ルーチン内以外の行を参照すると、ルーチンの最終行に続く空の行があるものと見なします。x は、出力する最初の行あるいは唯一の行です。y は、出力する最後の行です。

詳細は、"ObjectScript ランゲージ・リファレンス" の "PRINT" を参照してください。

例

以下の例では、現在のルーチンの最初の行、INIT で開始する 4 行目、FINI から最後までの行すべてを出力します。

INIT
  SET a=1
  SET b=2
  SET c=3
  SET d=4
FINI
  SET x=24
  SET y=25
  SET z=26
  PRINT +1,INIT:INIT+3,FINI:+9999

Caché を使用したフォーマット済み CRT 画面のプログラム

ターミナル入出力の機能の中には、次のようにフォーマット済み画面のプログラムに役立つものもあります。

• WRITE * を使用して、制御文字を簡単に送信する

• READ を使用して、エスケープ・シーケンスの応答を受信する

• SET $X = expression と SET $Y = expression を使用して、現在のカーソル位置を更新する

固定長の READ とプログラム固有の終端文字により、個々のフィールドの読み取りが簡単になります。隠しプロトコルを使用して、パスワードを非表示にできます。

WRITE * は、$X も $Y も変更しません。変更するには、WRITE $C(X) を使用するか、それらを明示的に設定します。

例

この例は、VT100 カーソルを行 10 列 20 に設定します。

%SYS>SET DY=10,DX=20
%SYS>WRITE *27,*91,DY+1,*59,DX+1,*72 SET $Y=DY,$X=DX

CURRENT^%IS を使用した変数設定

ユーティリティ・ルーチン CURRENT^%IS は、現在のデバイスで作業するのに役立つローカル変数を設定します。このルーチンを呼び出すには、以下を入力します。

%SYS>DO CURRENT^%IS

このコマンドは、以下の変数を設定します。

CURRENT^%IS で使用できる機能

コード	定義
W @FF	画面をクリアし、左上隅 (列 0、行 0) にカーソルを移動して $X=0、$Y=0 とします。
S DX=42,DY=10 X XY	$X=42、$Y=10 をそのままにした状態で、カーソルを直接列 42、行 10 に移動します。

エスケープ・シーケンスのプログラミング

エスケープ・シーケンスの ANSI 規格により、スマート・ターミナル・プログラムを実用できます。エスケープ文字とそれに続くすべての文字は画面に表示されませんが、$X と $Y が更新されます。WRITE * 文を使用してターミナルにエスケープ・シーケンスを送信し、$X と $Y を直接設定して最新の状態にします。

ANSI 規格は、エスケープ・シーケンスの標準構文を規定しています。特定のエスケープ・シーケンスの機能は、使用するターミナルの種類によって異なります。

各 READ の後に続く $ZB に、入力されたエスケープ・シーケンスが記述されます。Caché は、ANSI 規格のエスケープ・シーケンスと、ANSI 形式を使用する他のエスケープ・シーケンスを $ZB に置きます。Caché は、エスケープ・シーケンスの以下の 2 つの形式を認識します。

例

ここでは、Help キーを押すと、2 文字のシーケンス Escape-? が送信されるターミナルをプログラムしているとします (? は、10 進数値 63 です)。

%SYS>SET HELP=$C(27,63)
ASK READ !,"Enter ID: ",X I $ZB=HELP Do GIVEHELP GoTo ASK

このルーチンは、以下のように非標準のエスケープ・シーケンスを検出できます。

1. ESC をターミネータにします。

2. ESC が $ZB に表示された場合、以下を実行します。

   1. 隠しプロトコルのエコーを無効にし、$X/$Y が変更されないようにします。

   2. READ * で残りのシーケンスを読み取ります。

   3. 隠しプロトコルを無効にし、再度エコーを使用できるようにします。

      以下の図では、ユーザに ID を入力するよう要求しています。ユーザが、Esc-? を押すと、ヘルプ画面が表示されます。サブルーチン ESCSEQ は、非標準エスケープ・シーケンスの最後にアスタリスク “*” が使用されていることを前提としています。

DEMOS 
  SET HELP=$C(27,63) ;Get Help with <ESC>?
    SET ESC=$C(27) USE 0:("":"":ESC) ; Make <ESC> a READ terminator
                                     ; character
ASK READ !,"Enter ID: ",X I $ZB=ESC Do ESCSEQ G:SEQ=HELP ASK 
    . ;Input ID. Handle Help request. 
    .
    Quit
HELPSCR  ;Process Help request 
    . 
    Quit
ESCSEQ  USE 0:("":"S") SET SEQ=ESC ;Set terminal to no echo,init SEQ 
    FOR I=1:1 {
      READ *Y 
      SET SEQ=SEQ_$C(Y)
      QUIT:Y=42 }
    ; Read in Escape sequence, 
    ; end at "*" 
    USE 0:("":"":ESC) Quit ;Redefine terminator

全二重および半二重ターミナルとエコーのサポート

Caché は、全二重ターミナルの使用を想定しています。つまり、キーボードの動作は、プリンタや画面に依存していない必要があります。

全二重とは、双方向で同時に独立して送信が行われるということです。半二重とは、一度に片方向のみの送信を意味します。二重ターミナルは、エコーと関係ありません。しかし、リモート・エコーを全二重、ローカル・エコーを半二重と表示しているターミナルもあります。これは、入力した文字がターミナル自身で表示され、Caché はその文字をエコーしないことを意味します。

ターミナルのローカル・エコーあるいは全二重を無効に設定し、Caché がエコーできるようにします。エコーが発生するのは、コンピュータが文字を受け取ったときではなく、READ コマンドが入力バッファから文字を取得したときです。したがって、プロンプトとダイアログの応答は、ユーザが事前に入力したかどうかに関係なく、画面の決められた位置に表示されます。

公開ネットワークの中には、ターミナルに独自のエコーを供給するものもあります。

Windows システムでは、コンソールはローカル・エコーの設定変更を許可していません。ターミナル・エミュレータ (例えば VT220) 経由のターミナルでは、ターミナル・エミュレータ・ドキュメントを参照して、ローカル・エコーを無効にしてください。

UNIX® では、stty コマンドを使用して二重エコーを防ぎ、$X と $Y がカーソル位置と一致しているようにします。

Caché がサポートするコンピュータ間リンクと特殊デバイス

Caché は、柔軟なプロトコルと大容量バッファを提供しており、ルーチンが特殊なデバイスとそのプロトコルを処理できるようにしています。例えば、Caché は、ターミナル・リンクで接続された 2 台のコンピュータ間の全二重通信を簡単にサポートしています。2 つの Caché システムで必要な操作は、物理的な接続、適切なプロトコルの指定、および同一の速度、パリティ、文字列長の設定のみです。外部コンバータを使用すると、Caché は、同期 EBCDIC ターミナルのように IBM ポートと通信できます。

コンピュータ間のリンクを設定する場合、以下の点に注意してください。

• OPEN コマンドまたは USE コマンドで S プロトコルを指定するか、オペレーティング・システムのターミナル・パラメータを使用して、両方のエコーを無効にします。

• 通信プロトコルが XON/XOFF フロー制御 (Ctrl-Q と Ctrl-S) をサポートしていない場合、未応答の送信はオペレーティング・システムの入力バッファ範囲内に制限してください。

• イメージ・モードの場合、Caché は XON/XOFF をサポートしません。非イメージ (通常) モードでは、オペレーティング・システムの入力バッファが一杯の場合、コンピュータが XOFF を発行するかどうかは、オペレーティング・システムのターミナル・パラメータで決まります。XOFF と XON がサポートされていない場合、その必要がないようバッファに余裕を持たせてください。

• 読み取り操作の後で $ZA をテストして、パリティやデータのオーバーラン状態などの送信エラーを検出します。