HTTP 送信アダプタの使用法

この章では、Ensemble HTTP 送信アダプタ (EnsLib.HTTP.OutboundAdapterOpens in a new tab) の全般的な動作、およびプロダクションでのこのアダプタの使用法について説明します。以下のトピックについて説明します。

Tip:

Ensemble では、このアダプタを使用する特殊なビジネス・サービス・クラスとユーザのニーズに適したビジネス・サービス・クラスの 1 つも提供されます。そのため、プログラミングの必要がありません。"Ensemble の紹介" の “接続オプション” を参照してください。

全般的な動作

プロダクション内で、送信アダプタは、ユーザが作成および構成するビジネス・オペレーションに関連付けられます。このビジネス・オペレーションはプロダクション内からメッセージを受信し、メッセージ・タイプを調べ、適切なメソッドを実行します。このメソッドは、通常、関連するアダプタのメソッドを実行します。

EnsLib.HTTP.OutboundAdapterOpens in a new tab は、HTTP 要求を Ensemble の外部に送信し HTTP 応答を受信する Ensemble アダプタです。このアダプタは、以下のような項目を制御する設定を提供します。

アダプタが HTTP 要求を送信するサーバおよびポート
指定されたサーバおよびポートで、要求するリソースの URL パス
サーバへの接続に使用するオプションの SSL 構成
アダプタが要求をルーティングするプロキシ・サーバを指定するためのオプション情報

このアダプタは、HTTP POST、GET、および PUT アクションを送信するメソッドを提供します。

主要なメソッドは PostFormData() および GetFormData() です。各メソッドで、応答オブジェクトの出力引数、フォーム変数名のカンマ区切りのリスト、およびフォーム変数引数の変数数値 (1 つの変数数値がカンマ区切りリスト内の各名前に対応) を使用できます。1 つのフォーム変数に複数の値を設定する場合は、リスト内で同じ名前を複数回使用できます。もちろん、フラットなスカラ・コンテンツ (通常の Web ページなど) を要求するために、フォーム変数なしでこれらのメソッドを使用することもできます。
フォーム変数の複雑なセットが使用されている場合は、PostFormDataArray() および GetFormDataArray() メソッドを使用します。これらのメソッドでは、変数引数リストの代わりに、多次元配列が使用できます。多次元配列は、名前リスト内で複数のエントリを使用することなく、所定のフォーム変数の複数の値を配列のサブノードとして提供できるため、情報の組織化に役立ちます。また、位置ではなくフォーム変数名によって配列にインデックスを割り当てることができます。
その他の特別な HTTP 要求 (PUT など) を使用する必要がある場合や、フォーム変数や Cookie 以外の HTTP 要求の面でカスタマイズをする必要がある場合には、低レベルのワーカ・メソッドである SendFormDataArray() を使用できます。

HTTP 要求には、ローカル Ensemble サーバのデフォルトの文字エンコードが使用されます。異なる文字エンコードを指定するには、カスタム HTTP 要求を作成して送信します。これについては、“カスタム HTTP 要求の作成” を参照してください。

アダプタを使用するビジネス・オペレーションの作成

EnsLib.HTTP.OutboundAdapterOpens in a new tab を使用するビジネス・オペレーションを作成するために、新しいビジネス・オペレーション・クラスを作成します。後で、それをプロダクションに追加して、構成します。

存在しなければ、適切なメッセージ・クラスを作成する必要もあります。"Ensemble プロダクションの開発" の “Ensemble メッセージの定義” を参照してください。

ビジネス・オペレーション・クラスの基本要件を以下に列挙します。

ビジネス・オペレーション・クラスは、Ens.BusinessOperationOpens in a new tab を拡張するものでなければなりません。
クラスの ADAPTER パラメータは EnsLib.HTTP.OutboundAdapterOpens in a new tab である必要があります。
クラスの INVOCATION パラメータは、使用する呼び出しスタイルを指定する必要があります。以下のいずれかを使用します。
- Queue は、メッセージが 1 つのバックグラウンド・ジョブ内で作成され、元のジョブが解放された段階でキューに配置されることを意味します。その後、このメッセージが処理されると、別のバックグラウンド・ジョブがこのタスクに割り当てられます。これは最も一般的な設定です。
- InProc は、メッセージが、作成されたジョブと同じジョブで生成、送信、および配信されることを意味します。このジョブは、メッセージが対象に配信されるまで送信者のプールに解放されません。これは特殊なケースのみに該当します。
クラスでは、少なくとも 1 つのエントリを含むメッセージ・マップを定義します。メッセージ・マップは、以下の構造を持つ XData ブロック・エントリです。
```
XData MessageMap
{
<MapItems>
  <MapItem MessageType="messageclass">
    <Method>methodname</Method>
  </MapItem>
  ...
</MapItems>
}
```
クラスでは、メッセージ・マップ内で名前が付けられたすべてのメソッドを定義します。これらのメソッドは、メッセージ・ハンドラと呼ばれます。各メッセージ・ハンドラは、以下のシグニチャを持っている必要があります。
```
Method Sample(pReq As RequestClass, Output pResp As ResponseClass) As %Status
```
ここで、Sample はメソッド名、RequestClass は Ensemble 要求メッセージ・クラスの名前、ResponseClass は Ensemble 応答メッセージ・クラスの名前です。通常、メソッド・コードは、ビジネス・オペレーションのプロパティおよび Adapter プロパティのメソッドを参照します。
メッセージ・クラスの定義方法は、"Ensemble プロダクションの開発" の “Ensemble メッセージの定義” を参照してください。
メッセージ・ハンドラ・メソッドの定義方法については、この章で後述する “メッセージ・ハンドラ・メソッドの作成” を参照してください。
その他のオプションと一般情報は、"Ensemble プロダクションの開発" の “ビジネス・オペレーション・クラスの定義” を参照してください。

以下の例は、必要となる一般的な構造を示しています。

Class EHTTP.NewOperation1 Extends Ens.BusinessOperation
{
Parameter ADAPTER = "EnsLib.HTTP.OutboundAdapter";

Parameter INVOCATION = "Queue";

Method Sample(pReq As RequestClass, Output pResp As ResponseClass) As %Status
{
  Quit $$$ERROR($$$NotImplemented)
}

XData MessageMap
{
<MapItems>
  <MapItem MessageType="RequestClass">
    <Method>Sample</Method>
  </MapItem>
</MapItems>
}
}

Note:

スタジオには、上記のようなビジネス・オペレーション・スタブの作成に使用できるウィザードが用意されています。このウィザードにアクセスするには、[ファイル]→[新規作成] をクリックし、[プロダクション] タブをクリックします。次に [ビジネス・オペレーション] をクリックして [OK] をクリックします。

メッセージ・ハンドラ・メソッドの作成

EnsLib.HTTP.OutboundAdapterOpens in a new tab で使用するビジネス・オペレーション・クラスを作成する場合の最大のタスクは、通常、このアダプタで使用するメッセージ・ハンドラ、つまり、Ensemble メッセージを受信してさまざまな HTTP 操作を実行するメソッドの記述です。

各メッセージ・ハンドラ・メソッドは、以下のシグニチャを持っている必要があります。

Method Sample(pReq As RequestClass, Output pResp As ResponseClass) As %Status

ここで、Sample はメソッド名、RequestClass は Ensemble 要求メッセージ・クラスの名前、ResponseClass は Ensemble 応答メッセージ・クラスの名前です。

通常、このメソッドは以下の操作を実行します。

受信要求メッセージを調べます。
受信要求の情報を使用して、ビジネス・オペレーションの Adapter プロパティのメソッドを呼び出します。例えば、HTTP GET コマンドを送信する Get メソッドを呼び出します。
```
 set status=..Adapter.Get(.pHttpResponse,"Name",pRequest.Name)
```
この例は GET 要求を送信し、pRequest.Name という値を持つ Name と呼ばれるパラメータで渡します。
使用可能なメソッドについては、次の節で説明します。各メソッドは、ステータス (具体的には、%StatusOpens in a new tab のインスタンス) を返します。
これらのメソッドは、出力として HTTP 応答も返します。上記の例では、応答は pHTTPResponse に配置されています。応答は %Net.HttpResponseOpens in a new tab のインスタンスです。このオブジェクトの使用法については、“HTTP 応答の使用法” の章を参照してください。
HTTP 応答を調べます。
HTTP 応答内の情報を使用して、Ensemble 応答メッセージ (Ens.ResponseOpens in a new tab またはサブクラスのインスタンス) を作成します。メソッドは出力としてこのメッセージを返します。
メッセージ・クラスの定義については、"Ensemble プロダクションの開発" の “Ensemble メッセージの定義” を参照してください。
必ず出力引数 (pOutput) を設定します。通常、応答メッセージと同じように設定します。この手順は必須です。
適切なステータスを返します。この手順は必須です。

以下に例を示します。

Method PostMessage(pRequest As EHTTP.Request.OutboundPost,
Output pResponse As EHTTP.Response.OutboundPost) As %Status
{
  Set $ZT="Trap",tSC=$$$OK
  do {

    set input=pRequest.MessageStream
    set tResponse = ##class(%Net.HttpResponse).%New()
    set tsc = ..Adapter.Post(.tResponse,,input)

    set pResponse = ##class(EHTTP.Response.OutboundPost).%New()
    set len = tResponse.Data.SizeGet()
     While (tResponse.Data.AtEnd = 0) {
      do pResponse.MessageStream.Write(tResponse.Data.Read())
     }
    Quit
  } while (0)
Exit
  Quit tSC
Trap
  Set $ZT="",tSC=$$$EnsSystemError
  Goto Exit
}

HTTP コマンドの呼び出し

この節では、EnsLib.HTTP.OutboundAdapterOpens in a new tab を使用して HTTP コマンド (GET、POST、PUT、または DELETE) を送信する方法を説明します。HTTP コマンド内で、フォーム・データまたは要求本文のいずれかを送信できます。この節では、以下のトピックについて説明します。

フォーム・データの送信

HTTP フォーム・データを送信するには、Post、PostFormDataArray()、Get、GetFormDataArray()、または SendFormDataArray() メソッドのいずれかを使用します。これらの各メソッドは (出力として) HTTP 応答 (%Net.HttpResponseOpens in a new tab のインスタンス) を返します。このオブジェクトの使用法については、“HTTP 応答の使用法” の章を参照してください。

詳細はメソッドによって異なりますが、一部を例に示します。

 set tFormVar="USER,ROLE,PERIOD"

 set tUserID=pRequest.UserID
 set tRole=pRequest.UserRole
 set tED=pRequest.EffectiveDate

 set tSC=..Adapter.Get(.tResponse,tFormVar,tUserID,tRole,tED)

この例では、Ensemble 要求メッセージに UserID、UserRole、および EffectiveDate のプロパティがあると仮定します。

要求本文の送信

要求本文は、必要に応じて、ストリームまたは文字列のいずれかになります。ストリームとしての作成と書き込みについては、Caché ドキュメントを参照してください。例えば、"Caché オブジェクトの使用法" の “ストリームを使用した作業” の章を参照してください。

次に、Post()、PostFormDataArray()、Get()、または GetFormDataArray() メソッドのいずれかを使用します。この場合、要求本文を引数として渡すので、フォーム・データ引数は空のままにしておきます。これらの各メソッドは (出力として) HTTP 応答 (%Net.HttpResponseOpens in a new tab のインスタンス) を返します。このオブジェクトの使用法については、“HTTP 応答の使用法” の章を参照してください。

詳細はメソッドによって異なりますが、一部を例に示します。

   set tsc = ..Adapter.Post(.tResponse,,pRequest.MessageStream)

この例では、Ensemble 要求メッセージに MessageStream プロパティがあると仮定します。

HTTP ヘッダとしてのストリーム属性

ストリームを作成して要求本文として送信する場合、HTTP 送信アダプタが、HTTP ヘッダとして一部またはすべてのストリーム属性を含むようにすることができます。そのためには、SkipBodyAttrs プロパティを、HTTP ヘッダとして使用されない属性のリストと同じに設定する必要があります。デフォルト値は "*" です。これは、ストリーム属性はデフォルトでは無視される (そしてヘッダとして使用されない) ことを意味します。このプロパティは、実行時設定として使用できません。

ストリーム属性の詳細は、%Library.AbstractStreamOpens in a new tab のクラス参照を参照してください。

HTTP メソッドについての参照情報

この節では、HTTP コマンドの呼び出しに使用できるメソッドについての参照情報を提供します。

Post()

Method Post(Output pHttpResponse As %Net.HttpResponse,
            pFormVarNames As %String = "",
            pData...) As %Status

構成された宛先に HTTP POST コマンドを送信します (“宛先の指定” を参照)。フォーム・データまたは要求本文を送信します。

HTTP 応答は、最初の引数で出力として返されます。これは %Net.HttpResponseOpens in a new tab のインスタンスです。このオブジェクトの使用法については、“HTTP 応答の使用法” の章を参照してください。

このメソッドを使用して、以下のいずれかを行います。

指定されたフォーム変数にフォーム・データを送信するには、pFormVarNames 引数および pData 引数を必要に応じて指定します。pFormVarNames は、使用するフォーム変数名のカンマ区切りリストです。リスト内の各名前に対して、pData 引数を提供します。
指定されたフォーム変数に複数の値を渡すには、pFormVarNames リストにその変数名を複数回含めます。
追加の pData 引数を提供すると、リストの最後のフォーム変数に割り当てられます。
フォーム変数ではなく要求本文を送信するには、pFormVarNames を空のままにしておき、pData 引数として要求本文を渡します。

本文テキストとして渡されるデータ値は、文字列またはストリームです。フォーム変数として渡されるデータ値は、文字列である必要があります。

PostFormDataArray()

Method PostFormDataArray(Output pHttpResponse As %Net.HttpResponse,
                         pFormVarNames As %String = "",
                         ByRef pData) As %Status

構成された宛先に HTTP POST コマンドを送信します (“宛先の指定” を参照)。指定されたフォーム変数にフォーム・データを送信します。

pFormVarNames は、使用するフォーム変数名のカンマ区切りのリストです。リスト内の各名前に対して、pData 引数を提供します。

pData 引数は配列です。配列の最上位ノードは使用されません。各サブノードは、pFormVarNames リストにある対応するフォーム変数のインデックスによって、添え字が付けられます。指定された添え字の値は、次のように指定します。

単一の値を持つフォーム変数 (varname) の場合、pData(“varname”) の値には、送信するフォーム・データ値を指定します。サブノードはありません。
複数の値を持つフォーム変数 (varname) の場合、pData(“varname”) の値には、値の数を指定します。このフォーム変数の各値はサブノードで使用され、ノード内での位置によって添え字が付けられます。

PostURL()

method PostURL(pURL As %String, 
              Output pHttpResponse As %Net.HttpResponse, 
              pFormVarNames As %String = "", 
              pData...) as %Status

指定された URL (pURL) に HTTP POST コマンドを送信します。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

Get()

Method Get(Output pHttpResponse As %Net.HttpResponse,
           pFormVarNames As %String = "",
           pData...) As %Status

構成された宛先に HTTP GET コマンドを送信します (“宛先の指定” を参照)。フォーム・データまたは要求本文を送信します。Post() も参照してください。

GetFormDataArray()

Method GetFormDataArray(Output pHttpResponse As %Net.HttpResponse,
                        pFormVarNames As %String = "",
                        ByRef pData) As %Status

構成された宛先に HTTP GET コマンドを送信します (“宛先の指定” を参照)。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

GetURL()

method GetURL(pURL As %String, 
              Output pHttpResponse As %Net.HttpResponse, 
              pFormVarNames As %String = "", 
              pData...) as %Status

指定された URL (pURL) に HTTP GET コマンドを送信します。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

Put()

Method Get(Output pHttpResponse As %Net.HttpResponse,
           pFormVarNames As %String = "",
           pData...) As %Status

構成された宛先に HTTP PUT コマンドを送信します (“宛先の指定” を参照)。フォーム・データまたは要求本文を送信します。Post() も参照してください。

PutFormDataArray()

Method PutFormDataArray(Output pHttpResponse As %Net.HttpResponse,
                        pFormVarNames As %String = "",
                        ByRef pData) As %Status

構成された宛先に HTTP PUT コマンドを送信します (“宛先の指定” を参照)。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

PutURL()

method PutURL(pURL As %String, 
              Output pHttpResponse As %Net.HttpResponse, 
              pFormVarNames As %String = "", 
              pData...) as %Status

指定された URL (pURL) に HTTP PUT コマンドを送信します。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

Delete()

method Delete(Output pHttpResponse As %Net.HttpResponse, 
              pFormVarNames As %String = "", 
              pData...) as %Status

構成された宛先に HTTP DELETE コマンドを送信します (“宛先の指定” を参照)。フォーム・データまたは要求本文を送信します。Post() も参照してください。

DeleteFormDataArray()

method DeleteFormDataArray(Output pHttpResponse As %Net.HttpResponse, 
                           pFormVarNames As %String = "", 
                           ByRef pData) as %Status

構成された宛先に HTTP DELETE コマンドを送信します (“宛先の指定” を参照)。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

DeleteURL()

method DeleteURL(pURL As %String, 
              Output pHttpResponse As %Net.HttpResponse, 
              pFormVarNames As %String = "", 
              pData...) as %Status

指定された URL (pURL) に HTTP DELETE コマンドを送信します。指定されたフォーム変数にフォーム・データを送信します。PostFormDataArray() も参照してください。

SendFormDataArray()

Method SendFormDataArray(Output pHttpResponse As %Net.HttpResponse,
                        pOp As %String,
                        pHttpRequestIn As %Net.HttpRequest,
                        pFormVarNames As %String = "",
                        ByRef pData) As %Status

構成された宛先に HTTP 要求を送信します (“宛先の指定” を参照)。指定されたフォーム変数にフォーム・データを送信します。

pOp 引数は、実行する HTTP アクションを指定します。これは、"POST"、"GET"、"PUT" のいずれかです。

pFormVarNames は、使用するフォーム変数名のカンマ区切りのリストです。リスト内の各名前に対して、pData 引数を提供します。

pData 引数は配列です。GetFormDataArray() メソッドも参照してください。

特別なニーズに対しては、%Net.HTTPRequest またはサブクラスのインスタンスを作成し、そのプロパティを指定して、これを pHttpRequestIn 引数として使用します。これを行う場合、HTTP 要求はインスタンスのプロパティを使用して初期化されます。このメソッドを使用すると、送信アダプタの他のメソッドよりも詳細な制御が可能になります。例えば、このメソッドを使用すると、独自の HTTP ヘッダを要求に追加できます。

HTTP 応答の処理

これまでに説明したメソッドを使用する場合、出力として、HTTP 応答を受信します。このオブジェクトは %Net.HttpResponseOpens in a new tab のインスタンスです。このオブジェクトの使用法については、“HTTP 応答の使用法” の章で説明します。

Cookie の管理

Cookie とは応答ヘッダ内のテキスト文字列です。サーバはクライアントに対して、この文字列を保存し、その後の HTTP 要求でヘッダ値として返すように要求できます。一部のサーバは、Cookie を使用してオープン・セッションを維持します。

EnsLib.HTTP.OutboundAdapterOpens in a new tab は、Cookie を管理するための以下のプロパティおよびメソッドも提供します。カスタム・メソッドでこれらを使用できます。

UseCookies プロパティ

このアダプタをインスタンス化するときに HTTP 応答で受信される Cookie を保存するどうか、また、その後の各 HTTP 要求に挿入するかどうかを指定します。UseCookies が真の場合、そのアダプタのインスタンスに関連するすべてのジョブで Cookie のコレクションを保持し、そのジョブが新しく要求を送信するたびに適切な Cookie を選択して一緒に送信します。UseCookies が偽 (0) の場合、Cookie は送信されません。この規則により、各ジョブは要求元の Web サーバと独自の永続セッションを維持できます。

デフォルトは偽です。このプロパティは、実行時設定としても使用できます。

%Cookies プロパティ

Cookie の配列を格納します。ドメイン/サーバによってインデックス化されます。各要素は $LB(name, domain, path, value, expires, secure) です。このプロパティは Caché 多次元配列です。

DeleteCookie() メソッド

Method DeleteCookie(pName As %String,
                pPath As %String,
                pDomain As %String) As %Status

特定の Cookie を削除します。

DeleteCookies() メソッド

Method DeleteCookies(pDomain As %String = "",
                pPath As %String = "") As %Status

指定されたドメインやパスからすべての Cookie を削除します。

Note:

Cookie はある HTTP サーバに固有のものです。Cookie を挿入する場合は、特定のサーバへの接続を使用しており、他のサーバではその Cookie を使用できません。

カスタム HTTP 要求の作成

HTTP 送信アダプタの一般的なメソッド (Get など) を使用すると、アダプタは自動的に HTTP 要求を作成および送信します。この HTTP 要求にはフォーム・データまたは要求本文を含めることができます。特別な場合には、カスタム HTTP 要求を作成して、プロキシ認証や異なる文字エンコードなどの詳細を指定することもできます。

カスタム要求を送信するには、HTTP 送信アダプタの SendFormDataArray() メソッドを使用します。この方法については、前の章の “HTTP コマンドの呼び出し” を参照してください。その後、"Caché インターネット・ユーティリティの使用法" の “HTTP 要求の送信と HTTP 応答の読み取り” の章を参照してください。

HTTP 応答の使用法

送信アダプタを使用して HTTP 要求を送信した後、応答オブジェクト (%Net.HttpResponseOpens in a new tab) を受信します。具体的には、HTTP.OutboundAdapter の主要メソッドによって HTTP 要求を送信できます。これらのすべてのメソッドで、返信として送信される HTTP 応答にアクセスできます。

PostFormData()、PostFormDataArray()、GetFormData()、または GetFormDataDataArray メソッドを使用した場合は、メソッド呼び出しの最初の引数の出力として HTTP 応答が返されます。この引数は %Net.HttpResponseOpens in a new tab のインスタンスです。
SendFormDataArray() メソッドを使用した場合は、要求の HttpResponse プロパティが更新されます。このプロパティは %Net.HttpResponseOpens in a new tab のインスタンスです。

これらのメソッドの詳細は、“HTTP 送信アダプタの使用法” の章の “HTTP コマンドの呼び出し” を参照してください。

HTTP 応答の使用法の詳細は、"Caché インターネット・ユーティリティの使用法" の “HTTP 要求の送信と HTTP 応答の読み取り” を参照してください。

例

この節では、2 つの例を示します。

Post の使用例

以下の例は、HTTP 送信アダプタを使用して、構成された宛先に XML メッセージを送信します。まず、ビジネス・オペレーション・クラスは以下のとおりです。

Class EHTTP.PostService Extends Ens.BusinessOperation
{

Parameter ADAPTER = "EnsLib.HTTP.OutboundAdapter";

Parameter INVOCATION = "Queue";

Method PostMessage(pRequest As EHTTP.Request.OutboundPost,
Output pResponse As EHTTP.Response.OutboundPost) As %Status
{
  Set $ZT="Trap",tSC=$$$OK
  do {

    set tResponse = ##class(%Net.HttpResponse).%New()
    set tsc = ..Adapter.Post(.tResponse,,pRequest.MessageStream)
    set stream = ""

    set pResponse = ##class(EHTTP.Response.OutboundPost).%New()
    set len = tResponse.Data.SizeGet()
     While (tResponse.Data.AtEnd = 0) {
      do pResponse.MessageStream.Write(tResponse.Data.Read())
     }
    Quit
  } while (0)
Exit
  Quit tSC
Trap
  Set $ZT="",tSC=$$$EnsSystemError
  Goto Exit
}

XData MessageMap
{
<MapItems>
  <MapItem MessageType="EHTTP.Request.OutboundPost">
    <Method>PostMessage</Method>
  </MapItem>
</MapItems>
}

}

要求メッセージ・クラスは以下のとおりです。

Class EHTTP.Request.OutboundPost Extends Ens.Request
{

/// MessageStream contains the complete SOAP Message to post
Property MessageStream As %GlobalCharacterStream(CONTENT = "MIXED");

}

応答メッセージ・クラスは以下のとおりです。

Class EHTTP.Response.OutboundPost Extends Ens.Response
{

/// MessageStream contains the Response to the SOAP Message post
Property MessageStream As %GlobalCharacterStream(CONTENT = "MIXED");

}

Get の使用例

以下の例では、Get() メソッドを使用しています。

Method GetKPI(pRequest As EHTTP.Request.GetKPI,
ByRef pResponse As EHTTP.Response.GetKPI) As %Status
{
   set $ZT="ErrTrap",tSC=$$$OK
   do {
      set pResponse=##class(EHTTP.Response.GetKPI).%New()

      set tFormVar="KPINAME,PHYSICIAN,ROLE,PERIOD"

      set tRole=pRequest.UserRole
      set tUserID=pRequest.UserID
      set tED=pRequest.EffectiveDate
      set tYear=$p(tED,"-",1)
      set tMonth=$p(tED,"-",2)
      set tPeriod=tYear_tMonth

      if tRole="MFA" set tUserID="MEDICAL FACULTY ASSOCIATES"

      set tSC=..Adapter.Get
        (.tResponse,tFormVar,pRequest.KPI,tUserID,tRole,tPeriod)

      if '$IsObject(tResponse) Quit
      ;
      ;now parse the XML stream
      ;
      set reader=##class(%XML.Reader).%New()
      do tResponse.Data.Rewind()
      set ^drltrace("xml")=tResponse.Data.Read(32000)
      do tResponse.Data.Rewind()
      set tSC=reader.OpenStream(tResponse.Data)
      if $$$ISERR(tSC) {
         $$$LOGWARNING("Unable to open the XML Stream returned from IDX")
         $$$TRACE("XML request probably failed")
         do tResponse.Data.Rewind()
         set traceline=tResponse.Data.Read(1000)
         $$$TRACE(traceline)
         set tSC=$$$OK
         quit
      }
      ;
      ;Associate a class name with the XML element Name
      do reader.Correlate("KPIResult","EHTTP.IDX.KPIResult")

      if reader.Next(.tResults,.tSC)
      {

         set pResponse.KPIValues=tResults.KPIValues

      }
      if tSC=0 {
         $$$TRACE("Error reading values from IDX")
      }
   } while (0)
Exit
   Quit tSC
ErrTrap
   set $ZT="",tSC=$$$EnsSystemError
   goto Exit
}

この例は、対象のサーバから XML ファイルを取得して、そのファイルを解析し、特定のデータを取得します。

ビジネス・オペレーションの追加と構成

ビジネス・オペレーションを Ensemble プロダクションに追加するには、管理ポータルを使用して以下の操作を行います。

カスタム・ビジネス・オペレーション・クラスのインスタンスを Ensemble プロダクションに追加します。
特定の外部データ・ソースと通信を行うためのアダプタを構成します。具体的には、以下を行います。
- HTTP 要求の宛先の指定
- オプションのプロキシ・サーバの指定
ビジネス・オペレーションを有効化します。
プロダクションを実行します。

宛先サーバと URL パスの指定

以下の実行時設定を使用して、HTTP 要求を送信する宛先を指定します。

例

例えば、送信先の URL が http://122.67.980.43/HTTPReceive.aspx であるとします。

この場合、以下の設定を使用します。

設定	値
HTTPServer	122.67.980.43
URL	HTTPReceive.aspx

プロキシ・サーバの指定

必要な場合は、以下の実行時設定を使用して、プロキシ・サーバを介して HTTP 要求をルーティングします。