多次元ストレージの使用法 (グローバル)

グローバルの生成

新しいグローバルを生成するための設定作業は一切必要ありません。 グローバルにデータを設定するだけで、自動的に新しいグローバル構造が生成されます。 グローバル (またはグローバル添え字) を生成し、1 回の演算でそこにデータを置くことができます。グローバル (または添え字) を生成し、NULL 文字列を設定すれば空のグローバルのままとなります。ObjectScript では、これらの処理は SET コマンドを使用して実行します。

以下の例は、Color という名のグローバルが存在しなければそれを定義し、値 “Red” と関連付けます。Color という名前のグローバルが既に存在する場合は、新規の情報を格納できるようにそのグローバルを修正します。

Caché Basic では、以下のとおりです。

^Color = "Red"

ObjectScript では以下のようになります。

 SET ^Color = "Red"

グローバル・ノードに格納するデータ

グローバル添え字ノードに値を格納するには、他の変数配列と同様に、グローバル・ノードの値を設定します。指定したノードが存在していない場合は、そのノードを生成します。既に存在している場合、既存の値を新しい値に置き換えます。

式を使用して、グローバルにノードを指定します (グローバル参照)。グローバル参照は、キャレット文字 (^)、グローバル名、および必要に応じて 1 つ以上の添え字値で構成します。添え字は括弧 “( )” で囲み、コンマで区切ります。各添え字値は、それ自身がリテラル値、変数、論理式、グローバル参照などの式です。

グローバル・ノードの値の設定は、アトミック処理です。これは、正常に実行できることが保証されており、整合性を確保するためのロックを使用する必要もありません。

以下は、すべて有効なグローバル参照です。

Caché Basic では、以下のとおりです。

^Data = 2
^Data("Color") = "Red"
^Data(1,1) = 100
^Data(^Data) = 10     ' The value of ^Data is the subscript
^Data(a,b) = 50       ' The values of local variables a and b are subscripts
^Data(a + 10) = 50    

ObjectScript では以下のようになります。

   SET ^Data = 2
   SET ^Data("Color")="Red"
   SET ^Data(1,1)=100        /* The 2nd-level subscript (1,1) is set
                                to the value 100. No value is stored at
                                the 1st-level subscript (^Data(1)). */   
   SET ^Data(^Data)=10       /* The value of global variable ^Data 
                                is the name of the subscript. */
   SET ^Data(a,b)=50         /* The values of local variables a and b
                                are the names of the subscripts. */
   SET ^Data(a+10)=50       

ObjectScript を使用している場合、間接演算を使用して、実行時にグローバル参照を構築できます。

グローバル・ノードへの構造化されたデータ格納

各グローバル・ノードは最長 32K 文字の単独の文字列を含むことが可能です。

データは通常、以下のいずれかの方法でノード内に格納されます。

• 最長 32K 文字の 1 文字列 (正確には 32K マイナス 1 文字)。

• 文字で区切った複数のデータ部分で構成する文字列。

  区切り文字を使用してノード内にフィールド一式を格納するには、結合演算子 (_) を使用して値を連結します。以下の ObjectScript の例は、区切り文字として # 記号を使用しています。

     SET ^Data(id)=field(1)_"#"_field(2)_"#"_field(3)
  

  

  データ取得の際、$PIECE 関数を使用してフィールドを分離できます。

     SET data = $GET(^Data(id))
     FOR i=1:1:3 {
       SET field(i) = $PIECE(data,"#",i)
       }
     QUIT

  

• 複数のデータを含む、$LIST でコード化した文字列。

  $LIST 関数は、区切り文字を予約する必要がない特殊な長さエンコード法を使用します (これは Caché オブジェクトと SQL で使用する既定の構造です)。

  ノード内にフィールド一式を格納するには、$LISTBUILD 関数を使用してリストを構築します。

     SET ^Data(id)=$LISTBUILD(field(1),field(2),field(3))
  

  

  データ取得の際、$LIST 関数または $LISTGET 関数を使用してフィールドを分離できます。

     SET data = $GET(^Data(id))
     FOR i = 1:1:3 {
         SET field(i)=$LIST(data,i)
         }
     QUIT

  

• 大きなデータの一部 (ストリームや “BLOB”など)。

  個々のノードの容量が 32K に限られているので、例えばストリームのような大規模な構造は、連続した複数のノードにデータを格納することで実装します。

     SET ^Data("Stream1",1) = "First part of stream...."
     SET ^Data("Stream1",2) = "Second part of stream...."
     SET ^Data("Stream1",3) = "Third part of stream...."
  

  

  ストリームをフェッチするコード (%GlobalCharacterStreamOpens in a new tab クラスで提供されるコードなど) は、連続した文字列としてデータを提供する構造で、継続的にノードをループします。

• 文字列。

  ビットマップ・インデックスを実装する場合は、インデックス・グローバルのノード値をビット文字列に設定します。ビットマップ・インデックスとは、ビット文字列のビットがテーブルの行に対応するインデックスです。Caché は、エンコーディング・ビット文字列に圧縮アルゴリズムを使用します。したがって、ビット文字列は、Caché の $BIT 関数を使用してのみ操作できます。ビット文字列に関する詳細は、“ビット文字列関数の概要” を参照してください。

• 空ノード。

  必要なデータがノード自体に収められている場合、一般的には実際の添え字を NULL 文字列 ("") に設定します。例えば、名前を ID 値に関連付けるインデックスであれば、通常は以下のとおりです。

    SET ^Data("APPLE",1) = ""
    SET ^Data("ORANGE",2) = ""
    SET ^Data("BANANA",3) = ""

  

$GET 関数

ObjectScript では、$GET 関数を使用してグローバル・ノードの値を取得することもできます。

   SET mydata = $GET(^Data("Color"))

指定ノードの値を取得する (存在する場合) か、ノードに値がない場合は NULL 文字列 ("") を返します。$GET のオプションの 2 番目の引数を使用して、ノードに値がない場合に指定された既定値を返すこともできます。

WRITE コマンド、ZWRITE コマンド、ZZDUMP コマンド

ObjectScript のさまざまな表示コマンドを使用して、グローバルやグローバル・サブノードのコンテンツを表示できます。WRITE コマンドは、指定されたグローバルやサブノードの値を文字列として返します。ZWRITE コマンドは、グローバル変数名とその値、および下位ノードとその値を返します。ZZDUMP コマンドは、指定されたグローバルやサブノードの値を 16 進数ダンプ形式で返します。

$ORDER (Next / Previous) 関数

ObjectScript の $ORDER 関数 (および Caché Basic の Traverse) では、グローバル内の各ノードに順にアクセスできます。

$ORDER 関数は、指定されたレベル (添え字番号) で次の添え字値を返します。例えば、以下のグローバルを定義するとします。

 Set ^Data(1) = ""
 Set ^Data(1,1) = ""
 Set ^Data(1,2) = ""
 Set ^Data(2) = ""
 Set ^Data(2,1) = ""
 Set ^Data(2,2) = ""
 Set ^Data(5,1,2) = ""

最初のファースト・レベル添え字を検索するには、以下を使用します。

 SET key = $ORDER(^Data(""))

これは、NULL 文字列 ("") に続けて最初のファースト・レベル添え字を返します (NULL 文字列は、最初のエントリの前の添え字値を表すために使用します。また、以降の添え字値がないことを示す返り値としても使用されます)。この例では、key が値 1 を含みます。

1、または $ORDER 式の key を使用して、2 番目のファースト・レベル添え字を検索できます。

 SET key = $ORDER(^Data(key))

key に初期値 1 がある場合、この文で 2 に設定されます (^Data(2) が次のファースト・レベル添え字であるため)。この文を再度実行すると、key は次のファースト・レベル添え字の 5 に設定されます。^Data(5) に直接格納されているデータはありませんが、5 を返すという点に注意してください。この文を再実行しても、これ以上ファースト・レベル添え字が存在しないため、key は NULL 文字列 ("") に設定されます。

追加の添え字を $ORDER 関数で使用することで、異なる添え字レベルを繰り返すことができます。$ORDER は、引数リストにある最終添え字の次の値を返します。以下の文は、上記のデータを使用した例です。

 SET key = $ORDER(^Data(1,""))

ここでは、^Data(1,1) が次のセカンド・レベルの添え字であるため、key が 1 に設定されます。この文を再度実行すると、key は次のセカンド・レベル添え字の 2 に設定されます。この文をもう一度実行しても、ノード ^Data(1) にはこれ以上セカンド・レベル添え字が存在しないため、key は “” に設定されます。

$ORDER によるループ

以下の ObjectScript コードは単純グローバルを定義し、そのファースト・レベル添え字をすべてループします。

 // clear ^Data in case it has data
 Kill ^Data

 // fill in ^Data with sample data
 For i = 1:1:100 {
     // Set each node to a random person's name
     Set ^Data(i) = ##class(%PopulateUtils).Name()
 }

 // loop over every node
 // Find first node
 Set key = $Order(^Data(""))

 While (key '= "") {
     // Write out contents
     Write "#", key, " ", ^Data(key),!

     // Find next node
     Set key = $Order(^Data(key))
 }

グローバルの反復

指定されたグローバルが連続値の添え字を使用する構成であることがわかっている場合は、単純な For ループでその値を使用して繰り返し処理が可能です。例えば Caché Basic では以下のとおりです。

For i = 1 To 100
    Print ^Data(i)
Next

また、ObjectScript では以下のようになります。

 For i = 1:1:100 {
     Write ^Data(i),!
 }

通常は、上記で説明した $ORDER 関数を使用することをお勧めします。その方が効率も良く、削除されたノードのようなデータ間の欠落部分を心配する必要もありません。

$QUERY 関数

サブノード間を移動して、グローバルにある各ノードと各サブノードにアクセスする場合は、ObjectScript の $QUERY 関数を使用します(または、入れ子にした $ORDER ループでも可能です)。

$QUERY 関数はグローバル参照をとり、グローバルにある次のノードのグローバル参照を含む文字列 (後にノードが続かない場合は "") を返します。$QUERY で返された値を使用するには、ObjectScript の間接演算子 (@) を使用する必要があります。

例えば、以下のグローバルを定義するとします。

 Set ^Data(1) = ""
 Set ^Data(1,1) = ""
 Set ^Data(1,2) = ""
 Set ^Data(2) = ""
 Set ^Data(2,1) = ""
 Set ^Data(2,2) = ""
 Set ^Data(5,1,2) = ""

以下は $QUERY の呼び出しです。

 SET node = $QUERY(^Data(""))

これは、node を文字列 “^Data(1)” に設定します。“^Data(1)” は、グローバルの最初のノードのアドレスです。その後、グローバルの次のノードを取得するには、$QUERY を再度呼び出し、node で間接演算子を使用します。

 SET node = $QUERY(@node)

この時点で、node は文字列 “^Data(1,1)” を含みます。

以下の例では、グローバル・ノードを設定した後、$QUERY を使用して検索し、各ノードのアドレスを記述します。

 Kill ^Data // make sure ^Data is empty

 // place some data into ^Data
 Set ^Data(1) = ""
 Set ^Data(1,1) = ""
 Set ^Data(1,2) = ""
 Set ^Data(2) = ""
 Set ^Data(2,1) = ""
 Set ^Data(2,2) = ""
 Set ^Data(5,1,2) = ""

 // now walk over ^Data
 // find first node
 Set node = $Query(^Data(""))
 While (node '= "") {
     Write node,!
     // get next node
     Set node = $Query(@node)
 }

グローバル・ノードの照合

グローバルのノードがソートされる順序 (照合と呼びます) は、グローバル自体とそのグローバルを使用しているアプリケーションの 2 段階で制御されます。

アプリケーション・レベルでは、添え字として使用される値のデータ変換を行うことで、グローバル・ノードの照合方法を制御できます (Caché SQL とオブジェクトはユーザ指定の照合機能でこれを実行します)。例えば、大文字小文字は関係なくアルファベット順でソートされた名前リストを生成する場合、一般的にその名前を大文字で表記して添え字として使用します。

 // Erase any existing data
 Kill ^Data
 
 // Define a set of global nodes for sorting
 For name = "Cobra","jackal","zebra","AARDVark" {
     // use UPPERCASE name as subscript
     Set ^Data($ZCONVERT(name,"U")) = name
 }

 // Now iterate and display (in order)
 Set key = $Order(^Data(""))
 While (key '= "") {
     Write ^Data(key),!  // write untransformed name
     Set key = $Order(^Data(key)) // next subscript
 }

この例は、添え字が大文字小文字を区別せずにソートされるように、名前をそれぞれ大文字に変換します ($ZCONVERT 関数を使用します)。元の値が表示されるように、各ノードには未変換の値を保持します。

数値添え字と文字列値添え字

数値は文字列値より先に照合されます。つまり、1 の値は “a” の値よりも先に処理されます。指定された添え字に対して数値と文字列値の両方を使用する場合は、この事実は認識しておく必要があります。(値を基にデータをソートするため) インデックスにグローバルを使用する場合、通常、値は数字 (例えば給与) としてソートするか、文字列 (例えば郵便番号) としてソートします。

数値的に照合されたノードに対する一般的な解決法としては、単項演算子 + を使用して、添え字値を強制的に数値にします。例えば、id 値を age でソートするインデックスを構築する場合、以下のように age が必ず数値になるように強制できます。

 Set ^Data(+age,id) = ""

値を文字列としてソートする場合は (例えば “0022”、“0342”、“1584”)、スペース文字 (“ ”) を付けることで、添え字値が必ず文字列となるように強制できます。例えば、id 値を zipcode (郵便番号) でソートするインデックスを構築する場合、以下のように zipcode が必ず文字列になるように強制できます。

 Set ^Data(" "_zipcode,id) = ""

これにより、“0022” など、先頭に 0 が付く値は常に文字列として扱われます。

$SORTBEGIN 関数と $SORTEND 関数

通常、Caché 内データのソートに関しては心配する必要はありません。SQL を使用するか直接グローバル・アクセスを使用するかによって、自動的にソート処理されます。

しかし、場合によっては、さらに効率的なソート処理が可能な場合もあります。特に、(1) 順不同 (つまりソートされていない状態) で多数のグローバル・ノードを設定する必要があり、(2) 結果グローバルの合計サイズが Caché バッファ・プールの大部分を占める場合は、(データがキャッシュに収まりきらないので) SET 処理の多くはディスクで処理されるようになります。この結果、パフォーマンスが悪影響を受けることがあります。通常は、一時グローバルの大容量データのロード、インデックスの集合、インデックスなしの値のソートなど、インデックス・グローバルの生成にかかわる場合、上記のような状況になります。

これらの状況に効率的に対処するため、ObjectScript では $SORTBEGIN 関数と $SORTEND 関数が用意されています。$SORTBEGIN 関数はグローバル (またはその部分) の特別ノードを初期化します。グローバルへのデータ・セットはスクラッチ・バッファに書き込まれ、メモリ (または一時ディスク・ストレージ) でソートされます。$SORTEND 関数が処理の最後に呼び出されると、データは実際のグローバル・ストレージに順に書き込まれます。ディスク処理を以前ほど要求されずに、書き込みが適切に終了しているため、操作全体がより効率的です。

$SORTBEGIN 関数の使用法は非常に簡単です。ソートを開始する前にソート対象のグローバル名で起動し、処理が完了した時点で $SORTEND を呼び出します。

 // Erase any existing data
 Kill ^Data

 // Initiate sort mode for ^Data global
 Set ret = $SortBegin(^Data)

 // Write random data into ^Data
 For i = 1:1:10000 {
     Set ^Data($Random(1000000)) = ""
 }

 Set ret = $SortEnd(^Data)

 // ^Data is now set and sorted

 // Now iterate and display (in order)
 Set key = $Order(^Data(""))
 While (key '= "") {
     Write key,!
     Set key = $Order(^Data(key)) // next subscript
 }

$SORTBEGIN 関数はグローバル作成の特殊なケースに対して設計されており、使用の際には注意が必要です。特に $SORTBEGIN モードの場合、書き込みをしているグローバルからの読み取りはできません。これは、データが書き込まれていないと、読み取りが正しく行われないためです。

Caché SQL は自動的にこれら関数を使用して、一時インデックス・グローバルを作成します。これは、インデックスの付いていないフィールドでのソート処理などで使用します。

ロックとトランザクション

トランザクションを分離し、修正されたデータがトランザクションのコミット前に他のプロセスから見えないようにするには、ロックを使用する必要があります。ObjectScript では、LOCK コマンドを使用して、ロックを直接取得および解放できます。ロックは規約に従って機能します。指定されたデータ構造 (永続オブジェクトに使用されるものなど) に対し、ロックを必要とするすべてのコードは、すべて同じ論理ロック参照 (例えば LOCK コマンドによって同じアドレスが使用される) を使用します。

トランザクションでは、ロックは独特の動作をします。つまり、トランザクション中に取得されたすべてのロックは、トランザクションが終了するまで解放されません。その理由を、通常のトランザクションで実行されるアクションで考えてみます。

1. TSTART を使用して、トランザクションを開始します。

2. 修正を希望するノード (単数または複数) で、ロック (単数または複数) を取得します。これは通常 “書き込み” ロックと呼ばれます。

3. ノード (1 つ、または複数) を変更します。

4. ロック (1 つ、または複数) を解放します。トランザクション中のため、これらのロックはこの時点では実際には解放されません。

5. TCOMMIT を使用して、トランザクションを終了します。この時点で、前の手順で解放したすべてのロックが実際に解放されます。

他のプロセスがこのトランザクションに関連するノードを見る際に、コミットされていない変更箇所が表示されないようにする場合は、そのノードからデータを読み取る前にロック (“読み取り” ロックと呼ばれます) のテストを行います。書き込みロックはトランザクション終了まで保持されているので、トランザクションが完了 (コミットまたはロールバック) するまで、読み取りプロセスにはデータが表示されません。

大半のデータベース管理システムが、類似した機能を使用して、トランザクション分離を提供します。Caché は、このメカニズムを開発者が使用できるという点がユニークです。トランザクションをサポートしているときでも、新規アプリケーション・タイプのカスタム・データベース構造の生成を可能にします。当然、Caché オブジェクトまたは SQL でデータの管理やトランザクション管理を自動的に行うことができます。

入れ子にされた TSTART の呼び出し

Caché には、特別なシステム変数 $TLEVEL があります。これは、TSTART コマンドを呼び出した回数をトラッキングします。$TLEVEL は値 0 から始まります。TSTART を呼び出すたびに $TLEVEL の値は 1 ずつインクリメントされます。また、TCOMMIT を呼び出すたびに値が 1 ずつディクリメントされます。TCOMMIT の呼び出しによって $TLEVEL が 0 に戻ると、トランザクションは (コミットされて) 終了します。

TROLLBACK コマンドへの呼び出しは常に、現在のトランザクションを終了させ、$TLEVEL をその値に関係なく元の 0 に設定します。

この動作をアプリケーションで利用すると、トランザクションを含むコード (オブジェクト・メソッドなど) を別のトランザクションで包むことができます。例えば、永続オブジェクトに備わっている %Save メソッドは、常に、トランザクションとしてのオペレーションを実行します。TSTART と TCOMMIT を明示的に呼び出すことで、複数のオブジェクト保存処理を含むさらに大きなトランザクションを生成することができます。

 TSTART
 Set sc = object1.%Save()
 If ($$$ISOK(sc)) {
     // first save worked, do the second
    Set sc = object2.%Save()
 }

 If ($$$ISERR(sc)) {
     // one of the saves failed, rollback
     TROLLBACK
 }
 Else {
     // everything is ok, commit
  TCOMMIT
 }

ネイキッド・グローバル参照

Caché は、添え字付きグローバル参照の後にグローバル名と添え字レベルを示すネイキッド・インジケータを設定します。その後、ネイキッド・グローバル参照を使用して、同じグローバルと添え字レベルに連続して参照を作成します。グローバル名と上位レベルの添え字は削除されます。これにより、同じ (または下位の) 添え字レベルの同じグローバルに対する参照の繰り返しを能率的に行います。

ネイキッド参照に下位の添え字レベルを指定すると、そのレベルに合わせてネイキッド・インジケータがリセットされます。したがって、ネイキッド・グローバル参照を使用する場合、常に最新のグローバル参照で構築した添え字レベルで作業することになります。

ネイキッド・インジケータ値は、$ZREFERENCE 特殊変数に記録されます。この値は NULL 文字列に初期化されます。ネイキッド・インジケータが設定されていない状態でネイキッド・グローバル参照を試みると、<NAKED> エラーが生じます。ネームスペースを変更すると、ネイキッド・インジケータも再初期化されます。$ZREFERENCE を NULL 文字列 ("") に設定することで、ネイキッド・インジケータを再初期化できます。

以下の例は、添え字付きのグローバル ^Produce("fruit",1) が最初の参照に指定されています。Caché は、このグローバル名と添え字をネイキッド・インジケータに保存します。したがって、次のネイキッド・グローバル参照ではグローバル名 "Produce" と上位の添え字レベル "fruit" を省略できます。^(3,1) ネイキッド参照が下位の添え字レベルに移動した場合、この新規の添え字レベルが、その後に続くネイキッド・グローバル参照の条件となります。

   SET ^Produce("fruit",1)="Apples"  /* Full global reference  */
   SET ^(2)="Oranges"                /* Naked global references */
   SET ^(3)="Pears"                  /* assume subscript level 2 */
   SET ^(3,1)="Bartlett pears"       /* Go to subscript level 3  */
   SET ^(2)="Anjou pears"            /* Assume subscript level 3 */
   WRITE "latest global reference is: ",$ZREFERENCE,!
   ZWRITE ^Produce
   KILL ^Produce

この例は、グローバル変数 ^Produce("fruit",1)、^Produce("fruit",2)、^Produce("fruit",3)、^Produce("fruit",3,1)、^Produce("fruit",3,2) を設定します。

例外はありますが、ほとんどのグローバル参照 (完全あるいはネイキッド) がネイキッド・インジケータを設定します。$ZREFERENCE 特殊変数は、ネイキッド・グローバル参照の場合でも、最新のグローバル参照の完全なグローバル名と添え字を保持しています。ZWRITE コマンドも、ネイキッド参照を使用して設定したかどうかにかかわらず、各グローバルの完全な名前と添え字を表示します。

ネイキッド・グローバル参照は注意して使用する必要があります。Caché は、ネイキッド・インジケータを常に明確に設定するわけではないからです。以下はその例です。

• ネイキッド・インジケータは、完全グローバル参照によって最初に設定されます。そのグローバル参照が失敗しても、それ以降の完全グローバル参照やネイキッド・グローバル参照によって、ネイキッド・インジケータが変更されます。例えば、存在しないグローバルの値を WRITE しようとすると、ネイキッド・インジケータが設定されます。

• 添え字付きのグローバルを参照するコマンド後置条件では、Caché が後置条件を評価する方法に関係なく、ネイキッド・インジケータが設定されます。

• 添え字付きのグローバルを参照するオプション関数の引数は、Caché がすべての引数を評価するかどうかによって、ネイキッド・インジケータを設定する場合としない場合があります。例えば、$GET の 2 番目の引数を指定すると、その既定値が使用されなくても、必ずネイキッド・インジケータが設定されます。Caché は、左から右の順番で引数を評価します。したがって、最後の引数は、最初の引数で設定されたネイキッド・インジケータをリセットする場合があります。

• トランザクションをロールバックする TROLLBACK コマンドは、ネイキッド・インジケータをトランザクションの最初の値にはロールバックしません。

完全グローバル参照に拡張グローバル参照を含む場合、その後に続くネイキッド・グローバル参照は、同じ拡張グローバル参照と見なされます。つまり、ネイキッド・グローバル参照の一部として拡張参照を指定する必要はありません。