$WEXTRACT

Synopsis

$WEXTRACT(string,from,to)
$WE(string,from,to)

SET $WEXTRACT(string,from,to)=value
SET $WE(string,from,to)=value

説明

$WEXTRACT は、string の先頭から文字をカウントするか、または string の末尾からのオフセットで文字をカウントすることで、指定された位置での string 内の部分文字列を識別します。部分文字列には、1 文字または文字の範囲を指定できます。$WEXTRACT は、サロゲート・ペアを単一の文字として認識します。

$EXTRACT には、以下の 2 つの使用方法があります。

• string から部分文字列を返します。これには構文 $WEXTRACT(string,from,to) が使用されます。

• string 内の部分文字列を置き換えます。置換部分文字列は、元の部分文字列と同じ長さでも、長くても、短くてもかまいません。これには構文 SET $WEXTRACT(string,from,to)=value が使用されます。

$WEXTRACT と $EXTRACT は機能的に同じです。ただしサロゲート・ペアの処理が異なります。

部分文字列を返す方法

$WEXTRACT は、string から文字位置により部分文字列を返します。この部分文字列の抽出の特性は、使用するパラメータによって決まります。

• $WEXTRACT(string) は、文字列の先頭文字を抽出します。

• $WEXTRACT(string,from) は、from で指定した位置の 1 文字を抽出します。from の値は、文字列の最初からカウントした整数の文字数、文字列の最後の文字を指定するアスタリスク、または、文字列の最後から逆方向にカウントして指定する負の整数を持つアスタリスクになります。

  以下の例では、サロゲート・ペアを含む文字列から 1 つの文字を抽出します。$LENGTH はサロゲート・ペアを 2 文字とカウントしますが、$WEXTRACT はサロゲート・ペアを 1 文字とカウントします。

    IF $SYSTEM.Version.IsUnicode()  {
    SET hipart=$CHAR($ZHEX("D806"))
    SET lopart=$CHAR($ZHEX("DC06"))
    SET spair=hipart_lopart /* surrogate pair */
    WRITE "length of surrogate pair ",$LENGTH(spair),!
    SET mystr="AB"_spair_"DEFG"
    WRITE !,$WEXTRACT(mystr,4)    // "D" the 4th character
    WRITE !,$WEXTRACT(mystr,*)    // "G" the last character
    WRITE !,$WEXTRACT(mystr,*-5)  // "B" the offset 5 character from end
    WRITE !,$WEXTRACT(mystr,*-0)  // "G" the last character by 0 offset
    }
    ELSE {WRITE "This example requires a Unicode installation of Caché"}

  

• $WEXTRACT(string,from,to) は、from の位置から始まり、to の位置で終了する文字列の範囲 (その位置の文字を含む) を抽出します。以下の $WEXTRACT 関数は、サロゲート・ペアを単一文字とカウントして、両方とも文字列 “Alabama” を返します。

    IF $SYSTEM.Version.IsUnicode()  {
    SET hipart=$CHAR($ZHEX("D806"))
    SET lopart=$CHAR($ZHEX("DC06"))
    SET spair=hipart_lopart /* surrogate pair */
    SET var2=spair_"XXX"_spair_"Alabama"_spair
     WRITE !,$WEXTRACT(var2,6,12)
     WRITE !,$WEXTRACT(var2,*-7,*-1)
    }
    ELSE {WRITE "This example requires a Unicode installation of Caché"}

  

  from と to の位置が同じ場合、$WEXTRACT は単一の文字を返します。to の位置が from の位置よりも文字列の先頭に近い場合、$WEXTRACT は NULL 文字列を返します。

部分文字列の置換

$WEXTRACT を SET コマンドと一緒に使用して、指定した文字または文字列の範囲を別の値で置き換えることができます。また、文字列の末尾に文字を追加する場合にも使用できます。SET $WEXTRACT はサロゲート・ペアを単一の文字として認識します。

等号の左側で SET と共に $WEXTRACT を使用する場合、string は有効な変数名にすることができます。変数が存在しない場合は、SET $WEXTRACT が変数を定義します。string パラメータは、多次元プロパティ参照にすることもできますが、非多次元オブジェクト・プロパティにすることはできません。非多次元オブジェクト・プロパティで SET $WEXTRACT を使用しようとすると、<OBJECT DISPATCH> エラーが発生します。

$WEXTRACT (または $EXTRACT、$PIECE、あるいは $LIST) を伴った SET (a,b,c,...)=value 構文は、その関数で相対オフセット構文 * (文字列の末尾を表す) と *-n または *+n (文字列の末尾からの相対オフセットを表す) を使用する場合、等号の左側では使用できません。その代わりに、SET a=value,b=value,c=value,... 構文を使用する必要があります。

部分文字列の置換の詳細は、"$EXTRACT" 関数を参照してください。

例

以下の例は、サロゲート・ペアの Unicode 値を返す 2 パラメータ形式の $WEXTRACT を示します。

  IF $SYSTEM.Version.IsUnicode()  {
    SET hipart=$CHAR($ZHEX("D806"))
    SET lopart=$CHAR($ZHEX("DC06"))
    SET spair=hipart_lopart /* surrogate pair */
    SET x="ABC"_spair_"DEFGHIJK"
    WRITE !,"$EXTRACT character "
    ZZDUMP $EXTRACT(x,4)
    WRITE !,"$WEXTRACT character "
    ZZDUMP $WEXTRACT(x,4)
  }
  ELSE {WRITE "This example requires a Unicode installation of Caché"}

以下の例は、部分文字列の範囲にサロゲート・ペアを含む 3 パラメータ形式の $WEXTRACT を示します。

  IF $SYSTEM.Version.IsUnicode()  {
  SET hipart=$CHAR($ZHEX("D806"))
  SET lopart=$CHAR($ZHEX("DC06"))
  SET spair=hipart_lopart /* surrogate pair */
  SET x="ABC"_spair_"DEFGHIJK"
   WRITE !,"$EXTRACT two characters "
   ZZDUMP $EXTRACT(x,3,4)
   WRITE !,"$WEXTRACT two characters "
   ZZDUMP $WEXTRACT(x,3,4)
  }
  ELSE {WRITE "This example requires a Unicode installation of Caché"}

関連項目

• $EXTRACT 関数

• $WASCII 関数

• $WCHAR 関数

• $WFIND 関数

• $WISWIDE 関数

• $WLENGTH 関数

• $WREVERSE 関数