Using the %Dictionary Classes

Introduction to Class Definition Classes

The class definition classes provide object and SQL access to all class definitions. Using these classes, you can programmatically examine class definitions, modify class definitions, create new classes, and even write programs that automatically generate documentation. These classes are contained within the %Dictionary package.

There are two parallel sets of class definition classes: those that represent defined classes and those that represent compiled classes.

A defined class definition represents the definition of a specific class. It includes only information defined by that class; it does not include information inherited from superclasses. In addition to providing information about classes in the dictionary, these classes can be used to programmatically alter or create new class definitions.

A compiled class definition includes all of the class members that are inherited from superclasses. A compiled class definition object can only be instantiated from a class that has been compiled. You cannot save a compiled class definition.

This page discusses defined class definitions exclusively, though the operation of the compiled class definitions is similar.

The family of class definition classes that represent defined classes includes:

Browsing Class Definitions

You can use the SQL pages of the Management Portal to browse the class definition classes.

Similarly, you can programmatically browse through the class definitions using the same techniques you would use to browse any other kind of data: you can use dynamic SQL and you can instantiate persistent objects that represent specific class definitions.

For example, from within an InterSystems IRIS® data platform process, you can get a list of all classes defined within the dictionary for the current namespace by using the %Dictionary.ClassDefinition:Summary() query:

  set stmt=##class(%SQL.Statement).%New()
  set status = stmt.%PrepareClassQuery("%Dictionary.ClassDefinition","Summary")
  if $$$ISERR(status) {write "%Prepare failed:" do $SYSTEM.Status.DisplayError(status) quit}

  set rset=stmt.%Execute()
  if (rset.%SQLCODE '= 0) {write "%Execute failed:", !, "SQLCODE ", rset.%SQLCODE, ": ", rset.%Message quit}

  while rset.%Next()
  {
    write rset.%Get("Name"),!
  }
  if (rset.%SQLCODE < 0) {write "%Next failed:", !, "SQLCODE ", rset.%SQLCODE, ": ", rset.%Message quit}

This sample method will write the names of all the classes visible in the current namespace (including classes in the system library). You can filter out unwanted classes using the various columns returned by the %Dictionary.ClassDefinition:Summary() query.

You can get detailed information about a specific class definition by opening a %Dictionary.ClassDefinitionOpens in a new tab object for the class and observing its properties. The ID used to store %Dictionary.ClassDefinitionOpens in a new tab objects is the class name:

 Set cdef = ##class(%Dictionary.ClassDefinition).%OpenId("Sample.Person")
 Write cdef.Name,!

 // get list of properties
 Set count = cdef.Properties.Count()
 For i = 1:1:count {
     Write cdef.Properties.GetAt(i).Name,!
 }

Note that you must fully qualify class names with their package name or the call to %OpenId() will fail.

Modifying Class Definitions

You can modify an existing class definition by opening a %Dictionary.ClassDefinitionOpens in a new tab object, making the desired changes, and saving it using the %Save() method.

You can create a new class by creating a new %Dictionary.ClassDefinitionOpens in a new tab object, filling in its properties and saving it. When you create %Dictionary.ClassDefinitionOpens in a new tab object, you must pass the name of the class via the %New() command. When you want to add a member to the class (such as a property or method), you must create the corresponding definition class (passing its %New() command a string containing "class_name.member_name") and add the object to the appropriate collection within the %Dictionary.ClassDefinitionOpens in a new tab object.

For example:

 Set cdef = ##class(%Dictionary.ClassDefinition).%New("MyApp.MyClass")
 If $SYSTEM.Status.IsError(cdef)  {
     Do $system.Status.DecomposeStatus(%objlasterror,.Err)
     Write !, Err(Err)
 }
 Set cdef.Super = "%Persistent,%Populate"

 // add a Name property
 Set pdef = ##class(%Dictionary.PropertyDefinition).%New("MyClass:Name")
 If $SYSTEM.Status.IsError(pdef)  {
     Do $system.Status.DecomposeStatus(%objlasterror,.Err) 
     Write !,Err(Err)
 }
 
 Do cdef.Properties.Insert(pdef)

 Set pdef.Type="%String"

 // save the class definition object
 Do cdef.%Save()

See Also

• Defining Classes

• Top Level Class Syntax and Keywords