テーブルの定義

スキーマの名前付けに関する考慮事項

スキーマ名は、識別子の規約に従い、英数字以外の文字の使用法に関して多くの考慮事項があります。スキーマ名を区切り識別子として指定することはできません。“USER” またはその他の SQL 予約語をスキーマ名として指定しようとすると、SQLCODE -312 エラーとなります。INFORMATION_SCHEMA スキーマ名および対応する INFORMATION.SCHEMA パッケージ名は、すべてのネームスペースで予約されています。このスキーマおよびパッケージ内で、テーブルまたはクラスを作成しないでください。

CREATE TABLE などの create 操作を実行する場合に、まだ存在していないスキーマを指定すると、InterSystems IRIS によって新しいスキーマが作成されます。InterSystems IRIS はスキーマ名を使用して、対応するパッケージ名を生成します。スキーマの名前付け規約と対応するパッケージの名前付け規約は異なるため、ユーザは名前を変換する際の英数字以外の文字に関する考慮事項に注意する必要があります。これらの名前変換の考慮事項はテーブルと同じではありません。

• 最初の文字 ：

  • % (パーセント) ： % をスキーマ名の最初の文字として指定すると、対応するパッケージがシステム・パッケージであり、そのすべてのクラスがシステム・クラスであることを示します。この使用には、適切な特権が必要です。そうでないと、<PROTECT> エラーを示す %msg を含む SQLCODE -400 エラーが出力されます。

  • _ (アンダースコア) ： スキーマ名の最初の文字がアンダースコア文字である場合、この文字は対応するパッケージ名内で小文字の “u” に置き換えられます。例えば、スキーマ名 _MySchema は、パッケージ名 uMySchema を生成します。

• 後続の文字 ：

  • _ (アンダースコア) ： スキーマ名の最初の文字以外の任意の文字がアンダースコア文字である場合、この文字は対応するパッケージ名内でピリオド (.) に置き換えられます。ピリオドはクラス区切り文字であるため、アンダースコアはスキーマをパッケージとサブパッケージに分割します。したがって、My_Schema はパッケージ Schema を含むパッケージ My を生成します (My.Schema)。

  • @、#、$ 文字 ： スキーマ名にこれらの文字のいずれかが含まれる場合、これらの文字は対応するパッケージ名から削除されます。これらの文字を削除することで重複したパッケージ名が生成される場合、削除されたパッケージ名がさらに変更されます。削除されたスキーマ名の最後の文字が連続した整数 (0 で開始) で置き換えられ、一意のパッケージ名が生成されます。したがって、My@#$Schema はパッケージ MySchema を生成し、以降に作成される My#$Schema は、パッケージ MySchem0 を生成します。同じルールはクラス名に対応するテーブル名にも適用されます。

予約スキーマ名

INFORMATION_SCHEMA スキーマ名および対応する INFORMATION.SCHEMA パッケージ名は、すべてのネームスペースで予約されています。このスキーマおよびパッケージ内で、テーブルまたはクラスを作成しないでください。

IRIS_Shard スキーマ名は、すべてのネームスペースで予約されています。このスキーマ内で、テーブル、ビュー、またはプロシージャを作成しないでください。IRIS_Shard スキーマに格納される項目は、カタログ・クエリでも、INFORMATION_SCHEMA クエリでも表示されません。

既定のスキーマ名

• テーブル、ビュー、トリガ、またはストアド・プロシージャの作成や削除などの DDL 操作を実行する場合、未修飾名として既定のスキーマ名が指定されます。スキーマ検索パスの値は無視されます。

• 既存のテーブル、ビュー、またはストアド・プロシージャにアクセスして、SELECT、CALL、INSERT、UPDATE、DELETE などの DML 操作を実行する場合、未修飾名としてスキーマ検索パス (指定されている場合) からのスキーマ名が指定されます。スキーマ検索パスが指定されていない場合、またはスキーマ検索パスを使用して名前の付いた項目が見つからない場合、既定のスキーマ名が指定されます。

初期設定では、すべてのネームスペース (システム全体) に同じ既定のスキーマ名を使用します。すべてのネームスペースに同じ既定のスキーマ名を設定するか、現在のネームスペースに既定のスキーマ名を設定できます。

未修飾名を使用してテーブルまたはその他の項目を作成すると、InterSystems IRIS によってその項目に既定のスキーマ名と対応する永続クラス・パッケージ名が割り当てられます。名前の付いたスキーマまたは既定のスキーマが存在しない場合、InterSystems IRIS によってスキーマ (およびパッケージ) が作成され、作成した項目がそのスキーマに割り当てられます。スキーマの最後の項目を削除すると、InterSystems IRIS によって、そのスキーマ (およびパッケージ) が削除されます。スキーマ名の解析に関する以下の説明は、テーブル名、ビュー名、およびストアド・プロシージャ名にも当てはまります。

初期のシステム全体の既定の SQL スキーマ名は、SQLUser です。対応する永続クラス・パッケージ名は User です。このため、未修飾テーブル名 Employee か修飾付きテーブル名 SQLUser.Employee のいずれかによって、クラス User.Employee が生成されます。

USER は予約語であるため、スキーマ名を User (または他の SQL 予約語) にして修飾名を指定しようとすると、SQLCODE -1 エラーが返されます。

現在の既定のスキーマ名を返すには、$SYSTEM.SQL.Schema.Default()Opens in a new tab メソッドを呼び出します。

または、以下のプリプロセッサ・マクロを使用します。

#include %occConstant
  WRITE $$$DefSchema

以下のいずれかを使用して、既定のスキーマ名を変更できます。

• 管理ポータルに移動します。[システム管理] から、[構成]、[SQL およびオブジェクトの設定]、[SQL] の順に選択します。この画面で、[既定のスキーマ] の現在のシステム全体の設定を表示および編集できます。このオプションでは、システム全体の既定のスキーマ名が設定されます。このシステム全体の設定は、現在のネームスペースの SetDefault() メソッド値によってオーバーライドできます。

• $SYSTEM.SQL.Schema.SetDefault()Opens in a new tab メソッド。既定では、このメソッドはシステム全体の既定のスキーマ名を設定します。ただし、ブーリアンの 3 番目の引数 = 1 を設定することで、現在のネームスペースのみの既定のスキーマを設定できます。ネームスペースごとに異なる既定のスキーマ名が設定されている場合、$SYSTEM.SQL.CurrentSettings()Opens in a new tab メソッドは現在のネームスペースの既定のスキーマ名を返します。

スキーマ名は、対応するクラス・パッケージ名の生成に使用されます。これらの名前は名前付け規約が異なるため、同一ではない場合があります。

システム全体の既定のスキーマとして SQL 予約語を設定することで、SQL 予約語と同じ名前でスキーマを作成できますが、これは推奨されません。クラスの命名の一意性に関する規約に従って、User という名前の既定のスキーマにより、対応するクラス・パッケージ名 Use0 が生成されます。

スキーマ検索パス

DML 操作のために既存のテーブル (またはビューかストアド・プロシージャ) にアクセスする場合、未修飾名としてスキーマ検索パスからのスキーマ名が指定されます。スキーマは、指定された順序で検索され、最初の一致が返されます。検索パスに指定されているスキーマで一致が見つからない場合、または検索パスが存在しない場合、既定のスキーマ名が使用されます (#import マクロ指示文では別の検索方法が使用され、既定のスキーマ名に "フォールスルー" することはありません)。

• 埋め込み SQL では、#sqlcompile path マクロ指示文または #import マクロ指示文を使用して、InterSystems IRIS で未修飾名の解決に使用するスキーマ検索パスを指定できます。#sqlcompile path は、最初に検出された一致で未修飾名を解決します。#import は、検索パス内にリストされているすべてのスキーマに対して一致がちょうど 1 つある場合に未修飾名を解決します。

• 以下の例では、2 つのスキーマ名を記述して検索パスを指定しています。

  #sqlcompile path=Customers,Employees

  

  詳細は、"ObjectScript の使用法" の “ObjectScript マクロとマクロ・プリプロセッサ” を参照してください。

• ダイナミック SQL では、%SchemaPath プロパティを使用して、InterSystems IRIS で未修飾テーブル名の解決に使用するスキーマ検索パスを指定できます。%SchemaPath プロパティを直接指定することも、このプロパティを %SQL.StatementOpens in a new tab の %New()Opens in a new tab メソッドの 2 つ目のパラメータとして指定することもできます。以下の例では、2 つのスキーマ名を記述して検索パスを指定しています。

    SET tStatement = ##class(%SQL.Statement).%New(0,"Customers,Employees")

  

  詳細は、"InterSystems SQL の使用法" の “ダイナミック SQL の使用法” を参照してください。

• SQL シェルでは、SQL シェル構成パラメータ PATH を使用して、InterSystems IRIS で未修飾テーブル名の解決に使用するスキーマ検索パスを指定できます。

スキーマ検索パスで指定されているスキーマのどれとも未修飾名が一致しなかったり既定のスキーマ名とも未修飾名が一致しない場合、SQLCODE -30 エラー (例えば、"SQLCODE: -30 メッセージ: スキーマ内でテーブル 'PEOPLE' が見つかりません: CUSTOMERS,EMPLOYEES,SQLUSER") が発行されます。

プラットフォーム固有のスキーマ名を含める

Mac で ODBC ベースのクエリを作成し、Microsoft Query を使用して Microsoft Excel から実行する場合、使用可能なテーブルのリストからテーブルを選択すると、生成されたクエリにはテーブルのスキーマ (クラスのパッケージと同等のもの) は含まれません。例えば、Sample スキーマから Person テーブルのすべての行を返すよう選択すると、生成されるクエリは以下のようになります。

SELECT * FROM Person

InterSystems IRIS では未修飾のテーブル名は SQLUser スキーマにあるものとして解釈されるため、この文は、失敗するか、間違ったテーブルからデータを返します。これを修正するには、[SQL ビュー] タブで、必要なスキーマを明示的に参照するようにクエリを編集します。クエリは以下のようになります。

SELECT * FROM Sample.Person

スキーマのリスト

INFORMATION.SCHEMA.SCHEMATAOpens in a new tab 永続クラスは、現在のネームスペース内のすべてのスキーマをリストします。

以下の例では、現在のネームスペース内のすべての非システム・スキーマの名前が返されます。

SELECT SCHEMA_NAME 
FROM INFORMATION_SCHEMA.SCHEMATA WHERE NOT SCHEMA_NAME %STARTSWITH '%'

管理ポータルの左側にある SQL インタフェースでは、スキーマ (またはフィルタ・パターンに一致する複数のスキーマ) のコンテンツを表示できます。詳細は、"スキーマ・コンテンツのフィルタ処理" を参照してください。

フィールドに基づく RowID

テーブルを投影する永続クラスを定義することで、RowID にフィールドの値またはフィールドの組み合わせの値を設定するよう定義できます。それには、IdKey インデックス・キーワードでインデックスを指定します。例えば、インデックス定義 IdxId On PatientName [IdKey]; を指定して、テーブルに PatientName フィールドの値と同じ値の RowID を設定したり、インデックス定義 IdxId On (PatientName,SSN) [IdKey]; を指定して、PatientName フィールドと SSN フィールドを組み合わせた値の RowID を設定できます。

• フィールドに基づく RowID は、システムで割り当てられる連続する正の整数を取る RowID よりも非効率的です。

• INSERT 時 ： RowID を構成するフィールドまたはフィールドの組み合わせに指定される値は、一意である必要があります。一意でない値を指定すると、SQLCODE -119 "UNIQUE あるいは PRIMARY KEY 制約が INSERT の一意性チェックに失敗しました" が生成されます。

• UPDATE 時 ： 既定では、RowID を構成する各フィールドの値は変更できません。これらのいずれかのフィールドの値を変更しようとすると、SQLCODE -107 "RowID またはフィールドに基づく RowID を UPDATE できません" が生成されます。

RowID が複数のフィールドに基づく場合、RowID 値は各コンポーネント・フィールドの値を || 演算子で結合した値になります (Ross,Betsy||123-45-6789 など)。InterSystems IRIS は複数のフィールドに基づく RowID の最大長の特定を試み、最大長を特定できない場合、RowID の長さは既定で 512 になります。

詳細は、"主キー" を参照してください。

RowID は非表示か

• CREATE TABLE を使用してテーブルを作成する際、既定では RowID は非表示です。非表示フィールドは SELECT * によって表示されず、PRIVATE です。テーブルの作成時に、%PUBLICROWID キーワードを指定すると、RowID は非表示でなくなり、PUBLIC になります。このオプションの %PUBLICROWID キーワードは、テーブル要素の CREATE TABLE コンマ区切りリスト内の任意の場所で指定できます。ALTER TABLE では指定できません。詳細は、CREATE TABLE のリファレンス・ページの "RowID フィールドと %PUBLICROWID" を参照してください。

• テーブルとして投影する永続クラスを作成する際、既定では RowID は非表示ではありません。SELECT * によって表示され、PUBLIC です。クラス・キーワード SqlRowIdPrivate を指定することで、非表示で PRIVATE の RowID で永続クラスを定義できます。

外部キー参照として使用される RowID はパブリックである必要があります。

既定では、パブリック RowID を持つテーブルをコピー元またはコピー先テーブルとして使用し、INSERT INTO Sample.DupTable SELECT * FROM Sample.SrcTable を使用してデータを重複テーブルにコピーすることはできません。

管理ポータルの SQL インタフェース [カタログの詳細] の [フィールド] リストの [隠し] 列を使用して、RowID が非表示かどうかを示すことができます。

以下のプログラムを使用して、指定したフィールド (この例では、ID) が非表示かどうかを返すことができます。

  SET myquery = "SELECT FIELD_NAME,HIDDEN FROM %Library.SQLCatalog_SQLFields(?) WHERE FIELD_NAME='ID'"
  SET tStatement = ##class(%SQL.Statement).%New()
  SET qStatus = tStatement.%Prepare(myquery)
   IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
  SET rset = tStatement.%Execute()
  DO rset.%Display()
  WRITE !,"End of data" 

テーブル内のフィールド名 (非表示および表示) をリストする方法は、“列の名前と番号” を参照してください。

RowVersion フィールド

RowVersion フィールドは、行レベルのバージョン管理を提供する、オプションのユーザ定義フィールドです。これにより、ネームスペース全体で各行のデータが変更された順序を把握できます。InterSystems IRIS はネームスペース全体を範囲とするカウンタを維持しており、行データが変更 (挿入、更新、または %Save) されるたびに、そのフィールドに一意の正の増分整数を割り当てます。このカウンタはネームスペース全体を範囲とするため、ROWVERSION フィールドを含む 1 つのテーブルでの操作によって、同じネームスペース内の ROWVERSION フィールドを含む他のすべてのテーブルで使用される ROWVERSION カウンタの増分ポイントが設定されます。

RowVersion フィールドは、フィールド・データ型 ROWVERSION を指定して作成します (%Library.RowVersionOpens in a new tab)。テーブルごとに指定できる ROWVERSION データ型フィールドは 1 つのみです。複数の ROWVERSION フィールドを含むテーブルを作成しようとすると、5320 コンパイル・エラーが発生します。

このフィールドには任意の名前を付けることができ、どの列位置にも表示できます。ROWVERSION (%Library.RowVersionOpens in a new tab) データ型は BIGINT (%Library.BigIntOpens in a new tab) にマッピングされます。

このフィールドは、自動インクリメント・カウンタから 1 で始まる正の整数を受け取ります。このカウンタは、ROWVERSION 対応テーブル内のデータが挿入、更新、または %Save 操作によって変更されると必ずインクリメントされます。インクリメントされた値は、挿入または更新された行の ROWVERSION フィールドに記録されます。

ネームスペースには、RowVersion フィールドがあるテーブルと、そのフィールドがないテーブルを含めることができます。RowVersion フィールドがあるテーブルのデータが変更された場合にのみ、ネームスペース全体のカウンタは増分されます。

テーブルにデータが入力されるときに、InterSystems IRIS は挿入された各行に対して、このフィールドに連続した整数を割り当てます。既にデータが取り込まれているテーブルに ROWVERSION フィールドを追加するために ALTER TABLE を使用する場合、このフィールドは既存のフィールドについては NULL として作成されます。その後テーブルで挿入や更新が実行されると、その行の RowVersion フィールドに連続的な整数が割り当てられます。このフィールドは読み取り専用です。RowVersion 値を変更しようとすると、SQLCODE -138 エラー : "読み取り専用フィールドを INSERT/UPDATE することはできません" が生成されます。したがって、RowVersion フィールドは固有であり変更不可であると定義されますが、必須であるまたは NULL でないとは定義されません。

RowVersion の値は必ず増分になります。再使用されることはありません。したがって、挿入と更新により割り当てられる固有の RowVersion 値は、一時的な順序です。削除操作では、このシーケンスから数字が削除されます。そのため、RowVersion 値は数字的に連続していない場合があります。

このカウンタはリセットされません。すべてのテーブル・データを削除しても、RowVersion カウンタはリセットされません。ROWVERSION フィールドを含むネームスペース内のすべてのテーブルを削除しても、このカウンタはリセットされません。

一意キーや主キーに RowVersion フィールドを含めることはできません。RowVersion フィールドは、IDKey インデックスの一部にすることはできません。

シャード・テーブルに RowVersion フィールドを含めることはできません。

RowVersion フィールドは非表示ではありません (これは SELECT * により表示されます)。

これについては以下の、同じネームスペースにある 3 つのテーブルの例で示しています。

1. それぞれ ROWVERSION フィールドがある Table1 と Table3 を作成し、ROWVERSION フィールドがない Table2 を作成します。

2. Table1 に 10 行を挿入します。そうするとこれらの行の ROWVERSION 値により、カウンタは 10 だけ増分されます。カウンタはそれより前には使用されていなかったので、1 から始まり 10 になります。

3. Table2 に 10 行を挿入します。Table2 には ROWVERSION フィールドがないので、カウンタは増分されません。

4. Table1 の 1 行を更新します。そうするとこの行の ROWVERSION 値が反映されて、カウンタは増分されます (この場合は 11 になります)。

5. Table3 に 10 行を挿入します。そうするとこれらの行の ROWVERSION 値により、カウンタは 10 だけ増分されます (12 から始まり 21 になります)。

6. Table1 の 1 行を更新します。そうするとこの行の ROWVERSION 値が反映されて、カウンタは増分されます (この場合は 22 になります)。

7. Table1 の 1 行を削除します。この場合に ROWVERSION カウンタは変更されません。

8. Table3 の 1 行を更新します。そうするとこの行の ROWVERSION 値が反映されて、カウンタは増分されます (この場合は 23 になります)。

Serial カウンタ・フィールド

SERIAL データ型 (永続クラス・テーブル定義の %Library.CounterOpens in a new tab) を使用して、1 つ以上のオプションの整数カウンタ・フィールドを指定して、テーブルへのレコードの挿入順序を記録することができます。各 Serial カウンタ・フィールドは、独自のカウンタを保持しています。

テーブルに行が挿入されると、Serial カウンタ・フィールドは自動インクリメント・カウンタから正の整数を受け取り、このフィールドに値なし (NULL) または値 0 が指定されます。ただし、ユーザは挿入中にこのフィールドにゼロ以外の整数値を指定して、テーブル・カウンタの既定をオーバーライドできます。

• INSERT がカウンタ・フィールドにゼロ以外の整数値を指定しない場合、カウンタ・フィールドは自動的に正の整数カウンタ値を受け取ります。カウントは 1 から始まります。連続する各値は、このフィールドの最大割り当てカウンタ値から 1 ずつ増加します。

• INSERT がカウンタ・フィールドにゼロ以外の整数値を指定する場合、フィールドはその値を受け取ります。これは、正または負の整数値で、現在のカウンタ値よりも小さくても大きくてもかまいません。また、このフィールドに既に割り当てられている整数にすることもできます。この値が、割り当てられたカウンタ値よりも大きい場合は、自動インクリメント・カウンタのインクリメント開始点をその値に設定します。

カウンタ・フィールドの値を UPDATE しようとすると、SQLCODE -105 エラーが返されます。

このカウンタは、TRUNCATE TABLE コマンドによって 1 にリセットされます。このカウンタは、DELETE コマンドがテーブル内のすべての行を削除した場合でも、DELETE コマンドによってはリセットされません。

シャード・テーブルに Serial カウンタ・フィールドを含めることはできません。

AutoIncrement フィールド

%Library.AutoIncrementOpens in a new tab データ型 (または BIGINT AUTO_INCREMENT) を使用して整数カウンタ・フィールドを指定し、テーブルへのレコードの挿入順序を記録することができます。テーブルごとに指定できる %AutoIncrement データ型フィールドは 1 つのみです。テーブルに行が挿入されると、このフィールドは自動インクリメント・カウンタから正の整数を受け取り、このフィールドに値なし (NULL) または値 0 が指定されます。ただし、ユーザは挿入中にこのフィールドにゼロ以外の整数値を指定して、テーブル・カウンタの既定をオーバーライドできます。

• INSERT がカウンタ・フィールドにゼロ以外の整数値を指定しない場合、カウンタ・フィールドは自動的に正の整数カウンタ値を受け取ります。カウントは 1 から始まります。連続する各値は、このフィールドの最大割り当てカウンタ値から 1 ずつ増加します。

• INSERT がカウンタ・フィールドにゼロ以外の整数値を指定する場合、フィールドはその値を受け取ります。これは、正または負の整数値で、現在のカウンタ値よりも小さくても大きくてもかまいません。また、このフィールドに既に割り当てられている整数にすることもできます。ユーザが割り当てた値は、自動インクリメント・カウンタに影響を与えません。

カウンタ・フィールドの値を UPDATE しようとすると、SQLCODE -105 エラーが返されます。

このカウンタは、TRUNCATE TABLE コマンドによって 1 にリセットされます。このカウンタは、DELETE コマンドがテーブル内のすべての行を削除した場合でも、DELETE コマンドによってはリセットされません。

シャード・テーブルには AutoIncrement フィールドを含めることができます。

埋め込み SQL での DDL の使用

ObjectScript のメソッドまたはルーチンで埋め込み SQL を使用して、DDL コマンドを呼び出すことができます。

例えば、以下のメソッドは Sample.Employee テーブルを生成します。

ClassMethod CreateTable() As %String
{
 &sql(CREATE TABLE Sample.Employee (
    EMPNUM              INT NOT NULL,
    NAMELAST            CHAR (30) NOT NULL,
    NAMEFIRST           CHAR (30) NOT NULL,
    STARTDATE           TIMESTAMP,
    SALARY              MONEY,
    ACCRUEDVACATION     INT,
    ACCRUEDSICKLEAVE    INT,
    CONSTRAINT EMPLOYEEPK PRIMARY KEY (EMPNUM)))
        
  IF SQLCODE=0 {WRITE "Table created"  RETURN "Success"}
  ELSEIF SQLCODE=-201 {WRITE "Table already exists"  RETURN SQLCODE}
  ELSE {WRITE "Serious SQL Error, returning SQLCODE"  RETURN SQLCODE_" "_%msg}
 }

このメソッドが呼び出されると、Sample.Employee テーブルの生成を試みます (同様に、対応する Sample.Employee クラスの生成も試みます)。これが成功すると、SQLCODE 変数は 0 に設定されます。失敗した場合は、SQLCODE に失敗の原因を示す SQL エラー・コードが含まれます。

このような DDL コマンドでエラーが発生する主な原因は、以下のとおりです。

• SQLCODE -99 (権限違反) ： このエラーは、ユーザがその DDL コマンドを実行する特権を持っていないことを示します。通常、これはアプリケーションが現在のユーザが誰であるかを確立していないことに起因します。これは、$SYSTEM.Security.Login()Opens in a new tab メソッドを使用して、プログラムで実行できます。

   DO $SYSTEM.Security.Login(username,password)

  

• SQLCODE -201 (テーブルまたはビュー名がユニークではありません) ： 新規のテーブルを生成する際に、既に存在するテーブル名を使用した場合に、このエラーが表示されます。

クラス・メソッドを使用した DDL の実行

ObjectScript では、ダイナミック SQL %SQL.StatementOpens in a new tab オブジェクトを使用して、ダイナミック SQL を使用した DDL コマンドの作成と実行が可能です。

以下に示す例では、ダイナミック SQL を使用してテーブルを作成するクラス・メソッドを定義しています。

  Class Sample.NewT
  {
  ClassMethod DefTable(user As %String,pwd As %String) As %Status [Language=objectscript]
    {
    DO ##class(%SYSTEM.Security).Login(user,pwd)
    SET myddl=2
    SET myddl(1)="CREATE TABLE Sample.MyTest "
    SET myddl(2)="(NAME VARCHAR(30) NOT NULL,SSN VARCHAR(15) NOT NULL)"
    SET tStatement=##class(%SQL.Statement).%New()
    SET tStatus=tStatement.%Prepare(.myddl)
      IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
    SET rset=tStatement.%Execute()
    IF rset.%SQLCODE=0 {WRITE "Created a table"}
    ELSEIF rset.%SQLCODE=-201 {WRITE "table already exists"}
    ELSE {WRITE "Unexpected error SQLCODE=",rset.%SQLCODE}
    }
  }

このメソッドは、以下のように呼び出します。

  DO ##class(Sample.NewT).DefTable("myname","mypassword")

埋め込み SQL の例と同様に、現在ログインしているユーザがいない場合、このメソッドは失敗します。

DDL スクリプトのインポートおよび実行によるテーブルの定義

InterSystems SQL DDL スクリプト・ファイルをインポートするには、ターミナル・セッションからインタラクティブに $SYSTEM.SQL.Schema.Run()Opens in a new tab メソッドを使用するか、バックグラウンド・ジョブとして $SYSTEM.SQL.Schema.ImportDDL("IRIS")Opens in a new tab メソッドを使用します。このメソッドでは複数の SQL コマンドをインポートおよび実行でき、ユーザは txt スクリプト・ファイルを使用してテーブルおよびビューを定義し、これらにデータを入力することができます。詳細は、このドキュメントの "SQL コードのインポート" の章を参照してください。

他のベンダのリレーショナル・データベースから InterSystems IRIS にテーブルを移行する際、テキスト・ファイル内に 1 つ以上の DDL スクリプトが存在していることがあります。InterSystems IRIS には、そのようなテーブルを InterSystems IRIS にロードする際に役立ついくつかの %SYSTEM.SQL.SchemaOpens in a new tab メソッドが用意されています。汎用の ImportDDL()Opens in a new tab メソッドまたは特定ベンダ用の %SYSTEM.SQL.SchemaOpens in a new tab ロード・メソッドを使用できます。ベンダ固有の SQL は、InterSystems SQL に変換されて実行されます。エラーおよびサポートされない機能は、ログ・ファイルに記録されます。詳細は、このドキュメントの “SQL コードのインポート” の章の "コード移行 ： 非 InterSystems SQL のインポート" を参照してください。

例えば、ObjectScript コマンド行から Oracle DDL ファイルをロードするには、以下の手順を実行します。

1. InterSystems IRIS ランチャー・メニューの [ターミナル] コマンドを使用して、ターミナル・セッションを開始します。

2. テーブル定義をロードしたいネームスペースに切り替えます。

    SET $namespace = "MYNAMESPACE"

   

3. 目的の DDL インポート・メソッドを呼び出します。

    DO $SYSTEM.SQL.Schema.LoadOracle()

   

   ターミナルに表示された指示に従います。

プロパティ・パラメータの定義

永続クラスにテーブルを定義すると、そのテーブルの列に、定義したプロパティが投影されます。すべてのプロパティ定義では、そのプロパティの基となっているクラスを指定するデータ型クラスを指定する必要があります。指定したデータ型により、プロパティで使用できる値がそのデータ型に制限されます。テーブルに投影される永続クラスを定義する際、%Library パッケージのクラスを使用して、このデータ型を指定する必要があります。このクラスは、%Library.Datatype として、または %Datatype として指定できます。

多くのデータ型クラスには、使用できるプロパティ値を詳細に定義するためのパラメータが用意されています。これらのパラメータは、個々のデータ型に固有です。より一般的なデータ定義パラメータの一部を以下に示します。

• プロパティ値の制限

• 許可されるプロパティ値

• 一意のプロパティ値

• 計算プロパティ値

データがフィールドに挿入、またはフィールドで更新されると、InterSystems SQL は自動的にデータを検証して、データ型および参照整合性制約を適用します。他の方法でテーブルにデータを入力する場合は、テーブル・データを検証する必要があります。

許可されるプロパティ値

以下の 2 つの方法で、実際のプロパティ値を制限できます。

• 使用できる値のリスト (VALUELIST および DISPLAYLIST で列挙された値)。

• 使用できる値の一致パターン (PATTERN)。

列挙されるプロパティ値

テーブルを永続クラスとして定義することで、指定した特定の値のみを設定できるプロパティ (列) を定義できます。このためには、VALUELIST パラメータを指定します。VALUELIST (論理ストレージ値のリストを指定) は通常、DISPLAYLIST (対応する表示値のリストを指定) と共に使用されます。どちらのリストも、リスト区切り文字で始まります。複数のデータ型が VALUELIST および DISPLAYLIST を指定できます。次の例では、列挙された値を持つ 2 つのプロパティを定義します。

Class Sample.Students Extends %Persistent 
{
Parameter USEEXTENTSET = 1;

Property Name As %String(MAXLEN=50) [Required];
Property DateOfBirth As %Date;
Property ChoiceStr As %String(VALUELIST=",0,1,2",DISPLAYLIST=",NO,YES,MAYBE");
Property ChoiceODBCStr As %EnumString(VALUELIST=",0,1,2",DISPLAYLIST=",NO,YES,MAYBE");

Index BitmapExtent [ Extent, Type = bitmap ];
}

VALUELIST が指定されている場合、INSERT または UPDATE は VALUELIST にリストされているいずれかの値のみを指定でき、それ以外の場合は値なし (NULL) が指定されます。VALUELIST の有効な値では、大文字と小文字が区別されます。必須のプロパティでは、VALUELIST の値に一致しない値を指定すると、INSERT の場合は SQLCODE -104、UPDATE の場合は SQLCODE -105 の各検証エラーが返されます。必須ではないプロパティでは、VALUELIST の値に一致しない値は NULL 値に変換されます。

ODBC モードで表示した場合、%String および %EnumString データ型は動作が異なります。上の例では、論理モードで表示した場合、ChoiceStr と ChoiceODBCStr は共に VALUELIST 値を表示します。表示モードで表示した場合、ChoiceStr と ChoiceODBCStr は共に DISPLAYLISTT 値を表示します。ODBC モードで表示した場合、ChoiceStr は VALUELIST 値を表示し、ChoiceODBCStr は DISPLAYLIST 値を表示します。

プロパティ値のパターン・マッチング

複数のデータ型が PATTERN パラメータを指定できます。PATTERN は、使用できる値を、指定された ObjectScript パターンと一致する値に制限します。このパターンは、先頭の疑問符を省略した、引用符付きの文字列で指定します。次の例では、パターンを持つプロパティを定義します。

Class Sample.Students Extends %Persistent 
{
Parameter USEEXTENTSET = 1;

Property Name As %String(MAXLEN=50) [Required];
Property DateOfBirth As %Date;
Property Telephone As %String(PATTERN = "3N1""-""3N1""-""4N");

Index BitmapExtent [ Extent, Type = bitmap ];
}

パターンは引用符付きの文字列として指定されるため、パターンで指定されるリテラルは二重引用符で囲む必要があります。パターン・マッチングは、MAXLEN および TRUNCATE の前に適用されます。このため、MAXLEN を超え、切り捨てられる可能性のある文字列のパターンを指定する場合、パターンを “.E” で終了できます (任意のタイプの、無制限の数の末尾の文字)。

PATTERN と一致しない値を指定すると、INSERT の場合は SQLCODE -104、UPDATE の場合は SQLCODE -105 の各検証エラーが発生します。

一意のプロパティ値

CREATE TABLE を使用すると、列を UNIQUE として定義できます。これは、すべてのフィールドの値が一意の (重複がない) 値になることを意味します。

テーブルを永続クラスとして定義しても、対応する一意性プロパティ・キーワードはサポートされません。代りに、プロパティとそのプロパティに対する一意のインデックスを定義する必要があります。以下の例では、各レコードに一意の Num 値を指定します。

  Class Sample.CaveDwellers Extends %Persistent [ DdlAllowed ]
  { 
  Parameter USEEXTENTSET = 1;

  Property Num As %Integer;
  Property Troglodyte As %String(MAXLEN=50);

  Index UniqueNumIdx On Num [ Type=index,Unique ];
  Index BitmapExtent [ Extent, Type = bitmap ];
  }

インデックス名は、プロパティの名前付け規約に従います。オプションの Type キーワードは、インデックス・タイプを指定します。Unique キーワードは、プロパティ (列) を一意として定義します。

一意の値の列は、INSERT OR UPDATE 文を使用する際に必要になります。

計算プロパティ値

以下のクラス定義の例は、列 (Birthday) を持つテーブルを定義します。このテーブルでは、DateOfBirth の値が初めて設定されたときに、SqlComputed を使用して列の値が計算され、DateOfBirth の値が更新されたときに、SqlComputeOnChange を使用して列の値が再計算されます。Birthday には、この値の計算日時または再計算日時を記録した最新のタイムスタンプが記述されます。

Class Sample.MyStudents Extends %Persistent [DdlAllowed]
{
  Parameter USEEXTENTSET = 1;

  Property Name As %String(MAXLEN=50) [Required];
  Property DateOfBirth As %Date;
  Property Birthday As %String 
          [ SqlComputeCode = {SET {Birthday}=$PIECE($ZDATE({DateOfBirth},9),",")_
                              " changed: "_$ZTIMESTAMP},
                              SqlComputed, SqlComputeOnChange = DateOfBirth ];

  Index BitmapExtent [ Extent, Type = bitmap ];
}

既存の DateOfBirth 値を指定する DateOfBirth に対して UPDATE を実行しても Birthday の値は再計算されません。

SqlComputeCode プロパティのキーワードには、値の計算に使用される ObjectScript コードが記述されています。PropertyComputation メソッドに計算コードを指定することもできます。この場合、計算するプロパティの名前は Property です。このメソッドでは、ObjectScript 以外の言語 (Python など) で計算コードを指定できます。

このクラスでは、AgeComputation メソッドによって DOB (生年月日) プロパティに基づいて Age プロパティが計算されます。cols 入力引数は、%Library.PropertyHelperOpens in a new tab オブジェクトです。このオブジェクトの getfield メソッドを使用して、他のプロパティを参照できます。

Class/ObjectScript Class/Python

Class Sample.MyStudents Extends %Persistent [ DdlAllowed ]
{
Parameter USEEXTENTSET = 1;

Property Name As %String(MAXLEN = 50) [ Required ];
Property DOB As %Date;
Property Age As %Integer [ Calculated, SqlComputed, SqlComputeOnChange = DOB ];

Index BitmapExtent [ Extent, Type = bitmap ];

ClassMethod AgeComputation(cols As %Library.PropertyHelper) As %Integer
{
    set today = $zdate($horolog,8) 
    set bdate = $zdate(cols.getfield("DOB"), 8)
    return $select(bdate = "":"", 1:(today - bdate) \ 10000)
}

}

Class Sample.MyStudents Extends %Persistent [ DdlAllowed ]
{
Parameter USEEXTENTSET = 1;

Property Name As %String(MAXLEN = 50) [ Required ];
Property DOB As %Date;
Property Age As %Integer [ Calculated, SqlComputed, SqlComputeOnChange = DOB ];

Index BitmapExtent [ Extent, Type = bitmap ];

ClassMethod AgeComputation(cols As %Library.PropertyHelper) As %Integer [ Language = python ]
{
    import datetime as d
    iris_date_offset = d.date(1840,12,31).toordinal()
    bdate = d.date.fromordinal(cols.getfield("DOB") + iris_date_offset).strftime("%Y%m%d")
    today = d.date.today().strftime("%Y%m%d")
    return str((int(today) - int(bdate)) // 10000) if bdate else ""
}

}

計算コードの指定に関する詳細は、CREATE TABLE のリファレンス・ページで "計算列" のセクションを参照してください。

クラス・プロパティのキーワードの詳細は、"プロパティの構文とキーワード" を参照してください。

埋め込みオブジェクト (%SerialObject)

プロパティを定義する埋め込みシリアル・オブジェクト・クラスを参照することで、永続テーブルの構造を簡素化できます。例えば、通り、市、都道府県、および郵便番号で構成された住所情報を MyData.Person テーブルに含める場合があります。これらのプロパティを MyData.Person に指定するのではなく、これらのプロパティを定義するシリアル・オブジェクト (%SerialObject) クラスを定義してから、この埋め込みオブジェクトを参照する 1 つの Home プロパティを MyData.Person で指定できます。これを以下のクラス定義で示しています。

Class MyData.Person Extends (%Persistent) [ DdlAllowed ]
{  Parameter USEEXTENTSET = 1;
   Property Name As %String(MAXLEN=50);
   Property Home As MyData.Address;
   Property Age As %Integer;
   Index BitmapExtent [ Extent, Type = bitmap ];
}

Class MyData.Address Extends (%SerialObject)
{  Property Street As %String;
   Property City As %String;
   Property State As %String;
   Property PostalCode As %String;
}

シリアル・オブジェクト・プロパティ内のデータに直接アクセスすることはできません。シリアル・オブジェクト・プロパティを参照する永続クラス/テーブルを介してアクセスする必要があります。

• 永続テーブルから個々のシリアル・オブジェクト・プロパティを参照するには、アンダースコアを使用します。例えば、SELECT Name, Home_State FROM MyData.Person は州 (State) のシリアル・オブジェクト・プロパティ値を文字列として返します。シリアル・オブジェクト・プロパティ値は、クエリで指定された順序で返されます。

• 永続テーブルからすべてのシリアル・オブジェクト・プロパティを参照するには、参照フィールドを指定します。例えば、SELECT Home FROM MyData.Person はすべての MyData.Address プロパティの値を %List 構造として返します。シリアル・オブジェクト・プロパティ値は、シリアル・オブジェクトで指定されている Home_Street、Home_City、Home_State、Home_PostalCode の順序で返されます。管理ポータルの SQL インタフェース [カタログの詳細] では、この参照フィールドは [コンテナ] フィールドと呼ばれます。これは [隠し] フィールドであるため、SELECT * 構文では返されません。

• 永続クラスの SELECT * は、入れ子になっているシリアル・オブジェクトを含め、すべてのシリアル・オブジェクト・プロパティを個別に返します。例えば、SELECT * FROM MyData.Person は Age、Name、Home_City、Home_PostalCode、Home_State、および Home_Street の値を (この順序で) 返します。Home の %List 構造の値は返しません。シリアル・オブジェクト・プロパティ値は照合順で返されます。SELECT * はまず、永続クラスのすべてのフィールドを照合順でリストし (通常、アルファベット順)、その後に、入れ子になっているシリアル・オブジェクト・プロパティを照合順でリストします。

埋め込みシリアル・オブジェクトは、参照する永続テーブルと同じパッケージ内に存在する必要はありません。%Library.SerialObject の SqlCategory (および SqlCategory を明示的に定義していない %SerialObject のすべてのサブクラス) は STRING です。

埋め込みオブジェクトを定義することで、永続テーブルの定義を次のように簡素化できます。

• 永続テーブルに、同じ埋め込みオブジェクト内の異なる複数のレコードを参照する複数のプロパティを含めることができます。例えば、MyData.Person テーブルに、両方とも MyData.Address シリアル・オブジェクト・クラスを参照する、Home プロパティと Office プロパティを含めることができます。

• 複数の永続テーブルが同じ埋め込みオブジェクトのインスタンスを参照できます。例えば、MyData.Person テーブルの Home プロパティと MyData.Employee テーブルの WorkPlace プロパティが、両方とも MyData.Address シリアル・オブジェクト・クラスを参照できます。

• 埋め込みオブジェクトは、別の埋め込みオブジェクトを参照できます。例えば、MyData.Address 埋め込みオブジェクトに、CountryCode プロパティ、AreaCode プロパティ、および PhoneNum プロパティが含まれる MyData.Telephone 埋め込みオブジェクトを参照する Phone プロパティを含めることができます。永続クラスから複数のアンダースコアを使用して、入れ子になったシリアル・オブジェクト・プロパティを参照します (例えば、Home_Phone_AreaCode)。

シリアル・オブジェクト・クラスをコンパイルすると、ストレージ定義にデータ仕様が生成されます。コンパイラはシリアル・オブジェクト・クラス名に "State" という語を付加することで、この仕様にデータ名を割り当てます。したがって、MyData.Address には <Data name="AddressState"> が割り当てられます。この名前 (この例では AddressState) が既にプロパティ名として使用されている場合、コンパイラは整数を付加して一意のデータ名を作成します (<Data name="AddressState1">)。

"クラスの定義と使用" の ”シリアル・オブジェクトの概要” を参照してください。

シリアル・オブジェクト・プロパティのインデックス作成の詳細は、"埋め込みオブジェクト (%SerialObject) のプロパティのインデックス作成" を参照してください。

クラス・メソッド

テーブル定義の一部としてクラス・メソッドを指定できます。その例を以下に示します。

Class MyApp.Person Extends %Persistent 
{
Parameter USEEXTENTSET = 1;
Property Name As %String(MAXLEN=50) [Required];
Property SSN As %String(MAXLEN=15) [InitialExpression = "Unknown"];
Property DateOfBirth As %Date;
Property Sex As %String(MAXLEN=1);
Index BitmapExtent [ Extent, Type = bitmap ];
ClassMethod Numbers() As %Integer [ SqlName = Numbers, SqlProc ]
  {
   QUIT 123
  }
}

クラス・メソッドを SQL プロシージャに投影するには SqlProc キーワードが必要です。SELECT クエリでは、メソッドに定義した SqlName 値を使用してこのメソッドを呼び出すことができます。以下に例を示します。

SELECT Name,SSN,MyApp.Numbers() FROM MyApp.Person

永続クラスの作成によるシャード・テーブルの定義

シャード・テーブルとして投影する永続クラスを定義する前に、シャーディング環境を設定する必要があります。その後、シャード永続クラスを定義するには、クラス・キーワード Sharded=1 を、オプションのシャード関連クラス属性と共に指定します。

このクラスは、サンプルのシャード永続クラスと、オプションでシャード関連のクラス属性セットを定義します。

Class Sample.MyShardT Extends %Persistent [ Sharded = 1 ]
{
    Parameter DEFAULTCONCURRENCY As BOOLEAN = 0;
    Parameter USEEXTENTSET = 1;
    Index BitmapExtent [ Extent, Type = bitmap ];
}

次のクラス属性が適用されます。

• Sharded = 1 キーワードは、このクラスが投影されるテーブルをシャード・テーブルとして定義します。この設定により、シャーディング・インフラストラクチャで、データ分散を含め、シャード・テーブル・ストレージを管理します。したがって、InterSystems IRIS で生成および維持される既定のストレージ定義をカスタマイズすることはできません。このクラス定義内のストレージ定義に対して行われた変更はすべて無視されます。

• DEFAULTCONCONCURRENCY クラス・パラメータは 0 (ロックなし) に設定されます。シャード・テーブルには分散する性質があることから、0 のパラメータ値が必要です。この値は、%Open や %OpenId などのオブジェクト・メソッドの既定値として使用されます。したがって、すべてのメソッド呼び出しに並行処理引数を渡す必要はありません。

• USEEXTENTSET クラス・パラメータは 1 に設定されます。これにより、テーブル・ストレージは、より効率的なグローバルのセットに編成されます。DDL コマンドを使用してシャード・テーブルを定義する場合、InterSystems SQL はこの設定を自動的に適用します。

• ビットマップ・エクステント・インデックスは、エクステント・セット内のすべての ID のインデックスを作成します。この設定により、カウントやその他の操作がより効率的になります。DDL コマンドを使用してシャード・テーブルを定義する場合、InterSystems SQL はこの設定を自動的に適用します。

その後、シャード・キー・インデックスを定義できます。シャード・テーブルを作成すると、抽象シャード・キー・インデックスが自動的に生成されます。シャード・キー・インデックスは、行が存在するシャードを指定します。シャード・キー・インデックスの定義とシャード・テーブルの作成の詳細は、"シャード・テーブルの作成とデータのロード" を参照してください。

外部テーブルの概要

さまざまな理由により、InterSystems IRIS に直接データをロードすることが不可能であるか、合理的ではない場合があります。例として、データ・ファイルがきわめて大きく、InterSystems IRIS テーブルにロードするストレージ・コストに見合うほど頻繁にはクエリが実行されない状況が挙げられます。外部テーブルは、別のシステムで管理されているデータを投影し、InterSystems IRIS のインスタンスで管理および格納しているデータと同様に、投影したデータにクエリおよびアクセスできるようにする機能です。

外部テーブルの作成

外部テーブルを作成する前に、InterSystems IRIS が外部データ・ソースとどのように対話するかを決定するために外部サーバを定義する必要があります。外部サーバを定義すると、外部ソースのデータを表す外部テーブルを 1 つ以上定義できます。そのためには、外部データ・ソースのフィールドを InterSystems IRIS の列にマッピングするうえで必要な、列の名前とタイプなどの詳細情報を指定します。

手順 1：外部サーバを定義する

外部テーブルを定義するには、外部サーバを定義し、使用する外部データ・ラッパを指定しておく必要があります。そのためには、CREATE FOREIGN SERVER コマンドを使用します。

CREATE FOREIGN SERVER コマンドでは、外部データ・ラッパを指定する必要があります。InterSystems IRIS で特定のタイプのデータ・ソースをどのように操作するかを、この外部データ・ラッパで指定します。CREATE FOREIGN SERVER コマンドでは、外部データ・ラッパと、その外部データ・ラッパが必要とするメタデータを指定する必要があります。現在のところ、InterSystems SQL では 2 つの外部データ・ラッパとして CSV と JDBC をサポートしています。CSV 外部データ・ラッパでは、ローカル・ファイル・システムのフォルダへのパスを指定する必要があります。JDBC 外部データ・ラッパでは、外部データベースに接続するための JDBC 接続を指定する必要があります。

外部サーバに定義できる外部テーブルの数に制限はありません。

以下の例は、CSV 外部データ・ラッパを使用する外部サーバの作成方法を示しています。

CREATE FOREIGN SERVER Sample.TestFile FOREIGN DATA WRAPPER CSV HOST '\path\to\file'

以下の例は、JDBC 外部データ・ラッパを使用する外部サーバの作成方法を示しています。

CREATE FOREIGN SERVER Sample.PostgresDB FOREIGN DATA WRAPPER JDBC 'postgresConnection'

手順 2：外部テーブルを定義する

外部サーバを定義すると、CREATE FOREIGN TABLE コマンドを使用して外部テーブルを定義できます。このテーブルの列名は外部ソースのデータと同じ列名にすることができるほか、InterSystems IRIS では別の名前で外部ソースのデータ列を参照することもできます。外部テーブルを作成する構文は、LOAD DATA コマンドに似ています。

CREATE FOREIGN TABLE Sample.AccountTeam (
   TeamID BIGINT,
   Name VARCHAR(50),
   CountryCode VARCHAR(10)
) SERVERT Sample.PostgresDB TABLE 'Sample.Teams'

データ定義言語 (DDL) 文を使用して外部テーブルを作成すると、ClassType を "view" として、対応するクラスが作成されます。このクラスは手動で編集しないでください。また、外部テーブルは CREATE FOREIGN TABLE コマンドで定義する必要があります。クラス定義を作成することで外部テーブルを作成することはできません。

外部テーブルのクエリ

外部テーブルのクエリは、ネイティブ・テーブルのクエリとまったく同じです。

SELECT Name, CountryCode FROM Sample.AccountTeam ORDER BY Name

クエリではさらに高度な構文を活用することもできます。

SELECT t.Name, COUNT(m.*)
FROM Sample.AccountManager m JOIN Sample.AccountTeam t
     ON m.TeamID = t.TeamID
WHERE t.CountryCode = 'UK' AND m.Salary > 100000
GROUP BY t.Name

InterSystems SQL では、WHERE 節の簡潔な述語が可能な範囲で送信またはプッシュ・ダウンされます。これにより、ネットワーク上で送受信されるデータの量を制限し、リモート・データベースでの最適化を最大限に活用します。ただし、2 つの外部テーブル間での GROUP BY や JOIN のような複雑な節は、外部データの取得を完了した後で InterSystems IRIS によって処理されます。

クエリを発行するユーザには %Gateway_Object:USE 特権が必要です。

外部テーブルの削除

外部テーブルを削除するには DROP FOREIGN TABLE コマンドを使用します。

DROP FOREIGN TABLE Example.MyForeignTable

また、CASCADE オプションを指定して DROP FOREIGN SERVER コマンドを使用すると、外部サーバとそこに定義されているすべての外部テーブルを削除できます。

DROP FOREIGN SERVER Example.PostgresDB CASCADE

列の取得メソッド

テーブル内の列の名前を列番号順にリストするには、GetAllColumns()Opens in a new tab または GetVisibleColumns()Opens in a new tab メソッドを次のように使用します。

  SET stat=##class(%SYSTEM.SQL.Schema).GetAllColumns("Sample.Person",.byname,.bynum)
  IF stat=1 {
    SET i=1
    WHILE $DATA(bynum(i)) { WRITE "name is ",bynum(i),"   col num is ",i,!
                            SET i=i+1 }
  }
  ELSE { WRITE "GetAllColumns() cannot locate specified table" }

GetAllColumns() は、非表示の列を含め、定義されているすべての列をリストします。テーブルが埋め込み %SerialObject クラスを参照する場合、GetAllColumns() はまず永続クラスのすべての列をリストし (%SerialObject を参照するプロパティを含め)、次にすべての %SerialObject プロパティをリストします。これを、以下の GetAllColumns() の結果に示します。

name is ID   col num is 1
name is Age   col num is 2
name is Home   col num is 3
name is Name   col num is 4
name is x__classname   col num is 5
name is Home_City   col num is 6
name is Home_Phone   col num is 7
name is Home_Phone_AreaCode   col num is 8
name is Home_Phone_Country   col num is 9
name is Home_Phone_TNum   col num is 10
name is Home_PostalCode   col num is 11
name is Home_State   col num is 12
name is Home_Street   col num is 13

このメソッドを次のように使用して、指定した列名の列番号を特定することもできます。

  SET stat=##class(%SYSTEM.SQL.Schema).GetAllColumns("Sample.Person",.byname)
  IF stat=1 {
         WRITE "Home_State is column number ",byname("Home_State"),!  }
  ELSE { WRITE "GetAllColumns() cannot locate specified table" }