SQL パフォーマンス分析ツールキット

SQL パフォーマンス統計の有効化

サポート・スペシャリストは、SQL パフォーマンス分析ツールキットを使用して、特定の SQL 文または SQL 文のグループをプロファイリングできます。特定の SQL 文の実行時にこれらのツールを使用してパフォーマンス統計を収集し、その情報を使用して問題のある文を切り分けて分析したり、実際の作業負荷で分析したりすることができます。

%SYSTEM.SQL.PToolsOpens in a new tab クラスのメソッドを使用すると、高度なパフォーマンス統計の収集を開始できます。このような統計をさまざまな規模で収集するために以下のメソッドが用意されています。

• システム全体 ： setSQLStatsFlag()Opens in a new tab

• 特定のネームスペース ： setSQLStatsFlagByNS()Opens in a new tab

• 現在のプロセスまたはジョブ ： setSQLStatsFlagJob()Opens in a new tab

• 指定したプロセスまたはジョブ ： setSQLStatsFlagByPID()Opens in a new tab。最初のパラメータが未指定の場合、あるいは $JOB または空の文字列 ("") として指定されている場合、setSQLStatsFlagJob() が呼び出されます。したがって、SET SQLStatsFlag=$SYSTEM.SQL.SetSQLStatsFlagByPID($JOB,3) は SET SQLStatsFlag=$SYSTEM.SQL.SetSQLStatsFlagJob(3) と同等です。

これらのメソッドは、整数のアクション・オプションを取ります。返される情報は、コロンで区切られた文字列です。その最初の要素は、優先するアクション・オプションです。現在の設定を確認するには、getSQLStatsFlag() メソッドまたは getSQLStatsFlagByPID() メソッドを使用します。

これらのメソッドは、以下の例に示すように、ObjectScript から呼び出すことも、SQL から呼び出すこともできます。

• ObjectScript から ： SET rtn=##class(%SYSTEM.SQL.PTools).setSQLStatsFlag(2,,8)

• SQL から ： SELECT %SYSTEM_SQL.PTools_setSQLStatsFlag(2,,8)

また、SELECT 文、INSERT 文、UPDATE 文、または DELETE 文で %PROFILE キーワード (setSQLStatsFlagJob(2) と同じ) または %PROFILE_ALL キーワード (setSQLStatsFlagJob(3) と同じ) を使用すると、その文のみのパフォーマンス分析統計を収集できます。

統計設定の取得

setSQLStatsFlag[nnn]() メソッドは、以前の統計設定をコロンで区切られた値として返します。現在の設定を確認するには、getSQLStatsFlag()Opens in a new tab メソッドまたは getSQLStatsFlagByPID()Opens in a new tab メソッドを使用します。

コロンで区切られた 1 つ目の値は、アクション・オプションの設定です。コロンで区切られた 2 つ目の値は、収集オプションです。コロンで区切られた 3 つ目の値と 4 つ目の値は、ネームスペース固有の統計の収集に使用されます。コロンで区切られた 5 つ目の値は、終了オプションをエンコードしたものです。コロンで区切られた 6 つ目の値では FlagType を指定します。0 = システム・フラグ、1 = プロセス/ジョブ・フラグです。

以下の例に示すように、ptInfo 配列を使用して、終了オプションの設定をより詳細に表示できます。

  KILL
  DO ##class(%SYSTEM.SQL.PTools).clearSQLStatsALL("USER")
  DO ##class(%SYSTEM.SQL.PTools).setSQLStatsFlagByNS("USER",3,,7,"M:5:1")
DisplaySettings
  SET SQLStatsFlag = ##class(%SYSTEM.SQL.PTools).getSQLStatsFlag(0,.ptInfo)
  WRITE "ptInfo array of performance statistics return value:",!
  ZWRITE ptInfo,SQLStatsFlag

クエリ・パフォーマンス統計のエクスポート

%SYSTEM.SQL.PToolsOpens in a new tab の exportSQLStats()Opens in a new tab メソッドを使用して、クエリ・パフォーマンス統計をファイルにエクスポートできます。このメソッドは、%SYSTEM.SQL.PToolsOpens in a new tab クラスから統計データをファイルにエクスポートする場合に使用します。

exportSQLStats() は、以下の例に示すように呼び出すことができます。

• ObjectScript から ： SET status=##class(%SYSTEM.SQL.PTools).exportSQLStats("$IO") (既定値は format T です)。

• SQL から ： CALL %SYSTEM_SQL.PTools_exportSQLStats('$IO') (既定値は format H です)。

filename 引数を指定しなかった場合、このメソッドは現在のディレクトリにエクスポートします。既定では、このファイルの名前は、PT_StatsSQL_exportSQLStats_ の後に現在のローカル日時が YYYYMMDD_HHMMSS として付加されたものになります。$IO を指定すると、データをターミナルまたは管理ポータルのディスプレイに出力できます。filename 引数を指定した場合、このメソッドは、現在のネームスペースの Mgr サブディレクトリ、または指定したパスの場所にファイルを作成します。このエクスポートは、現在のネームスペース内のデータに限られます。

出力ファイルの format を P (テキスト)、D (コンマ区切りのデータ)、X (XML マークアップ)、H (HTML マークアップ)、または Z (ユーザ定義の区切り文字) として指定できます。

既定では、このメソッドはクエリ・パフォーマンス統計をエクスポートします。以下の例に示すように、代わりに SQL クエリ・テキストまたは SQL クエリ・プラン・データをエクスポートするように指定することもできます。

• クエリ・テキスト ： CALL %SYSTEM_SQL.PTools_exportSQLStats('$IO',,0,1,0)

• クエリ・プラン ： CALL %SYSTEM_SQL.PTools_exportSQLStats('$IO',,0,1,1)

exportSQLStats() は、コメントを削除し、リテラル置換を実行することにより、クエリ・テキストを変更します。

ExportSQLQuery()Opens in a new tab によって、同じクエリ・テキストおよびクエリ・プラン・データを返すことができます。

クエリ・パフォーマンス統計の削除

clearSQLStatsALL()Opens in a new tab メソッドを使用すると、パフォーマンス統計を削除できます。既定では、現在のネームスペースのすべてのルーチンに対して収集された統計が削除されます。異なるネームスペースの指定、特定のルーチンへの削除操作の限定、またはその両方を指定できます。

また、管理ポータルの [SQL 実行時統計情報] ページで [統計情報を削除] ボタンを使用して、現在のネームスペースのすべてのクエリについて蓄積されたすべての統計情報を削除できます。成功した場合、メッセージには削除された統計の数が示されます。統計がなかった場合は、"削除するものがありません" というメッセージが表示されます。正常に削除できなかった場合は、エラー・メッセージが表示されます。

パフォーマンス統計の例

以下の例では、現在のプロセスによって準備されたクエリのメイン・モジュールに関するパフォーマンス統計を収集し (アクション・オプション 2)、その後、exportSQLStats() を使用してパフォーマンス統計をターミナルに表示します。

  DO ##class(%SYSTEM.SQL.PTools).clearSQLStatsALL()
  DO ##class(%SYSTEM.SQL.PTools).setSQLStatsFlagJob(2)
  SET myquery = "SELECT TOP 5 Name,DOB FROM Sample.Person"
  SET tStatement = ##class(%SQL.Statement).%New()
  SET qStatus = tStatement.%Prepare(myquery)
    IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
  SET pStatus = ##class(%SYSTEM.SQL.PTools).exportSQLStats("$IO")
    IF pStatus'=1 {WRITE "Performance stats display failed:"
       DO $System.Status.DisplayError(qStatus) QUIT}

以下の例では、現在のプロセスによって準備されたクエリのすべてのモジュールに関するパフォーマンス統計を収集し (アクション・オプション 3)、その後、埋め込み SQL から exportSQLStats() を呼び出してパフォーマンス統計をターミナルに表示します。

  DO ##class(%SYSTEM.SQL.PTools).clearSQLStatsALL()
  DO ##class(%SYSTEM.SQL.PTools).setSQLStatsFlagJob(3)
  SET myquery = "SELECT TOP 5 Name,DOB FROM Sample.Person"
  SET tStatement = ##class(%SQL.Statement).%New()
  SET qStatus = tStatement.%Prepare(myquery)
    IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
  &sql(CALL %SYSTEM_SQL.PTools_exportSQLStats('$IO'))

以下の例では、現在のプロセスによって準備されたクエリのメイン・モジュールに関するパフォーマンス統計を収集し (アクション・オプション 2)、その後、StatsSQLViewOpens in a new tab クエリを使用してこれらの統計を表示します。

  DO ##class(%SYSTEM.SQL.PTools).clearSQLStatsALL()
  DO ##class(%SYSTEM.SQL.PTools).setSQLStatsFlagJob(2)
  SET myquery = "SELECT TOP 5 Name,DOB FROM Sample.Person"
  SET tStatement = ##class(%SQL.Statement).%New()
  SET qStatus = tStatement.%Prepare(myquery)
   IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
GetStats
  SET qStatus = tStatement.%Prepare("SELECT * FROM %SYS_PTools.StatsSQLView")
   IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
  SET rsstats = tStatement.%Execute()
  DO rsstats.%Display()
  WRITE !!,"End of SQL Statistics"

以下の例では、USER ネームスペースのすべてのクエリのすべてのモジュールに関するパフォーマンス統計を収集します (アクション・オプション 3)。1 分後に統計の収集時間が経過すると、アクション・オプション 2 にリセットされ、収集の範囲は、すべてのネームスペースで既定値の 15 (すべての統計) に設定されます。

  DO ##class(%SYSTEM.SQL.PTools).clearSQLStatsALL("USER")
  DO ##class(%SYSTEM.SQL.PTools).setSQLStatsFlagByNS("USER",3,,7,"M:1:2")
  SET myquery = "SELECT TOP 5 Name,DOB FROM Sample.Person"
  SET tStatement = ##class(%SQL.Statement).%New()
  SET qStatus = tStatement.%Prepare(myquery)
   IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
GetStats
  SET qStatus = tStatement.%Prepare("SELECT * FROM %SYS_PTools.StatsSQLView")
   IF qStatus'=1 {WRITE "%Prepare failed:" DO $System.Status.DisplayError(qStatus) QUIT}
  SET rsstats = tStatement.%Execute()
  DO rsstats.%Display()
  WRITE !!,"End of SQL Statistics",!
TerminateResetStats
  WRITE "returns:  ",##class(%SYSTEM.SQL.PTools).getSQLStatsFlag(),!
  HANG 100
  WRITE "reset to: ",##class(%SYSTEM.SQL.PTools).getSQLStatsFlag()