InterSystems IRIS の Web ゲートウェイ・レジストリ
InterSystems Web ゲートウェイ・レジストリは、それぞれの接続された Web ゲートウェイのインストール環境を InterSystems IRIS® に登録し、InterSystems IRIS コードがこれらのインストール環境と対話する (キャッシュのクリアなどのため) ことを可能にするインフラストラクチャを提供します。そのようなプログラムで制御された通信には、Web ゲートウェイの実行時構成の読み取りと変更、およびシステム・ステータスとログ情報の収集が含まれます。関連するクラスは以下のとおりです。
%CSP.Mgr.GatewayRegistry (The Gateway Registry)
%CSP.Mgr.GatewayMgr (A Connected Gateway)
以下のコードは、すべての接続された (つまり、アクティブな) Web ゲートウェイのインストール環境をリストし、Web サーバ IP アドレス、ポート、および Web ゲートウェイ・ビルド番号をコンソール・ウィンドウに書き込みます。
Set registry = $system.CSP.GetGatewayRegistry()
Set gateways = registry.GetGatewayMgrs()
For no=1:1:gateways.Count() {
Set gateway = gateways.GetAt(no)
Write !,no, " : "
Write gateway.IPAddress,":",gateway.Port," ",gateway.Version
}
InterSystems IRIS が最初に起動されたときは、このリストは空です。管理者およびユーザのアクティビティが増加すると、インスタンスのアプリケーションを提供する Web ゲートウェイ用に少なくとも 1 つのエントリが表示されます。
上記のクラスについては、他のドキュメントで説明されています。 一般的なタスクを説明するコード例を以下に示します。
既定のパラメータのリスト
Kill defaults
Do gateway.GetDefaultParams(.defaults)
ZWrite defaults
既定のパラメータの更新
Kill newpars
Set newpars("Server_Response_Timeout")=30
Do gateway.SetDefaultParams(.newpars)
サーバのリスト
Set status = gateway.GetServers(.servers)
For no=1:1:$ListLength(servers) {
Set server = $List(servers,no)
Write !,no, " : ",server
}
サーバ・パラメータのリスト
Kill serverpars
Do gateway.GetServerParams("LOCAL",.serverpars)
ZWrite serverpars
サーバ・パラメータの更新
Kill newpars
Set newpars("Maximum_Server_Connections")=250
Do gateway.SetServerParams("LOCAL",.newpars)
アプリケーション・パスのリスト
Set status = gateway.GetApplicationPaths(.paths)
For no=1:1:$ListLength(paths) {
Set path = $List(paths,no)
Write !,no, " : ",path
}
アプリケーション・パラメータのリスト
Kill pathpars
Do gateway.GetApplicationParams("/csp",.pathpars)
ZWrite pathpars
アプリケーション・パラメータの更新
Kill newpars
Set newpars("GZIP_Compression")="Enabled"
ゲートウェイ・キャッシュのクリア
Do gateway.ClearCache("*")
構成を再ロードするよう Web ゲートウェイを強制する
Web ゲートウェイの構成が外部エージェント (つまり、Web ゲートウェイ独自のシステム管理スイート以外のエージェント) によって変更される場合があります。
完全な再起動を必要とせずに、Web ゲートウェイに構成を再ロードするようインタラクティブに指示するには、以下の 2 つの方法があります。
InterSystems IRIS Web ゲートウェイ・レジストリの使用
以下のレジストリ・メソッドが提供されています。
Set status = %CSP.Mgr.GatewayMgr.ActivateCSPIni()
呼び出しが成功すると、Web ゲートウェイはその構成ファイルを読み取り、行われたすべての変更を有効化します。
InterSystems IRIS の外部スクリプトの使用
スクリプトでは、変更された Web ゲートウェイの構成ファイルの SYSTEM セクションに次の行 (大文字と小文字が区別される) を追加する必要があります。
[SYSTEM]
RELOAD=1
The Web Gateway caretaker daemon checks the RELOAD flag approximately every minute and, if correctly set, reloads and reactivates its configuration and removes the flag from the file. 再ロード操作が成功すると、以下のメッセージがイベント・ログに書き込まれます。
Gateway Management
Gateway Configuration Reloaded and Reactivated
