ObjectScript の演算子の概要

ObjectScript の SET コマンドは、代入演算子 ( = ) を併用して変数に値を代入します。代入コマンドの右側に式が置かれます。

 SET value = 0
 SET value = a + b

ObjectScript では、代入コマンドの左側にも特定の関数を使用できます。

 SET pies = "apple,banana,cherry"
 WRITE "Before: ",pies,!

 // set the 3rd comma-delimited piece of pies to coconut
 SET $Piece(pies,",",3) = "coconut"
 WRITE "After: ",pies

ObjectScript は、二項算術演算子より単項マイナス演算子を優先します。ObjectScript はまず数値式を検査し、単項マイナス演算子を実行します。その後、式を評価して結果を算出します。以下に例を示します。

USER>WRITE -123 - 3
-126
USER>WRITE -123 + - 3
-126
USER>WRITE -(123 - 3)
-120

式の評価の順序は、それぞれの式を対の小括弧で入れ子にして変更できます。小括弧は、囲んだ式 (算術式と関係式の両方) をグループ化し、演算の順序を制御します。以下に例を示します。

USER>SET TorF = ((4 + 7) > (6 + 6))
 
USER>WRITE TorF
0

上記では、小括弧で 4 と 7、および 6 と 6 を加算しているため、論理式は 11 > 12 となり、結果は False になります。以下のコードと比較します。

USER>SET Value = (4 + 7 > 6 + 6)
 
USER>WRITE Value
7

この場合、演算の優先順位は左から右になります。したがって、最初に 4 と 7 を加算します。その合計の 11 と 6 を比較し、11 は 6 より大きくなるため、論理演算の結果は 1 (True) になります。その後、1 に 6 を加算するため、結果は 7 になります。

優先順位により結果のタイプが異なることに注意してください。上記の例で、最初の式の演算は最終的にブーリアン値を返し、2 番目の式は数値を返します。

以下の例では、複数レベルの入れ子を示します。

USER>WRITE 1+2*3-4*5
25
USER>WRITE 1+(2*3)-4*5
15
USER>WRITE 1+(2*(3-4))*5
-5
USER>WRITE 1+(((2*3)-4)*5)
11

内側の入れ子の式から 1 レベルずつ外側に進み、各レベルで左から右へと式が評価されます。

例えば、すべての演算子と同様に && 演算子は、左から右の順に実行されるため、以下のコード例の最後の文は 0 に評価されます。

USER>SET x = 3
 
USER>SET y = 2
 
USER>WRITE x && y = 2
0

これは、最後のステップで、評価が次のように実行されるからです。

1. 最初に、x が定義されていて、0 以外の値であるかどうかが確認されます。x は 3 なので評価は続行されます。

2. 次に、y が定義されていて、0 以外の値であるかどうかが確認されます。y は 2 なので評価は続行されます。

3. 次に、3 && 2 の値が評価されます。3 も 2 も 0 ではないので、この式は True で、1 に評価されます。

4. 次に、返された値を 2 と比較します。1 は 2 ではないので、この評価は 0 を返します。

多くのプログラミング言語に精通している人にとって、これは予想外の結果です。x に0 でない値が定義されていて、y が 2 のときに True を返すことを意図している場合は、次のように括弧が必要です。

USER>SET x = 3
 
USER>SET y = 2
 
USER>WRITE x && (y = 2)
1

関数など、式のタイプによって副次的作用が発生する場合があります。以下の論理式を考えてみます。

 IF var1 = ($$ONE + (var2 * 5)) {
    DO ^Test 
 }

ObjectScript は、最初に var1、次に関数 $$ONE、その次に var2 を評価します。その後、var2 を 5 倍し、最後に ObjectScript は、加算の結果が var1 の値に等しいかどうかをテストします。等しい場合、DO コマンドを実行して Test ルーチンを呼び出します。

別の例として、以下の例を考えてみます。

USER>SET var8=25,var7=23
 
USER>WRITE var8 = 25 * (var7 < 24)
1

ObjectScript は、厳密に左から右の順に式を評価します。プログラマは、括弧を使用して優先順位を確立する必要があります。この場合、ObjectScript はまず論理式 var8 = 25 を評価し、結果が 1 になります。次に、この結果に (var7 < 24) の結果を乗算します。式 (var7 < 24) は 1 に評価されます。このため、ObjectScript は 1 に 1 を乗算し、結果が 1 になります。