Skip to main content
Previous sectionNext section

Defining Messages

This chapter describes how to define the classes that define production message bodies. It contains the following sections:

Introduction

A message body can be any persistent object.

In practice, you often create a subclass of Ens.Request or Ens.Response and add properties. This creates the standard message body. If you use these classes, you have easy access to the various built-in features for viewing the contents of messages from the Management Portal. These features help developers and administrators detect errors in a running production, especially if the production uses message content to determine where the message should be sent.

Some electronic documents — Electronic Data Interchange (EDI) formats such as X12 — contain data that is arbitrarily long and complex. In this case, it is better to use an alternative class, a class that represents an InterSystems IRIS® virtual document. In this case, the message body does not have a set of properties to contain the message contents. For details, see Using Virtual Documents in Productions.

Most of the examples in this book assume a standard message body, with a relatively small number of message properties.

Creating a Simple Message Body Class

To create a message class (to be used as the message body), create a class that:

  • Extends either Ens.Request or Ens.Response.

  • Contains properties as needed to represent elements of data to be carried in the message.

The following shows a simple example:

Class Demo.Loan.Msg.CreditRatingResponse Extends Ens.Response
{

Property TaxID As %String;

Property CreditRating As %Integer;

}
Copy code to clipboard

The class can also contain methods. For example:

Class Demo.Loan.Msg.Application Extends Ens.Request{

Property Amount As %Integer;
Property Name As %String;
Property TaxID As %String;
Property Nationality As %String;
Property BusinessOperationType As %String;
Property Destination As %String;

Method RecordNumber() As %String
{
  If ..%Id()="" Do ..%Save()
  Quit ..%Id()
}

Method GetRecordNumberText(pFormatAsHTML As %Boolean = 0) As %String
{
  Set tCRLF=$s(pFormatAsHTML:"<br>",1:$c(13,10))
  Set tText=""
  Set tText=tText_"Your loan application has been received,"_tCRLF
  Set tText=tText_"and is being processed."_tCRLF
  Set tText=tText_"Your record number is "_..RecordNumber()_"."_tCRLF
  Set tText=tText_"You'll receive a reply from FindRate"_tCRLF
  Set tText=tText_"within 2 business days."_tCRLF
  Set tText=tText_"Thank you for applying with FindRate."_tCRLF
  Quit tText
}

}
Copy code to clipboard

If you create a message class that does not extend Ens.Request or Ens.Response:

Creating a Complex Message Body Class

In the previous example, the message body class contained only simple properties. In some cases, you may need to define properties that use other classes. If so, you should carefully consider what to do when you purge message bodies (as described in Managing Productions).

When you purge message bodies, InterSystems IRIS deletes only the specific message body object. For example, consider the following message class:

Class MyApp.Messages.Person Extends Ens.Response
{

Property Name As %String;

Property MRN As %String;

Property BirthDate As %Date;

Property Address As MyApp.Messages.Address;

}
Copy code to clipboard

The Address class is as follows:

Class MyApp.Messages.Address Extends %Persistent
{

Property StreetAddress As %String;

Property City As %String;

Property State As %String;

Property ZIP As %String;

}
Copy code to clipboard

In this case, if you purge message bodies, InterSystems IRIS deletes instances of MyApp.Messages.Person, but does not delete instances of MyApp.Messages.Address.

If your message body class uses other classes as properties and if your application requires that any referenced objects should also be purged, use one of the following approaches:

  • Make sure that the referenced classes are serial. For example, redefine the Address class as follows:

    Class MyApp.Messages.Address Extends %SerialObject
    {
    ...
    }
    Copy code to clipboard

    In this case, the data for the Address class is stored as part of the Person class (and is thus automatically purged at the same time).

  • Define the property as a suitable relationship. See “Persistent Behavior of Relationships” in the chapter “Relationships” in Defining and Using Classes.

  • Add a delete trigger or %OnDelete() method to the message class so that this class deletes the appropriate records in the referenced classes.

  • Optionally include %XML.Adaptor as a superclass so that the properties defined in the referenced class can be displayed in the Management Portal.

Setting Message Purge Behavior

When you define a message body class, you can include the ENSPURGE parameter to specify how InterSystems IRIS handles instances of the class during purge operations. The parameter has two possible values:

  • 0 — InterSystems IRIS does not purge message bodies based on the class, even when the option to purge message bodies is enabled.

  • 1 — InterSystems IRIS purges messages bodies based on the class when the option to purge message bodies is enabled.

The ENSPURGE parameter affects all purges from the Management Portal, except for purges of the Enterprise Message Bank. Similarly, it affects programmatic purges using the Purge() method of the Ens.MessageHeader class.

For example, consider the Sample.Person persistent database class:

Class Sample.Person Extends (%Persistent, %Populate, %XML.Adaptor)

{
Property Name As %String(POPSPEC = "Name()") [ Required ];

Property SSN As %String(PATTERN = "3N1""-""2N1""-""4N") [ Required ];

Property DOB As %Date(POPSPEC = "Date()");

...
}
Copy code to clipboard

If you configure a production to send Sample.Person objects to a business operation that updates patient information, it might be important to retain the objects. To ensure that the system does not purge any instances of the Sample.Person message body class, you could add the ENSPURGE parameter to the class definition as follows:

Class Sample.Person Extends (%Persistent, %Populate, %XML.Adaptor)

{
Parameter ENSPURGE As %Boolean = 0;

Property Name As %String(POPSPEC = "Name()") [ Required ];

Property SSN As %String(PATTERN = "3N1""-""2N1""-""4N") [ Required ];

Property DOB As %Date(POPSPEC = "Date()");

...
}
Copy code to clipboard

During subsequent purges, the system removes only the headers of messages based on the Sample.Person message body class. The message bodies are essentially orphaned and can be removed only programmatically. For more information, see Purging Production Data.

The ENSPURGE parameter is inheritable and is not required. The default value is 1.