InterSystems IRIS プログラミングの概要

はじめに

InterSystems IRIS は、ObjectScript と呼ばれる汎用プログラミング言語と Python のサポートが組み込まれた高性能のマルチモデル・データ・プラットフォームです。

InterSystems IRIS では、多重プロセスがサポートされ、並列処理の制御が可能です。各プロセスは、データに直接アクセスします。

InterSystems IRIS では、自身の嗜好に合わせて、クラス、ルーチン、またはそれらの組み合わせを記述できます。どの場合でも、格納するデータは最終的にグローバルという構造に収められます。InterSystems IRIS プログラミングには、以下の機能があります。

• クラスとルーチンは相互に交換して使用できます。

• クラスとルーチンはお互いを呼び出すことができます。

• クラスには、オブジェクト指向の機能が用意されています。

• データベース・ストレージは、ObjectScript と Python の両方に統合されます。

• クラスは、プログラミングが簡素化されるようにデータを永続化できます。永続クラスを使用する場合、データは、オブジェクト、SQL テーブル、およびグローバルとして同時に使用できます。

• グローバルには、クラスとルーチンのどちらからでも直接アクセスできます。つまり、完全に目的どおりにデータの格納およびデータへのアクセスを行える柔軟性を備えています。

ユーザのニーズに合ったアプローチを選択できます。

クラス

InterSystems IRIS ではクラスがサポートされます。システム・クラスを使用することも、独自のクラスを定義することもできます。

InterSystems IRIS では、プロパティ、メソッド、パラメータ (他のクラス言語では定数と呼ぶ) など、よく知られたクラス要素をクラスに含めることができます。また、トリガ、クエリ、インデックスなど、クラスでは通常定義されない項目を含めることもできます。

InterSystems IRIS クラス定義では、クラス定義言語 (CDL) を使用して、クラスとそのメンバ (プロパティ、メソッド、パラメータなど) を指定します。メソッド内部の実行可能コードの記述には、Python または ObjectScript を使用できます。メソッドごとに、Language キーワードを使用して、そのメソッドの記述に使用する言語を指定します。以下に例を示します。

クラス定義を以下に示します。

Class/ObjectScript Class/Python

Class Sample.Employee Extends %Persistent
{

/// The employee's name.
Property Name As %String(MAXLEN = 50);

/// The employee's job title.
Property Title As %String(MAXLEN = 50);

/// The employee's current salary.
Property Salary As %Integer(MAXVAL = 100000, MINVAL = 0);

/// This method prints employee information using ObjectScript.
Method PrintEmployee() [ Language = objectscript] 
{
    Write !,"Name: ", ..Name, " Title: ", ..Title
}

}

Class Sample.Employee Extends %Persistent
{

/// The employee's name.
Property Name As %String(MAXLEN = 50);

/// The employee's job title.
Property Title As %String(MAXLEN = 50);

/// The employee's current salary.
Property Salary As %Integer(MAXVAL = 100000, MINVAL = 0);

/// This method prints employee information using Embedded Python.
Method PrintEmployee() [ Language = python ] 
{
    print("\nName:", self.Name, "Title:", self.Title)
}

}

メソッドで使用する言語を指定しない場合、コンパイラはメソッドが ObjectScript で記述されていると想定します。

InterSystems IRIS の各種クラスおよび InterSystems IRIS の各種永続クラス固有の機能については別途説明します。

ルーチン

InterSystems IRIS でルーチンを作成する場合は ObjectScript を使用します。以下に示すのは、ObjectScript で記述されたルーチンの一部です。

    SET text = ""
    FOR i=1:5:$LISTLENGTH(attrs)
    {
        IF ($ZCONVERT($LIST(attrs, (i + 1)), "U") = "XREFLABEL")
        {
            SET text = $LIST(attrs, (i + 4))
            QUIT
        }
    }
    
    IF (text = "")
    {
        QUIT $$$ERROR($$$GeneralError,$$$T("Missing xreflabel value"))
    }

クラスとルーチンを一緒に使用する方法

InterSystems IRIS では、クラスをルーチン内から使用できます。例えば、以下はルーチンの一部を示しており、ここでは Sample.Employee クラスを参照しています。

 //get details of random employee and print them
showemployee() public {
    set rand=$RANDOM(10)+1        ; rand is an integer in the range 1-10
    write "Your random number: "_rand
    set employee=##class(Sample.Employee).%OpenId(rand)  
    do employee.PrintEmployee()
    write !,"This employee's salary: "_employee.Salary
      
    }

同様に、メソッドはルーチン内のラベルを呼び出すことができます。例えば、以下はルーチン employeeutils 内のラベル ComputeRaise を呼び出します。

Method/ObjectScript Method/Python

Method RaiseSalary() As %Numeric
{
    set newsalary=$$ComputeRaise^employeeutils(..Salary)
    return newsalary
}

Method RaiseSalary() as %Numeric [ Language = python ]
{
    import iris
    newsalary=iris.routine("ComputeRaise^employeeutils", self.Salary)
    return newsalary
}

グローバルの概要

InterSystems IRIS では、他のプログラミング言語にはない特殊な変数がサポートされています。それがグローバル変数です (通常、単にグローバルと呼ばれます)。InterSystems IRIS では、グローバルという用語は、そのデータが、このデータベースにアクセスするすべてのプロセスで使用可能であることを示します。その使用は他のプログラミング言語とは異なっており、他のプログラミング言語では、グローバルは “そのモジュールのすべてのコードで使用可能であること” を意味します。

グローバルのコンテンツは、InterSystems IRIS データベースに保存されます。ここでは、以下の点のみを理解しておくことが重要です。

• グローバルは、データベースに自動的に格納されます。グローバル変数のノードに値を割り当てると、そのデータは直ちにデータベースに書き込まれます。

• グローバルのコンテンツは、プログラムによって、または管理ポータルを使用して表示できます。

InterSystems SQL

InterSystems IRIS は、InterSystems SQL と呼ばれる SQL の実装を提供します。InterSystems SQL は、メソッド内およびルーチン内で使用できます。

マクロ

ObjectScript では、置換を定義するマクロもサポートします。その定義は、値、あるコード行の全体、(##continue 指示文も含む) 複数の行のいずれかです。マクロは、整合性を確保するために使用します。以下はその例です。

 #define StringMacro "Hello, World!"

 write $$$StringMacro

マクロの使用の詳細は、"マクロとインクルード・ファイルの使用" を参照してください。

インクルード・ファイル

ルーチンの中でマクロを定義し、それを同じルーチンの中で後で使用できます。より一般的には、それらは中央の場所で定義します。このためには、インクルード・ファイルを作成して使用します。インクルード・ファイルは、マクロを定義し、他のインクルード・ファイルをインクルードできます。

インクルード・ファイルの使用法の詳細は、"マクロとインクルード・ファイルの使用" を参照してください。

これらのコード要素がどのように連携しているか

このページで紹介するコード要素が InterSystems IRIS でどのように使用されるのかを理解しておくと役立ちます。

ObjectScript、Python、InterSystems SQL、クラス定義、マクロ、ルーチンなどを組み合わせて使用できるのは、記述したコードを InterSystems IRIS が直接使用しているのではないからです。代わりに、コードのコンパイル時に、システムが使用する下位レベルのコードが生成されます。これは、ObjectScript の場合は ObjectScript エンジンで使用される OBJ コードであり、Python の場合は Python エンジンで使用される PYC コードです。

複数のステップがあります。ステップを詳細に理解しておく必要はありませんが、以下の点を覚えておくことをお勧めします。

• クラス・コンパイラは、Python メソッド以外のすべての要素について、クラス定義および ObjectScript コードを処理して INT コードを生成します。Python コードは PY コードに処理されます。

  場合によっては、コンパイラは、ユーザが編集できない追加クラスを生成および保存します。これは、例えば、Web サービスおよび Web クライアントを定義するクラスをコンパイルしたときに行われます。

  クラス・コンパイラは、各クラスのクラス記述子も生成します。これは、システム・コードが実行時に使用します。

• ObjectScript コードの場合、プリプロセッサ (マクロ・プリプロセッサまたは MPP と呼ばれることもあります) は、インクルード・ファイルを使用し、マクロを置換します。また、ルーチン内の埋め込み SQL も処理します。

  これらの変更は、一時的な作業領域で行われ、コードが変更されることはありません。

• ルーチンの INT コードは追加のコンパイラによって作成されます。

• INT コードおよび PY コードは中間層であり、この層では、データへのアクセスは直接グローバル・アクセスを使用して処理されます。これは人間が読めるコードです。

• INT コードは OBJ コードの生成に使用され、PY コードは PYC コードの生成に使用されます。このコードは、InterSystems IRIS 仮想マシンによって使用されます。コードを OBJ コードや PYC コードにコンパイルしたら、INT ルーチンや PY ルーチンはコードの実行に不要となります。

• クラスをコンパイルしたら、それらを配置モードにすることができます。InterSystems IRIS には、指定クラスの中間コードと内部クラスを削除するユーティリティがあり、このユーティリティはアプリケーションを配置するときに使用できます。

  InterSystems IRIS システム・クラスを調べると、クラスによっては配置モードになっているため、見えないことがあります。