Thanks for your feedback!
Need to tell us more? Click here or use the Feedback button.

Is this page helpful?

Contents

CDA ドキュメントの提供および登録
非 CDA ドキュメントの提供および登録
サードパーティ・システムの IHE メタデータ要件

XDS ドキュメント・リポジトリへのドキュメントの提供と登録

インターシステムズ製品は、IHE “XDS.b Provide and Register Document Set” トランザクションを介して、XDS リポジトリにドキュメントを提供および登録できます。ドキュメントが Clinical Document Architecture (CDA) を使用している場合、InterSystems はドキュメントからドキュメント・メタデータを直接抽出できます。例えば PDF ファイルなど、他の全種類のドキュメントについて、メッセージでドキュメント・メタデータを提供する必要があります。

CDA ドキュメントの提供および登録

インターシステムズ製品は、IHE “XDS.b Provide and Register Document Set” トランザクション (PnR) を介して、アフィニティ・ドメイン内のドキュメント・リポジトリに CDA ドキュメントを提供および登録できます。インターシステムズ製品は、ドキュメントそのものからメタデータを抽出できます。

Provide and Register に MPI ID が含まれない場合は、自動的に PIX クエリが実行されます。この PIX クエリは、抽出された MRN を使用して患者の MPI ID を取得します。

CDA が別のドキュメントを置換する場合 (Provide and Register で <ReplacementContext> が指定されている場合)、XDS クエリが実行されて、置換するドキュメントの固有 ID が取得されます。

このセクションでは、以下の項目について説明します。

CDA Provide and Register のメッセージ・トレース

以下の図に、CDA ドキュメントにおける、アノテーション付きの XDS Provide and Register のメッセージ・トレースを示します。ここには、オプションの検索要求と置換クエリの両方が示されています。

図に示されているテスト・サービスは、単純なメッセージ・ルータです。トレース操作は、トレース内の中間処理の各段階を可視化するユーティリティです。図中の番号は、以下の手順の各段階に一致します。

CDA Provide and Register の手順

最小限のメタデータと共に、Provide and Register 要求Opens in a new tabを InterSystems Document Source に提供します。
最小限必要なメタデータには、<MIMEType>、<FormatCode>、および <BodyCharacter> 内のファイルの内容が含まれます。<BodyCharacter> に含めるファイルを開くときは、必ず正しいファイル・タイプとして開いてください。例えば、XML 形式の CDA ドキュメントはテキスト・ファイルとして開きます。
新しい Provide and Register 要求が作成されると、自動的にドキュメント固有 ID が生成されます。
InterSystems Document Source は、CDA からドキュメント・メタデータを抽出し、それを使用して完全な IHE “ProvideAndRegisterDocumentSetRequest” を作成します。
1. Provide and Register 要求に MPI ID が含まれない場合、InterSystems Document Source は、CDA から MRN と割り当て機関を抽出し、前述の手順を使用して PIX クエリを実行します。
2. このドキュメントが既存のドキュメントを置換するよう Provide and Register で指定されている場合、Document Source は、XDS クエリを実行して、リポジトリの置換対象ドキュメントの ID を取得します。Provide and Register には、置換コンテキストに関するさまざまな条件を含めることができますが、MPI ID と既定のエントリ・ステータス “[承認済み]” は、指定されていなくても既定で含まれます。
3. Document Source は、DocumentTransform 設定で指定された XSL 変換を使用して、CDA から追加のメタデータを抽出し、それを使用して Provide and Register 要求に値を入力します。
その後、InterSystems Document Source は、XDSbRepositoryServiceName 設定で指定された別のシステム上にある XDS ドキュメント・レジストリ・エンドポイントに Provide and Register 要求を転送します。Provide and Register には、抽出されたドキュメント・メタデータとドキュメント自体 (<BodyCharacter> の内容) の両方が MTOM 添付ファイルとして含まれます。

Note:

InterSystems Document Source は、XDSbRepositoryServiceName 設定を使用してドキュメントの送信先を決定するため、複数のリポジトリにドキュメントをポストする場合は、各リポジトリに対して別個のドキュメント・ソース操作を設定する必要があります。特定のドキュメントに対して適切なリポジトリを決定するために使用する条件に基づいて、メッセージ・ルータを使用し、ドキュメントの送信先のドキュメント・ソース操作を決定します。
他のシステム上にあるドキュメント・リポジトリは、ドキュメントを保存し、要求で提供されたドキュメント・メタデータでアフィニティ・ドメインのドキュメント・レジストリを更新します。
他のシステム上にあるドキュメント・リポジトリは、成功 (または失敗) メッセージで応答します。
InterSystems Document Source は、“RegistryResponse” の種類の XML メッセージを返し、成功または失敗を示します。ドキュメントがレジストリに送信される前にトランザクションが失敗した場合、InterSystems Document Source は null を返します。

CDA Provide and Register のコンポーネントと設定

CDA ドキュメントの Provide and Register で使用されるコンポーネントと設定

コンポーネント	設定
ビジネス・ホスト	Document Source ： HS.IHE.XDSb.DocumentSource.OperationsOpens in a new tab
ビジネス・ホスト	PIX Consumer ： HS.IHE.PIXv3.Consumer.OperationsOpens in a new tab MPI ID を取得するために必要な場合
ビジネス・ホスト	Document Consumer ： HS.HC.IHE.XDSb.Consumer.OperationsOpens in a new tab メッセージで <Replacement Context> が指定されている場合
プロダクション設定	Document Source 内の DocumentTransform
プロダクション設定	Document Source 内の XDSbRepositoryServiceName
プロダクション・メッセージ	HS.Message.IHE.XDSb.ProvideAndRegisterRequestOpens in a new tab
プロダクション・メッセージ	HS.Message.XMLMessageOpens in a new tab ： RegistryResponse
プロダクション・メッセージ	HS.Message.PatientSearchRequestOpens in a new tab (PIX の場合)
プロダクション・メッセージ	HS.Message.PatientSearchResponseOpens in a new tab (PIX の場合)
プロダクション・メッセージ	HS.Message.IHE.XDSb.QueryRequestOpens in a new tab (置換の場合)
プロダクション・メッセージ	HS.Message.IHE.XDSb.QueryResponseOpens in a new tab (置換の場合)
インターシステムズ製品に送信する場合の最小限のドキュメント・メタデータ (IHE 最小要件の詳細は、"サードパーティ・システムの IHE メタデータ要件" を参照)	ファイルを正しいタイプとして開きます。例えば、XML はテキスト・ファイルとして開きます。メタデータ： <ContentTypeCode> — ドキュメントのコンテンツ・タイプを示します。 <SourceId> — ドキュメントを提供する施設の OID。 <MIMEType> — 通常は text/xml。 <FormatCode> — ドキュメント・タイプを示します。 <BodyCharacter> — ファイルの内容が含まれます。 <HealthCareFacilityTypeCode> — 施設タイプを示します。 <PracticeSettingCode> — 診療タイプを示します。
XSL 変換	IHE/XDSb/Version1/DocumentToProvideAndRegister.xsl
サービス・レジストリ・エントリ	XDSb.Repository
サービス・レジストリ・エントリ	PIXv3.Manager (PIX の場合)
サービス・レジストリ・エントリ	XDSb.Registry (置換の場合)
外部 IHE アクター・エンドポイント	XDS ドキュメント・リポジトリ
外部 IHE アクター・エンドポイント	PIX Manager (PIX の場合)
外部 IHE アクター・エンドポイント	XDS ドキュメント・レジストリ (置換の場合)

CDA Provide and Register の例

以下のメソッドは、CDA ファイルを開き、ドキュメントを提供および登録するために必要な最小限のメタデータを提供します。このメソッドを使用するには、Foundation プロダクションの HS.IHE.XDSb.DocumentSource.Operations に移動して、XDSbConsumerOperations 設定の値を HS.IHE.XDSb.Consumer.Operations から HS.HC.IHE.XDSb.Consumer.Operations に変更します。

 ClassMethod CDAPnR()
 {
    /// Provide and Register a CDA document
 
    // Create the Provide and Register message, which automatically assigns a 
    // document unique ID
    Set tMessage=##class(HS.Message.IHE.XDSb.ProvideAndRegisterRequest).%New()
 
    // Identify the message source
    Set tMessage.SourceId="1.3.6.1.4.1.21367.1"
 
    // Create a document instance to hold the document metadata
    Set tDocument = ##class(HS.Message.IHE.XDSb.Document).%New()
 
    // Open the document file and insert it into <BodyCharacter> (for non-CDA, 
    // this is <Body>). The document will become an MTOM attachment in the 
    // outbound message. In this case, we are providing a Consolidated CDA (C-CDA) 
    //in XML, so open the file as a text file.
    Set tFile = ##class(%File).%New()
    Set tFile.Name="C:\wtemp\testccda.xml"
    Do tFile.Open("R")
    Do tFile.Rewind()
    Do tDocument.BodyCharacter.CopyFrom(tFile)
    Kill tFile
 
    // Set the required minimum document metadata. For CDA, the <MIMEType> is "text/xml"
    Set tDocument.MimeType="text/xml"
    Set tDocument.FormatCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
          "urn:hl7-org:sdwg:ccda-structuredBody:1.1",
          "1.3.6.1.4.1.19376.1.2.3",
          "Consolidated CDA R1.1 Structured Body Document")
    Set tDocument.HealthcareFacilityTypeCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
          "22232009”,”2.16.840.1.113883.6.96","Hospital")
    Set tDocument.PracticeSettingCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
          "394802001","2.16.840.1.113883.6.96","General Medicine")
 
    // This is optional and controls replacement. If you specify a ReplacementContext,
    // then an XDS.B query is performed to obtain the document unique ID
    // of documents that match the context.
    //
    // In the case below, it is looking for documents that match the specified 
    // format code. You may include other context items as well. InterSystems 
    // automatically adds the Patient ID and the Status of "approved"
    // to the context.
    Set tContext = ##class(HS.Message.IHE.XDSb.QueryItem).CodedValue(
           "$XDSDocumentEntryFormatCode",
           "urn:hl7-org:sdwg:ccda-structuredBody:1.1",
           "1.3.6.1.4.1.19376.1.2.3")
 
    Do tDocument.ReplacementContext.Insert(tContext)
 
    /// Insert the document metadata into the message
    Do tMessage.Documents.Insert(tDocument)
 
    /// Send to the routing service (or directly to 
    /// HS.IHE.XDSb.DocumentSource.Operations)
    Write ##class(HS.Test.Service).SendSync(tMessage,.rr)
 
    quit
 }

非 CDA ドキュメントの提供および登録

インターシステムズ製品は、IHE “XDS.b Provide and Register Document Set” トランザクション (PnR) を介して、アフィニティ・ドメイン内のドキュメント・リポジトリに任意の種類のドキュメントを提供および登録できます。ドキュメント・メタデータをインターシステムズ製品に提供する必要があります。

このセクションでは、以下の項目について説明します。

非 CDA Provide and Register のメッセージ・トレース

以下の図に、非 CDA ドキュメントにおける、アノテーション付きの XDS Provide and Register のメッセージ・トレースを示します。ここには、置換コンテキストのクエリ要求が含まれます。

非 CDA ドキュメントの提供および登録の手順

インターシステムズ製品は、IHE “XDS.b Provide and Register Document Set” トランザクション (PnR) を介して、アフィニティ・ドメイン内のドキュメント・リポジトリに任意の臨床ドキュメント (例えば PDF) を提供および登録できます。

完全なドキュメント・メタデータと共に、Provide and Register 要求Opens in a new tabを InterSystems Document Source に提供します。メッセージの <SourcePatientId> に患者の MPI ID を含める必要があります。MRN のみがある場合は、メッセージを作成する前に、PIX クエリを実行して MPI ID を取得します。
最小限必要なドキュメント・メタデータには、<MIMEType>、<FormatCode>、<Body>、<SourcePatientInfo>、および作成者情報が含まれます。<Body> に含めるファイルを開くときは、必ず正しいファイル・タイプとして開いてください。例えば、PDF ファイルはバイナリとして開きます。
新しい Provide and Register 要求が作成されると、自動的にドキュメント固有 ID が生成されます。
このドキュメントが既存のドキュメントを置換するよう Provide and Register で指定されている場合、Document Source は、XDS クエリを実行して、リポジトリの置換対象ドキュメントの ID を取得します。Provide and Register には、置換コンテキストに関するさまざまな条件を含めることができますが、MPI ID と既定のエントリ・ステータス “[承認済み]” は、指定されていなくても既定で含まれます。
InterSystems Document Source は、DocumentTransform 設定で指定された XSL 変換を使用して、メッセージを IHE “ProvideAndRegisterDocumentSetRequest” に変換します。
その後、InterSystems Document Source は、XDSbRepositoryServiceName 設定で指定された別のシステム上にある XDS ドキュメント・レジストリ・エンドポイントに Provide and Register 要求を転送します。Provide and Register には、ドキュメント・メタデータとドキュメント自体 (<Body> の内容) の両方が MTOM 添付ファイルとして含まれます。
他のシステム上にある XDS ドキュメント・リポジトリは、ドキュメントを保存し、要求で提供されたドキュメント・メタデータでアフィニティ・ドメインの XDS ドキュメント・レジストリを更新します。
他のシステム上にある XDS ドキュメント・リポジトリは、成功 (または失敗) メッセージで応答します。
InterSystems Document Source は、“RegistryResponse” の種類の XML メッセージを返し、成功または失敗を示します。ドキュメントがレジストリに送信される前にトランザクションが失敗した場合、InterSystems Document Source は null を返します。

非 CDA Provide and Register のコンポーネントと設定

非 CDA ドキュメントの Provide and Register で使用されるコンポーネントと設定

コンポーネント	設定
ビジネス・ホスト	Document Source ： HS.IHE.XDSb.DocumentSource.OperationsOpens in a new tab
ビジネス・ホスト	Document Consumer ： HS.HC.IHE.XDSb.Consumer.OperationsOpens in a new tab メッセージで <Replacement Context> が指定されている場合
プロダクション設定	Document Source 内の XDSbRepositoryServiceName
プロダクション・メッセージ	HS.Message.IHE.XDSb.ProvideAndRegisterRequestOpens in a new tab
プロダクション・メッセージ	HS.Message.XMLMessageOpens in a new tab ： RegistryResponse
プロダクション・メッセージ	HS.Message.IHE.XDSb.QueryRequestOpens in a new tab (置換の場合)
プロダクション・メッセージ	HS.Message.IHE.XDSb.QueryResponseOpens in a new tab (置換の場合)
インターシステムズ製品に送信する場合の最小限のドキュメント・メタデータ IHE 最小要件の詳細は、"サードパーティ・システムの IHE メタデータ要件" を参照完全なドキュメント・メタデータの詳細は、Provide and RegisterOpens in a new tab 要求メッセージのクラス・リファレンスを参照	ファイルを正しいタイプとして開きます。例えば、PDF はバイナリとして開きます。メタデータ： <MIMEType> — 例えば、application/pdf です。MIME タイプの完全なリストは、iana.orgOpens in a new tab を参照してください。 <FormatCode> — ドキュメント・タイプを示します。 <Body> — ファイルの内容が含まれます。 <SourcePatientInfo> — HL7 セグメントとしての患者基本情報。 <HealthCareFacilityTypeCode> — 施設タイプを示します。 <PracticeSettingCode> — 診療タイプを示します。 <Author...> (...施設、...ロール、...人物、...専門)
XSL 変換	IHE/XDSb/Version1/DocumentToProvideAndRegister.xsl
サービス・レジストリ・エントリ	XDSb.Repository
サービス・レジストリ・エントリ	XDSb.Registry (置換の場合)
外部 IHE アクター・エンドポイント	XDS ドキュメント・リポジトリ
外部 IHE アクター・エンドポイント	XDS ドキュメント・レジストリ (置換の場合)

非 CDA ドキュメントの提供および登録の例

以下のメソッドは、PDF ドキュメントに対して XDS Provide and Register を生成します。このメソッドを使用するには、Foundation プロダクションの HS.IHE.XDSb.DocumentSource.Operations に移動して、XDSbConsumerOperations 設定の値を HS.IHE.XDSb.Consumer.Operations から HS.HC.IHE.XDSb.Consumer.Operations に変更します。

 ClassMethod CDAPnR2()
 {
   // Create the message, which automatically assigns a document unique ID
   Set tMessage=##class(HS.Message.IHE.XDSb.ProvideAndRegisterRequest).%New()

   // Provide SubmissionSet metadata (see "Note 1" below)
   Set tMessage.PatientId="100000001^^^&1.3.6.1.4.1.21367.2010.1.2.300&ISO"
   Set tMessage.SourceId="1.3.6.1.4.1.21367.2010.1.2.300.2.0"
   Set tMessage.ContentTypeCode = ##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "11488-4","2.16.840.1.113883.6.1","Consultation Note")
   
   // Create a document instance to hold the document metadata
   Set tDocument = ##class(HS.Message.IHE.XDSb.Document).%New()
   
   // Open the document (see "Note 2" below)
   Set tFile = ##class(%Stream.FileBinary).%New()
   Set tFile.Filename="C:\wtemp\testdoc.pdf"
   Do tFile.Rewind()
   Do tDocument.Body.CopyFrom(tFile)
   Kill tFile
   
   // Set the "MIMEType" (see "Note 3" below)
   Set tDocument.MimeType="application/pdf"
   
   // Enter the document metadata (see "Note 4" below)
   Set tDocument.CreationTime="20180821102615-0400"
   Set tDocument.LanguageCode="en-CA"
   
   Set tDocument.ClassCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "26435-8","2.16.840.1.113883.6.1","MOLECULAR PATHOLOGY STUDIES")
   Set tDocument.FormatCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "urn:ihe:iti:xds-sd:pdf:2008","1.3.6.1.4.1.19376.1.2.3","Scanned Documents PDF")
   Set tDocument.HealthcareFacilityTypeCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "OF","2.16.840.1.113883.5.11","Outpatient facility")
   Set tDocument.PracticeSettingCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "394802001","2.16.840.1.113883.6.96","General Medicine")
   Set tDocument.TypeCode=##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "18768-2","2.16.840.1.113883.6.1","CELL COUNTS+DIFFERENTIAL STUDIES")
   
   Do tDocument.ConfidentialityCode.Insert(##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "N","2.16.840.1.113883.5.25","Normal"))
   Do tDocument.EventCodeList.Insert(##class(HS.IHE.XDSb.Types.CodedValue).Create(
       "1.2.840.10065.1.12.1.13","1.2.840.10065.1.12","Review Signature"))
   
   // Patient demographics
   Set tDocument.SourcePatientId="1111222^^^&1.3.6.1.4.1.21367.2010.1.2.310&ISO"
   Do tDocument.SourcePatientInfo.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New(
       "PID-3|1111222^^^&1.3.6.1.4.1.21367.2010.1.2.310&ISO"))
   Do tDocument.SourcePatientInfo.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New(
       "PID-5|Smith^James^"))
   Do tDocument.SourcePatientInfo.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New(
       "PID-7|20000930"))
   Do tDocument.SourcePatientInfo.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New("PID-8|M"))
   Do tDocument.SourcePatientInfo.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New(
       "PID-11|123 Money Street^^Somewhere^SW^"))
   
   // Document author
   Set tAuthor= ##class(HS.IHE.XDSb.Types.Author).%New()
   Set tAuthor.AuthorPerson="John Smith"
   Do tAuthor.AuthorInstitution.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New("Johns Hopkins"))
   Do tAuthor.AuthorRole.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New("Role"))
   Do tAuthor.AuthorSpecialty.Insert(##class(HS.IHE.XDSb.Types.SlotValue).%New("Specialty"))
   Do tDocument.Author.Insert(tAuthor)
   
   // Optional replacement context (see "Note 5" below)
   Set tContext = ##class(HS.Message.IHE.XDSb.QueryItem).CodedValue("$XDSDocumentEntryEventCodeList",
      "1.2.840.10065.1.12.1.13","1.2.840.10065.1.12")
   Do tDocument.ReplacementContext.Insert(tContext)
   
   // Insert the document metadata into the message
   Do tMessage.Documents.Insert(tDocument)
   
   // Send the message to the test service (or directly to HS.IHE.XDSb.DocumentSource.Operations)  
   Write ##class(HS.Test.Service).SendSync(tMessage,.rr)
   
   Quit
}

テスト・サービスを使用したときのエラーを捕捉するには、上記の例で最後にある Write 文を以下のように置き換えます。

  Set tSC = ##class(HS.Test.Service).SendSync(tMessage,.rr)
  if $$$ISOK(tSC) {   
  set statusSuccess=rr.ContentStream.FindAt(
     1,"urn:oasis:names:tc:ebxml-regrep:ResponseStatusType:Success")
  set statusFail=rr.ContentStream.FindAt(
     1,"urn:oasis:names:tc:ebxml-regrep:ResponseStatusType:Failure")    
  if statusFail0 { w !, "Response Status was a failure!"   
     Do rr.ContentStream.Rewind() w !, rr.ContentStream.Read(231), " ... " }
  if statusSuccess>0 { w !, "Response Status was Success"  } 
  } else { Do $System.Status.DisplayError(tSC) }

注 1

送信セットのメタデータには、患者 ID (MPIID とホーム・コミュニティ OID)、ドキュメント・ソース、コンテンツ・コードを以下のように記述します。

手元に MRN のみがある場合は、PIX クエリを使用して患者 ID を取得します。
SourceId は、使用しているリポジトリに関連付けた機能の OID にする必要があります。
コード化エントリ・レジストリ (HS.IHE.CodedEntry) から ContentTypeCode を選択します。
この例の“スキーム” OID 2.16.840.1.113883.6.1 は LOINC を意味しています。

注 2

ドキュメント・ファイルを開き、それを Body (CDA では CharacterBody) に挿入します。このドキュメントは、送信するメッセージの MTOM 添付ファイルになります。この場合は PDF を指定しているので、このファイルをバイナリとして開きます。

注 3

PDF の MIMEType は application/pdf です。有効なタイプのリストは、http://www.iana.org/assignments/media-types/index.htmlOpens in a new tab を参照してください。

注 4

ドキュメントの作成時間には、IHE 仕様に従って YYYYMMDDHHMMSS のオフセット形式を使用します。以下の例では、現在の時間を正しい形式で生成します。

$REPLACE($TR($ZDT($H,3,6),":T"),"-","",,2)

注 5

これはオプションであり、置き換えを制御します。ReplacementContext を指定している場合は、コンテキストに一致するドキュメントのドキュメント固有 ID を取得する XDS.B クエリが実行されます。

この場合は、指定した eventcode と一致するドキュメントが検索されます。他のコンテキスト・アイテムを追加することもできます。コンテキストに患者 ID と "承認済み" ステータスが自動的に追加されます。

サードパーティ・システムの IHE メタデータ要件

以下の表は、IHE 仕様で必須のメタデータ属性を示しています。ドキュメントをサードパーティ・システムに送信する場合、必須メタデータ属性のすべてまたはサブセットが必要になる場合があります。例えば、CDA ドキュメントをインターシステムズ製品に提供する場合、ソース患者 ID がメタデータに記述されている必要はありません。この情報はドキュメントから抽出できるためです。他のシステムでは、この動作はサポートされていない場合があります。

DocumentEntry メタデータ属性の要件 (必須* とは、“既知の場合は必須” を意味します)

メタデータ属性	XDS.b Provide and Register	XDS.b Register	XDM Distribute	XDR Provide and Register	XDR (メタデータに制限) Provide and Register
author	必須	必須*	必須*	必須*	必須*
availabilityStatus	オプション	オプション	オプション	オプション	オプション
classCode	必須	必須	必須*	必須	必須*
comments	オプション	オプション	オプション	オプション	オプション
confidentialityCode	必須	必須	必須*	必須	必須*
creationTime	必須	必須	必須*	必須	必須*
entryUUID	必須	必須	必須	必須	必須
eventCodeList	オプション	オプション	オプション	オプション	オプション
formatCode	必須	必須	必須*	必須	必須*
hash	オプション	必須	必須	オプション	オプション
healthcareFacility TypeCode	必須	必須	必須*	必須	必須*
homeCommunityId	オプション	オプション	オプション	オプション	オプション
languageCode	必須	必須	必須*	必須	必須*
legalAuthenticator	オプション	オプション	オプション	オプション	オプション
mimeType	必須	必須	必須	必須	必須
patientId	必須	必須	必須*	必須	必須*
practiceSettingCode	必須	必須	必須*	必須	必須*
repositoryUniqueId	オプション	必須	オプション	オプション	オプション
serviceStartTime	必須*	必須*	必須*	必須*	必須*
serviceStopTime	必須*	必須*	必須*	必須*	必須*
size	オプション	必須	必須	オプション	オプション
sourcePatientId	必須	必須	必須*	必須	必須*
sourcePatientInfo	オプション	オプション	必須*	オプション	必須*
title	オプション	オプション	オプション	オプション	オプション
typeCode	必須	必須	必須*	必須	必須*
uniqueId	必須	必須	必須	必須	必須
URI	オプション	オプション	必須	オプション	オプション

SubmissionSet メタデータ属性の要件 (必須* とは、“既知の場合は必須” を意味します)

メタデータ属性	XDS.b Provide and Register	XDS.b Register	XDM Distribute	XDR Provide and Register	XDR (メタデータに制限) Provide and Register
author	必須*	必須*	必須*	必須*	必須*
availabilityStatus	オプション	オプション	オプション	オプション	オプション
comments	オプション	オプション	オプション	オプション	オプション
contentTypeCode	必須	必須	必須*	必須	必須*
entryUUID	必須	必須	必須	必須	必須
homeCommunityId	オプション	オプション	オプション	オプション	オプション
intendedRecipient	オプション	オプション	必須*	必須*	必須*
patientId	必須	必須	必須*	必須	必須*
sourceId	必須	必須	必須	必須	必須
submissionTime	必須	必須	必須	必須	必須

別のアフィニティ・ドメインのドキュメントのクエリと取得 (XCA)

XDS レジストリのクエリとリポジトリからのドキュメントの取得