SDA のカスタマイズ

Extension クラスへのプロパティの追加

SDA をカスタマイズするには、HSCUSTOM ネームスペースの HS.Local パッケージ内の拡張クラスにプロパティを追加します。

IDE で、該当するネームスペースに切り替えて、目的の拡張クラスを開きます。必要に応じて、新規プロパティを追加します。

以下のタイプのプロパティを追加できます。

• %StringOpens in a new tab

• 任意の HS.SDA3.<DataType> (Boolean や Numeric など)。

• 任意の既存の HS.SDA3 シリアル・クラス。

• 作成した任意のカスタム・シリアル・クラス (HS.SDA3.DataTypeOpens in a new tab を拡張する必要があります)。HS.Local や HS.SDA3 など、すぐに使用可能な HealthShare パッケージにカスタム・シリアル・クラスを定義しないでください。これにより、クラス名が SDA3 の将来の標準クラス名と競合しないようにします。例えば、カスタム・シリアル・クラスには、HS.SDA3.MySDASection ではなく ZUser.HS.MySDASection のような名前を付ける必要があります。HSCUSTOM にカスタム・パッケージ・マッピングを追加できます。

• 新規作成した任意のコード・テーブル (HS.SDA3.CodeTableTranslatedOpens in a new tab を拡張する必要があります)。以下のコード・テーブルは変換できません。

  変換から除外されるコード・テーブル

  HealthCareFacility	CareProviderType	Country
  Organization	City	County
  User	State	Trust
  CareProvider	Zip

以下の例では、Sneeziness プロパティおよび FlowerType プロパティが HS.Local.SDA3.AllergyExtensionOpens in a new tab クラスに追加されています。Sneeziness は文字列で、FlowerType はカスタム・タイプです。

 Class HS.Local.SDA3.AllergyExtension Extends HS.SDA3.DataType
 {
 Parameter STREAMLETCLASS = "HS.SDA3.Streamlet.Allergy";
 Property Sneeziness As %String;
 Property FlowerType As My.Local.Type.FT;
 }

クラスのリコンパイル

変更を加えた後、関連するクラスをリコンパイルする必要があります。効率性を最大限にするために、HS.SDA3 パッケージ全体をコンパイルすることをお勧めします。

追加のインスタンスがある場合は、新規のコード (関連付けられたマッピングを含む) が必ず各インスタンスに配置されるようにします。

拡張プロパティへのデータの入力

これで拡張プロパティの準備が整ったので、次はソース・システムからの受信データがそれらの拡張プロパティに入力されるようにする必要があります。

これは、ニーズとシステム設定に応じて複数の方法で実行できます。

• HealthShare Unified Care Record を実行している場合は、パイプラインを作成できます。詳細は、"Configuring Unified Care Record for Data Feeds" の “Creating Pipelines and Inbound Processes” の章を参照してください。

• InterSystems IRIS for Health または Health Connect を実行している場合は、DTL 変換を作成できます。詳細は、"DTL 変換の開発" を参照してください。DTL を作成する場合に目的の拡張プロパティが必ず使用可能になるようにするには、HSCUSTOM から XML スキーマをエクスポートして、それを目的のネームスペースにインポートする必要があります。

  1. ターミナルから、HSCUSTOM ネームスペースで以下を実行します。

     do ##class(HS.SDA3.Container).ExportXMLSchema()

     エクスポート・ファイルに使用する目的のファイル名を入力するよう求められます。必要に応じて、フル・パスとファイル名を .xsd 拡張子を付けて指定します。

  2. 管理ポータルから、DTL を作成しようとしているネームスペースで、[Interoperability]→[相互運用]→[XML]→[XML スキーマ構造] の順に選択します。

  3. [インポート] ボタンを選択して、エクスポート・ファイルに移動します。エクスポートされたスキーマが目的のネームスペースにインポートされます。

  4. これで、新しい DTL 変換を開いて拡張プロパティを使用できるようになりました。拡張クラスのプロパティが 1 つの場合、そのカスタム・プロパティは DTL ダイアグラムの拡張プロパティの下には表示されません。例えば、拡張クラスに BloodType と Sneeziness という 2 つのプロパティがある場合は、DTL ダイアグラムの拡張プロパティを展開して 2 つのカスタム・プロパティを表示できます。ただし、拡張クラスに BloodType という 1 つのプロパティしかない場合、DTL ダイアグラムの拡張プロパティの下に BloodType は表示されません。BloodType プロパティは親拡張プロパティに "ロールアップ" されます。

• 任意の製品を実行していて、HL7 メッセージを SDA に変換するために HS.Gateway.HL7.HL7ToSDA3Opens in a new tab クラスを使用している場合は、以下の操作を行います。

  1. HS.Gateway.HL7.HL7ToSDA3Opens in a new tab を拡張する新規クラスを作成します。

  2. 新規クラスで、追加した SDA 拡張を処理するためのコールバック・メソッドを実装します。このコールバック・メソッドには、On<StreamletName>() という形式 (例えば、OnAllergy()) で名前が付けられます。

  3. HS.Gateway.HL7.InboundProcess オペレーションを編集して、その HL7ToSDA3Class プロパティを、新規クラスを参照するように変更します。

以下に、SDA 拡張にデータを入力する具体的なケースと考慮事項を示します。

新しい拡張を FHIR DSTU2 で使用するために、拡張を作成した SDA クラスごとに、対応する DTL のカスタム・コピーを作成する必要があります。FHIR/SDA DSTU2 DTL をカスタマイズする方法の詳細は、"インターシステムズ製品における FHIR のサポート" を参照してください。

異なる拡張のセットによって環境間で共有される未加工の SDA に対応するには、すべての SDA3 クラスで XML 処理指示文 XMLIGNOREINVALIDTAG = 1 を使用します。認識できない Extension プロパティを持つ SDA ストリームをシステムがオブジェクトに読み込もうとした場合、認識できないプロパティは無視されます。TraceOperations が有効になっている場合、これが発生すると警告トレースがログに記録されます。

HS.Local.SDA3.PatientExtensionOpens in a new tab に格納されたデータを使用可能にし、HealthShare 導入環境全体で一貫して使用されるようにするために、HS.Types.PatientInfoOpens in a new tab クラスでは、タイプが HS.Local.SDA3.PatientExtensionOpens in a new tab の Extension という名前のプロパティがサポートされます。これにより、HS.Types.PatientInfoOpens in a new tab のすべてのサブクラスでも拡張が継承されます。これらのクラスを以下の表に示します。また、HS.Registry.PatientOpens in a new tab には、タイプが HS.Local.SDA3.PatientExtension Opens in a new tab の Extension プロパティが関連付けられており、HS.Hub.MPI.Manager の AddUpdateHub() メソッドのコードによって Patient の拡張クラスが処理されて HS_Registry.Patient テーブルに格納されます。

ストリームレット・クラスのカスタマイズ

前のセクションで説明したように、SDA オブジェクトにプロパティを追加できることに加えて、関連付けられたストリームレット・クラスの動作の一部をカスタマイズすることもできます。このセクションでは、そのプロセスと、留意する必要のある重要な制限事項について説明します。

以下の場合に、ストリームレット・クラスのカスタマイズを選択できます。

• 関連付けられている SDA クラスの照合ロジックを変更する場合

• 関連付けられている SDA クラスの検証ロジックを変更する場合

• 変換済みコードとして扱われるフィールドと、そのように扱われないフィールドを変更する場合

• コールバック・メソッドの動作をオーバーライドする場合

手順

一般的な手順は以下のとおりです。

1. HSCUSTOM ネームスペースで、目的の SDA オブジェクトに対応するストリームレット・クラスを拡張します。クラス・パッケージ名または独自に作成したサブパッケージ名を使用する必要があります。カスタム・クラスを HS.Local に保存する場合は、先頭が Z になっているサブパッケージ名 (HS.Local.ZMyPackage など) を使用する必要があります。HSCUSTOM にカスタム・パッケージ・マッピングを追加できます。

2. SDA 拡張クラスの STREAMLETCLASS パラメータを適切に調整します。例えば、HS.Local.SDA3.AllergyExtensionOpens in a new tab には以下が指定されます。

   Parameter STREAMLETCLASS = "HS.SDA3.Streamlet.Allergy";

   このストリームレット・クラスを拡張してクラス MyPackage.SDA3.Streamlet.ZAllergy を新規作成する場合、このパラメータを以下のように変更できます。

   Parameter STREAMLETCLASS = "MyPackage.SDA3.Streamlet.ZAllergy";

3. 必要に応じて、コールバック・メソッドをカスタマイズするか、メソッドを新たに追加するか、または一時プロパティを新たに追加します。操作を開始する前に、以下に示している制限事項を確認してください。

以下の例では、新規の Sneeziness プロパティに対するカスタムの照合および検証が含まれる新しい Allergy ストリームレットを定義しています。

 Class ZHS.SDA3.Streamlet.ZAllergy Extends HS.SDA3.Streamlet.Allergy
 {
 /// Adding a fallback match
 /// Previously, it matched based on the Allergy code table, 
 /// with nullable matches on FromTime and AllergyCategory code table
 /// If that doesn't match, we want it to also try using the ATCCode code table 
 /// (with nullable match on FromTime)
 Parameter MATCHINGS = "ALG/Allergy*/FromTime,AllergyCategory*|| ZATC/ATCCode*/FromTime";
 /// Adding some validation for our extension property
 Method OnValidate() As %Status
  {
   // We use IsDefined to avoid instantiating (swizzling) a null serial property, such as Extension
   // If we know that we'll always have data under Extension, this isn't needed
   If ..SDA.IsDefined("Extension") {
   Set tSneez=..SDA.Extension.Sneeziness
   If tSneez'?1.N1" Tissue".E, tSneez'?1.N1" Hankie".E {
   Quit $$$ERROR($$$GeneralError, "Sneeziness must be in terms of Tissues or Hankies.")
 }
 }
 Quit ##super()
 }
 }

照合の再計算

カスタム・ストリームレットに合わせて MATCHINGS パラメータを変更した場合、データを再評価して新規の照合を確認し、必要な場合はそれらの照合を調整する必要があります。以下で説明するように、これを実行できるように 3 つのユーティリティが用意されています。

これらの各ユーティリティは、ストリームレット・タイプを引数として取ります。標準ストリームレットまたは標準ストリームレットの拡張の場合、これは Allergy などの標準タイプです。カスタム・ストリームレットの場合は、HSCustom.SDA3.Streamlet.ZAllergy のような完全クラス名を使用する必要があります。

1. まず、RecalculateMatches を使用して既存の照合を再計算します。例えば、以下のようになります。

    Do ##class(HS.SDA3.Streamlet.Utility.RecalculateMatches).Start("HSCustom.SDA3.Streamlet.ZAllergy")

   

2. 次に、FindMatches を使用して照合の重複をすべて特定します。例えば、以下のようになります。

    Do ##class(HS.SDA3.Streamlet.Utility.FindMatches).Start("HSCustom.SDA3.Streamlet.ZAllergy")

   

   ^HS.SDA3.Streamlet.MatchGroups グローバルのコンテンツを表示して、このユーティリティが重複を検出したかどうかを確認できます。

3. FindMatches で照合の重複を特定した場合は、ReconcileMatches ユーティリティを実行して、このような照合をすべて調整できます。

    Do ##class(HS.SDA3.Streamlet.Utility.ReconcileMatches).ReconcileMatches("HSCustom.SDA3.Streamlet.ZAllergy")

   

   ReconcileMatches() メソッドは、最新のストリームレットを受け取り、それに一致するその他すべてを削除済みとマークすることで、これを実行します。一致のグループから受け取るストリームレットの判別に別の条件を適用する場合は、ReconcileMatches() メソッドを拡張するか、これを目的とした独自のカスタム・メソッドを作成できます。

FindMatches および RecalculateMatches はオプションで 2 つ目のパラメータを取ることができます。このパラメータはブーリアン値であり、処理をメソッドの前回の実行から再開するか、最初からやり直すかを指定します。例えば、以下のような場合です。

 Do ##class(HS.SDA3.Streamlet.Utility.FindMatches).Start("HSCustom.SDA3.Streamlet.ZAllergy", 1)

このパラメータが 0 に設定されているか省略されている場合、メソッドは指定されたタイプのすべてのストリームレット ID を処理します。このパラメータが 1 に設定されている場合、メソッドは、前回正常に処理されたストリームレット ID から再開します。この ID はグローバル ^ISC.HS.Streamlet.Loader("Last") に格納されています。

カスタム SDA プロパティの使用

ObjectScript コードでカスタム・プロパティを使用できるようになりました。カスタム拡張クラスおよびそのプロパティは、他のクラスと同じように動作します。

例えば、Sneeziness プロパティを新たに Allergy 拡張クラスに追加した場合、これを以下のように使用できます。

 Set tAllergy=##class(HS.SDA3.Allergy).%New()
 Set tAllergy.Extension.Sneeziness="3 Tissues"

Clinical Viewer で新規のプロパティを表示することもできます。詳細な手順は、"Customizing the Clinical User Interfaces" ガイドの "Adding SDA Fields to the Clinical Viewer" を参照してください。

カスタム SDA 拡張は、HealthShare Patient Index と Health Insight からアクセスして使用できます。詳細および追加の構成については、製品のドキュメントを参照してください。

カスタム SDA データ・クラスの作成

カスタム SDA コンテナを作成する最初の手順では、カスタム SDA セクションごとにカスタム SDA データ・クラスを定義します。

1. HS.SDA3.SuperClassOpens in a new tab を拡張するクラスを新規作成します。

   いずれかのカスタム SDA セクションにカスタム SDA データ・クラスを定義して、Health Insight でデータを解釈して保存できるようにする場合は、先に進む前に次のセクションを確認してください。

2. クラスに User.ZMySection のような名前を付けます。将来の標準 SDA3 クラス名と競合しないように、短いクラス名に接頭語 “Z” を付けることをお勧めします。

   クラスは SDA プロパティの標準セットを継承します。

   ActionCode	EncounterNumber	EnteredOn	ToTime
   ActionScope	EnteredAt	ExternalId	UpdatedOn
   CustomPairs	EnteredBy	FromTime

3. 独自の SDA プロパティを追加できます。文字列以外のデータ型を使用する場合は、Blob、Boolean、Numeric、TimeStamp などの既存の SDA3 データ型クラスを使用します。これにより、二重引用符のペアが削除をトリガする削除メカニズムに対応できるようになります。

   二重引用符の削除は、コレクション内の要素には適用されません。そのような要素を削除するには、問題のストリームレットに ActionCode = 'R' を割り当てて、ストリームレットの置換をトリガし、既存のすべてのコレクションをクリアする必要があります。

   以下のタイプのプロパティを追加できます。

   • %StringOpens in a new tab

   • 任意の HS.SDA3.<DataType> (Boolean や Numeric など)。

   • 任意の既存の HS.SDA3 シリアル・クラス。

   • 作成した任意のカスタム・シリアル・クラス (HS.SDA3.DataTypeOpens in a new tab を拡張する必要があります)。HS.Local や HS.SDA3 など、すぐに使用可能な HealthShare パッケージにカスタム・シリアル・クラスを定義しないでください。これにより、クラス名が SDA3 の将来の標準クラス名と競合しないようにします。例えば、カスタム・シリアル・クラスには、HS.SDA3.MySDASection ではなく ZUser.HS.MySDASection のような名前を付ける必要があります。

   • 新規作成した任意のコード・テーブル (HS.SDA3.CodeTableTranslatedOpens in a new tab を拡張する必要があります)。以下のコード・テーブルは変換できません。

     変換から除外されるコード・テーブル

     HealthCareFacility	CareProviderType	Country
     Organization	City	County
     User	State	Trust
     CareProvider	Zip

4. SDA クラスの標準の命名規則は、“Medication” のような単数形です。この場合、コンテナには、以下の XML に示すように “Medications” のような標準の複数形のリストが格納されます。

   <Medications>
      <Medication>
      </Medication>
      <Medication>
      </Medication>
   </Medications>

   

   カスタム・セクションの末尾に “s” を追加しても (Diagnosis/Diagnoses など) 機能しない場合は、SDA データ・クラスに StartXMLList()Opens in a new tab メソッドおよび EndXMLList()Opens in a new tab メソッドを実装し、コンテナで開始および終了のコレクション・タグを出力します。

    ClassMethod StartXMLList()
    {
        Quit "<Diagnoses>"
    }

   

    ClassMethod EndXMLList()
    {
        Quit "</Diagnoses>"
    }

   

5. クラスをコンパイルします。

   Note:

   <PROTECT> エラーが発生する場合、HSLIB データベースを一時的に書き込み可能にし、クラスを再コンパイルしてから、HSLIB を読み取り専用に戻します。

以下の例は、移植手術に関する情報のカスタム・データ・クラスを示しています。

 Class User.ZTransplant Extends HS.SDA3.SuperClass
 {

 Property OrganType As %String;

 Property TransplantPhysician As HS.SDA3.CodeTableDetail.CareProvider;

 Storage Default
 {
 <Data name="SuperClassState">
      <Subscript>"SuperClass"</Subscript>
      <Value name="1"><Value>ActionCode</Value></Value>
      <Value name="2"><Value>ActionScope</Value></Value>
      <Value name="3"><Value>EnteredBy</Value></Value>
      <Value name="4"><Value>EnteredAt</Value></Value>
      <Value name="5"><Value>EnteredOn</Value></Value>
      <Value name="6"><Value>ExternalId</Value></Value>
      <Value name="7"><Value>EncounterNumber</Value></Value>
      <Value name="8"><Value>FromTime</Value></Value>
      <Value name="9"><Value>ToTime</Value></Value>
      <Value name="10"><Value>Deleted</Value></Value>
      <Value name="11"><Value>UpdatedOn</Value></Value>
      <Value name="12"><Value>CustomPairs</Value></Value>
      <Value name="13"><Value>OrganType</Value></Value>
      <Value name="14"><Value>TransplantPhysician</Value></Value>
 </Data>
 <SequenceNumber>5</SequenceNumber>
 <Type>%Library.SerialState</Type>
 }
 }

カスタム SDA ストリームレット・クラスの作成

カスタム SDA コンテナ作成の 2 つ目の手順では、カスタム・データ・クラスごとに、データを格納するためのカスタム SDA ストリームレット・クラスを定義します。

1. HS.SDA3.Streamlet.Abstract と %PersistentOpens in a new tab の両方を拡張するクラスを新規作成します。

2. クラスに User.Streamlet.ZMySection のような名前を付けます。将来の標準 SDA3 クラス名と競合しないように、短いクラス名に接頭語 “Z” を付けることをお勧めします。

   前述のクラス名は、<PackageName>.streamlet.<SDADataClassname> というストリームレット・クラスの標準の命名規則を示しています。この命名規則に従わない場合は、SDA データ・クラスの HS.SDA3.SuperClassOpens in a new tab の GetStreamletClass() メソッドを実装して、ストリームレット・クラスの名前を出力する必要があります。既定のコードは次のとおりです。

      // for a standard SDA class, we get the streamlet class from the extension class,
      // to let the extension override it.  Classes that don't allow extension
      // can override this method
      If pType'["." Quit $Parameter("HS.Local.SDA3."_pType_"Extension","STREAMLETCLASS")
      // For custom ones, if we have a parameter, use it
      If $Parameter(,"STREAMLETCLASS")'="" Quit $Parameter(,"STREAMLETCLASS")
      //The code below is for backwards compatibility - it predates the parameter
      //and can be overridden if need be, but really one should just use the parameter
      Quit $P(pType,".",1,$L(pType,".")-1)_".Streamlet."_$P(pType,".",$L(pType,"."))
   

   

3. 以下のパラメータの値を入力します。

   パラメータ	説明	必須かどうか
   INFOTYPE	事前定義の情報タイプまたはカスタムの情報タイプ。	必須
   SDACLASS	SDA データ・クラスの名前。	必須
   DATEPROPERTY	日付でのフィルタ処理に使用するプロパティの名前。指定されていない場合、既定値の ToTime に設定されます。	オプション
   MATCHINGS	HealthShare Unified Care Record で対象のセクションに対する照合を実行する方法を指定します。Health Connect には適用されません。 照合の詳細は、HS.SDA3.Streamlet.Abstract のクラス・リファレンスを参照してください。 例については、いずれかの SDA3 ストリームレット・クラスのクラス・リファレンスを参照してください。	必須
   ACTIONSCOPES	このストリームレット・クラスに、限定された一連の有効な ACTIONSCOPES 値が設定されている場合、このパラメータはそれらの値のコンマ区切りリスト (先頭と末尾にもコンマあり) である必要があります。HealthShare Unified Care Record 専用で、Health Connect には適用されません。	オプション

4. オプションで、HealthShare Unified Care Record に実装するコールバックの以下のコードを入力します (Health Connect および InterSystems IRIS for Health には適用されません)。

   • OnInactivate()

   • OnMatchActionScope()

   • OnBeforeMatch()

   • OnValidate()

   • OnBeforeSave() — 一時多次元プロパティ Stash を使用して、OnBeforeSave() から OnAfterSave() にデータを渡すことができます ：

   • OnAfterSave()

5. クラスをコンパイルします。

以下の例は、移植手術に関する情報のカスタム・ストリームレット・クラスを示しています。

 Class User.Streamlet.ZTransplant Extends (HS.SDA3.Streamlet.Abstract, %Persistent)
 {

 Parameter INFOTYPE = "PRC";

 Parameter SDACLASS = "User.ZTransplant";

 Parameter DATEPROPERTY = "EnteredOn";

 Parameter MATCHINGS = "PRC/EnteredOn";

 Storage Default
 {
 <ExtentSize>100000</ExtentSize>
 <SequenceNumber>5</SequenceNumber>
 <Type>%Library.Storage</Type>
 }
 }

カスタム SDA コンテナ・クラスの作成

カスタム SDA コンテナ作成の 3 つ目の手順では、カスタム SDA セクションを格納するカスタム SDA コンテナ・クラスを定義します。

1. HS.SDA3.ContainerOpens in a new tab を拡張するクラスを新規作成します。

2. コンテナ・クラスに User.ZMyContainer のような名前を付けます。将来の標準 SDA3 クラス名と競合しないように、短いクラス名に接頭語 “Z” を付けることをお勧めします。

3. 新規の SDA データ・セクションごとにプロパティを追加します。プロパティに ZMySections (複数形) という名前を付けるか、またはデータ・クラスに StartXMLList()Opens in a new tab メソッドおよび EndXMLList()Opens in a new tab メソッドを実装している場合はその値をプロパティ名として使用します。プロパティは、User.ZMySection (単数形) のリストである必要があります。

4. クラスをコンパイルします。

   Note:

   <PROTECT> エラーが発生する場合、HSLIB データベースを一時的に書き込み可能にし、クラスを再コンパイルしてから、HSLIB を読み取り専用に戻します。

以下の例は、移植手術に関するセクションを格納するカスタム・コンテナ・クラスを示しています。

Class User.ZMyContainer Extends HS.SDA3.Container
{

Parameter XMLNAME = "Container";

Property ZTransplants As list Of User.ZTransplant;

}

構成レジストリへのカスタム SDA コンテナの登録

カスタム SDA コンテナ作成の最後の手順では、構成レジストリにカスタム・コンテナを登録します。

1. 構成レジストリに、以下のようなエントリを作成します。

   • キーが \CustomSDA3Container である

   • 値が、接尾語 “.cls” の付かないコンテナ・クラスの名前である

カスタムの SDA の名前と値のペアの作成

SDA の各セクションには、<CustomPairs> 要素が含まれています。既存の SDA セクションに、追加データ項目を取得する名前と値のペアを追加するには、該当するセクションに <CustomPairs> 要素が含まれる SDA ドキュメントを登録するだけです。名前と値の各ペアは、<NVPair> 要素に記述されます。<CustomPairs><NVPair><Name> プロパティにデータの説明を入力し、<CustomPairs><NVPair><Value> プロパティにデータを格納します。

以下の例は、SDA のアレルギーに関するセクションに一連の治療を追加する方法を示しています。

<Container>
  ...
   <Allergies>
     <Allergy>
       ...
       <CustomPairs>
         <NVPair>
           <Name>Treatment</Name>
           <Value>Oral Corticosteroids</Value>
         </NVPair>
         <NVPair>
           <Name>Treatment</Name>
           <Value>Injected Steroids</Value>
         </NVPair>
       </CustomPairs>
     </Allergy>
   </Allergies>
 ...
</Container>

カスタム SDA オブジェクトの作成

SDA には、他の SDA セクションに関連しないデータの格納に使用できる <CustomObjects> セクションを設定できます。このセクションは、1 つ以上の <CustomObject> 要素で構成されます。

各 <CustomObject> 要素に、以下の要素を 1 つ以上含める必要があります。

• <CustomType> — エントリのタイプを指定します。

• <CustomPairs> — データを格納する名前と値のペアのリストです。前述のセクションを参照してください。

各 <CustomObject> には以下の要素を含めることもできます。

• <ActionCode><ActionScope> — 実行するアクションを示した、HealthShare Unified Care Record 製品に対する指示。具体的な詳細は、クラス・リファレンスを参照してください。

• <CustomMatchKey> — データベースに既に存在するオブジェクトと、対象タイプのエントリとを照合する方法を示した、HealthShare Unified Care Record 製品に対する指示。通常は、カスタム・ペア・エントリを連結したものになります (例 ： <NVPair3>|<NVPair1>)。各値は照合で必須になり、指定された順序で評価されます。

• <ExternalID> — 外部システムに対して意味を持つ可能性がある識別子。指定されている場合、プライマリ照合キーとして使用されます。

• <EnteredOn>、<EnteredAt>、<EnteredBy> — ソースの詳細。

• <FromTime>、<ToTime> — データが有効な期間に関する詳細。

詳細は、HS.SDA3.CustomObjectOpens in a new tab のクラス・リファレンスを参照してください。

以下の例では、2 件の理学療法の訪問ケアに関するデータが格納されています。

<Container>
  ...
  <Patient>
    ...
  </Patient>
  ...
  <CustomObjects>
    <CustomObject>
      <CustomType>HomeCareEvent</CustomType>
      <EnteredOn>2012-02-05T13:00:00Z</EnteredOn>
      <CustomPairs>
        <NVPair>
          <Name>EventType</Name>
          <Value>Physiotherapy</Value>
        </NVPair>
        <NVPair>
          <Name>Comment</Name>
          <Value>Minimal progress.  Assistance required for many tasks.</Value>
        </NVPair>
      </CustomPairs>
    </CustomObject>
    <CustomObject>
      <CustomType>HomeCareEvent</CustomType>
      <EnteredOn>2012-02-01T12:55:00Z</EnteredOn>
      <CustomPairs>
        <NVPair>
          <Name>EventType</Name>
          <Value>Physiotherapy</Value>
        </NVPair>
        <NVPair>
          <Name>Comment</Name>
          <Value>Home evaluation.  Bathroom rails and detachable shower head required.</Value>
        </NVPair>
      </CustomPairs>
    </CustomObject>
  </CustomObjects>
 ...
</Container>