特殊な HTML 指示文
CSP ページ・クラス内の OnPage() コールバックで、特殊な指示文である &html<> を使用して HTML を記述できます。この指示文では、より簡単に HTML を構築できますが、その結果はユニット・テストには適していません (ブラウザを使用せずに結果を検証できないため)。
&html<> の基本
特殊な指示文 &html<> には、複数行の HTML など、任意の有効な HTML を含めることができます。以下に例を示します。
Class GCSP.HTML Extends %CSP.Page
{
ClassMethod OnPage() As %Status
{
&html<<!DOCTYPE html>
<html lang="en" dir="ltr">
<body>
<h1>Basic Page</h1>
<div>No double quotes needed "here"</div>
</body>
</html>>
Quit $$$OK
}
}
&html<> 内の式
指示文 &html<> に含まれる HTML 内に式を含めると便利な場合があります。以下の 2 つの可能性があります。
-
コンパイル時に評価される式。この場合、次の構文を使用できます。
##(expression)##
この種類の式は、CSP コンパイル時式と呼ばれます。
-
実行時に評価される式。この場合、次の構文を使用できます。
#(expression)#
ここで、expression は任意の ObjectScript 式です。この種類の式は、CSP 実行時式と呼ばれます。
どちらの場合も、式が必要な場所に構文を含めるだけです (いかなる連結も必要ありません)。以下に例を示します。
Class GCSP.HTML1 Extends %CSP.Page
{
ClassMethod OnPage() As %Status
{
&html<<!DOCTYPE html>
<html lang="en" dir="ltr">
<body>
<h1>Basic Page</h1>
<div>This class was compiled at ##($zdatetime($h,3))##</div>
<div>This class was viewed at #($zdatetime($h,3))#</div>
</body>
</html>>
Quit $$$OK
}
}