ファイルおよびディレクトリのプロパティと属性

ファイルまたはディレクトリが読み取り専用か書き込み可能かの確認

ファイル名またはディレクトリ名を指定すると、ReadOnly() メソッドは、そのファイルまたはディレクトリが読み取り専用の場合は 1 を返し、そうでない場合は 0 を返します。

USER>write ##class(%File).ReadOnly("export.xml")
1
USER>write ##class(%File).ReadOnly("C:\temp")
0

同様に、ファイル名またはディレクトリ名を指定すると、Writeable() メソッドは、そのファイルまたはディレクトリが書き込み可能な場合は 1 を返し、そうでない場合は 0 を返します。

USER>write ##class(%File).Writeable("export.xml")
0
USER>write ##class(%File).Writeable("C:\temp")
1

ファイルまたはディレクトリを読み取り専用または書き込み可能にする方法 (Windows)

Windows 上のファイルまたはディレクトリを読み取り専用にするには、SetReadOnly() メソッドを使用します。このメソッドは、成功または失敗を示すブーリアン値を返します。このメソッドは 3 つの引数を取りますが、2 つ目は Windows では省略されます。1 つ目の引数は、ファイルまたはディレクトリの名前です。3 つ目の引数は、出力引数です。これが負の値の場合、メソッドが失敗したときにオペレーティング・システムから返されるエラー・コードが含まれます。

以下の例では、SetReadOnly() の呼び出しによって、ファイル C:\temp\testplan.pdf が正常に読み取り専用に変更されます。

USER>write ##class(%File).ReadOnly("C:\temp\testplan.pdf")
0
USER>write ##class(%File).SetReadOnly("C:\temp\testplan.pdf",,.return)
1
USER>write ##class(%File).ReadOnly("C:\temp\testplan.pdf")
1

以下の例では、SetReadOnly() の呼び出しが失敗し、"アクセスが拒否された" ことを示す Windows システム・エラー・コード 5 が返されます。

USER>write ##class(%File).SetReadOnly("C:\",,.return)
0
USER>write return
-5

Windows 上のファイルまたはディレクトリを書き込み可能にするには、SetWriteable() メソッドを使用します。このメソッドは同じ 3 つの引数を取りますが、同じようにその 2 つ目は Windows では省略されます。

USER>write ##class(%File).Writeable("export.xml")
0
USER>write ##class(%File).SetWriteable("export.xml",,.return)
1
USER>write ##class(%File).Writeable("export.xml")
1

ファイルまたはディレクトリを読み取り専用または書き込み可能にする方法 (Unix)

Unix でもメソッド SetReadOnly() と SetWriteable() を使用できますが、2 つ目のパラメータがあることで動作が多少異なります。詳細は、"クラス・リファレンス" の "%Library.File.SetReadOnly()Opens in a new tab" または "%Library.File.SetWriteable()Opens in a new tab" を参照してください。

ただし、Unix では、所有者、グループ、およびユーザに異なる許可を指定できます。ファイルとディレクトリの許可のきめ細かい制御については、"ファイルとディレクトリの属性の表示と設定" を参照してください。

ファイルとディレクトリの属性の表示

%Library.FileOpens in a new tab の Attributes() メソッドは、引数としてファイル名またはディレクトリ名を取り、整数として表現された属性のビット・シーケンスを返します。

以下は、Windows システムで実行した場合の例です。

USER>write ##class(%File).Attributes("iris.dat")
32
USER>write ##class(%File).Attributes("C:\temp")
16
USER>write ##class(%File).Attributes("secret.zip")
35

1 つ目の例の 32 は、iris.dat がアーカイブ・ファイルであることを示します。2 つ目の例の 16 は、C:\temp がディレクトリであることを示します。3 つ目の例では、複数のビットが設定されており、35 は、secret.zip が非表示で (2) 読み取り専用 (1) のアーカイブ (32) であることを示します。32 + 2 + 1 = 35 の計算になります。

以下は、Unix システムで実行した場合の例です。

write ##class(%File).Attributes("/home")
16877

この例の 16877 は、/home が、所有者は読み取り (256)、書き込み (128)、および実行 (64) の許可を持ち、グループは読み取り (32) および実行 (8) の許可を持ち、それ以外は読み取り (4) および実行 (1) の許可を持つディレクトリ (16384) であることを示します。16384 + 256 + 128 + 64 + 32 + 8 + 4 + 1 = 16877 の計算になります。

ファイルとディレクトリの属性の設定

一方、SetAttributes() メソッドは、ファイルまたはディレクトリの属性を設定して (可能な場合)、成功または失敗を示すブーリアン値を返します。このメソッドは、3 つの引数を取ります。1 つ目の引数は、ファイルまたはディレクトリの名前です。2 つ目の引数は、ファイルまたはディレクトリに設定する属性を表す整数です。3 つ目の引数は、出力引数です。これが負の値の場合、メソッドが失敗したときにオペレーティング・システムから返されるエラー・コードが含まれます。

以下は Windows で実行した場合の例で、1 ビットを設定して C:\temp\protectme.txt を読み取り専用にします。

USER>write ##class(%File).Attributes("C:\temp\protectme.txt")
32
USER>write ##class(%File).SetAttributes("C:\temp\protectme.txt",33,.return)
1
USER>write ##class(%File).Attributes("C:\temp\protectme.txt")
33

以下は Unix で実行した場合の例で、既定のディレクトリ内の myfile に対する許可を 644 から完全な許可 (777) に変更します。

USER>write ##class(%File).Attributes("myfile")
33188
USER>write ##class(%File).SetAttributes("myfile",33279,.return)
1
USER>write ##class(%File).Attributes("myfile")
33279

目的の属性値は、通常ファイルの値 (32768) に所有者 (448)、グループ (56)、およびその他 (7) のマスクを加算して計算されます。